R_ReservationDocumentSearch

@AbapCatalog.sqlViewName: 'RRESVNDOCSRCH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Reservation Document Search'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['Reservation'],
    representativeKey: 'Reservation'
}

@Metadata.ignorePropagatedAnnotations: true

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser' ]

define view R_ReservationDocumentSearch
  as select from I_ReservationDocumentHeader

  association [0..1] to I_UserContactCard         as _CreatedByUser                on  $projection.UserID = _CreatedByUser.ContactCardID

  association [0..1] to I_UserContactCard         as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.ContactCardID

  association [0..1] to I_Plant                   as _IssuingOrReceivingPlant      on  $projection.IssuingOrReceivingPlant = _IssuingOrReceivingPlant.Plant

  association [0..1] to I_StorageLocation         as _IssuingOrReceivingStorageLoc on  $projection.IssuingOrReceivingStorageLoc = _IssuingOrReceivingStorageLoc.StorageLocation
                                                                                   and $projection.IssuingOrReceivingPlant      = _IssuingOrReceivingStorageLoc.Plant
  //Extension

  association [1..1] to E_ReservationDocument     as _Extension                    on  $projection.Reservation = _Extension.Reservation

{
  key Reservation,
      GoodsMovementType                                           as GoodsMovementType,
      ReservationOrigin,
      ResvnVerificationCompanyCode,
      OrderID,
      CostCenter,
      ProfitCenter,
      ControllingArea,
      GoodsRecipientName,
      ReservationDate,
      IsCheckedAgainstFactoryCal,
      Customer,
      cast (WBSElementInternalID as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      _WBSElementBasicData.WBSElementExternalID                   as WBSElement,
      SalesOrder,
      AssetNumber,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      @Semantics.user.createdBy: true
      UserID,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      /* Associations */
      _ReservationDocumentItem,
      _ControllingArea,
      _CostCenter,
      _Customer,
      _GoodsMovementType,
      _VerificationCompanyCode,
      _Order,
      _WBSElementBasicData,
      _CreatedByUser,
      _LastChangedByUser,
      _IssuingOrReceivingPlant,
      _IssuingOrReceivingStorageLoc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RESERVATIONDOCUMENTHEADER",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"E_RESERVATIONDOCUMENT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CUSTOMER",
"I_GOODSMOVEMENTTYPE",
"I_LOGISTICSORDER",
"I_PLANT",
"I_RESERVATIONDOCUMENTITEM",
"I_STORAGELOCATION",
"I_USERCONTACTCARD",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_RESERVATIONDOCUMENTHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/