I_RESERVATIONHEADER

@AbapCatalog:{
               sqlViewName: 'IRESERVATIONHD',
               preserveKey: true,
               compiler.compareFilter: true
             }

@EndUserText.label: 'Reservation Header'

@AccessControl.authorizationCheck: #CHECK

@ObjectModel:{
               usageType:{
                           sizeCategory: #L,
                           serviceQuality: #A,
                           dataClass:#TRANSACTIONAL
                         },
               compositionRoot: true,
               representativeKey: 'Reservation'
             }


@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}

@Metadata.allowExtensions: true

define view I_ReservationHeader
  as select from rkpf

  association [0..1] to I_LogisticsOrder          as _Order                   on  $projection.OrderID = _Order.OrderID
  association [0..1] to I_GoodsMovementType       as _GoodsMovementType       on  $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType
  association [0..*] to I_CostCenter              as _CostCenter              on  $projection.CostCenter = _CostCenter.CostCenter
  association [0..*] to I_ProfitCenter            as _ProfitCenter            on  $projection.ControllingArea =  _ProfitCenter.ControllingArea
                                                                              and $projection.ProfitCenter    =  _ProfitCenter.ProfitCenter
                                                                              and $projection.ReservationDate >= _ProfitCenter.ValidityStartDate
                                                                              and $projection.ReservationDate <= _ProfitCenter.ValidityEndDate

  association [0..1] to I_ControllingArea         as _ControllingArea         on  $projection.ControllingArea = _ControllingArea.ControllingArea

  association [0..1] to I_Customer                as _Customer                on  $projection.Customer = _Customer.Customer

  association [1..*] to I_ReservationItem         as _ReservationItem         on  $projection.Reservation = _ReservationItem.Reservation

  association [0..1] to I_WBSElementByInternalKey as _WBSElementByInternalKey on  $projection.WBSElementInternalID = _WBSElementByInternalKey.WBSElementInternalID  
  association [0..1] to I_SalesOrder              as _SalesOrder              on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [0..1] to I_SalesOrderItem          as _SalesOrderItem          on  $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
                                                                              and $projection.SalesOrder     = _SalesOrderItem.SalesOrder
  association [0..1] to I_SalesOrderScheduleLine  as _SalesOrderScheduleLine  on  $projection.SalesOrderScheduleLine = _SalesOrderScheduleLine.ScheduleLine
                                                                              and $projection.SalesOrder             = _SalesOrderScheduleLine.SalesOrder
                                                                              and $projection.SalesOrderItem         = _SalesOrderScheduleLine.SalesOrderItem
  association [0..*] to I_MasterFixedAsset        as _MasterFixedAsset        on  $projection.AssetNumber = _MasterFixedAsset.MasterFixedAsset
                                                                              
  association [0..*] to I_FixedAsset              as _FixedAsset              on  $projection.AssetSubNumber = _FixedAsset.FixedAsset
                                                                              
                                                                              
  association [0..1] to I_Plant                   as _Plant                   on  $projection.IssuingOrReceivingPlant = _Plant.Plant
  association [0..1] to I_StorageLocation         as _StorageLocation         on  $projection.IssuingOrReceivingStorageLoc = _StorageLocation.StorageLocation
                                                                              and $projection.IssuingOrReceivingPlant      = _StorageLocation.Plant
  association [0..1] to I_CompanyCode             as _VerificationCompanyCode on  $projection.ResvnVerificationCompanyCode = _VerificationCompanyCode.CompanyCode

{
  key rsnum              as Reservation,
  
      creationcode       as ReservationCreationCode,
      
      kzver              as ReservationOrigin,
      
      usnam              as UserID,

      @ObjectModel.foreignKey.association: '_Order'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_LogisticsOrderStdVH',
                     element: 'OrderID' }
        }]
      aufnr              as OrderID,

      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      bwart              as GoodsMovementType,

      kostl              as CostCenter,
      prctr              as ProfitCenter,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      kokrs              as ControllingArea,
      @API.element.releaseState: #DECOMMISSIONED
      @API.element.successor: 'ProfitabilitySegment_2'
//      @VDM.lifecycle.status: #DEPRECATED

//      @VDM.lifecycle.successor: 'ProfitabilitySegment_2'

//      cast(paobjnr as nsdm_rkeobjnr) as ProfitabilitySegment,

      cast( case when paobjnr > '9999999999' then '9999999999' else lpad( paobjnr, 10, '0' )
            end as rkeobjnr_numc )   as ProfitabilitySegment,
      cast(paobjnr as rkeobjnr_char) as ProfitabilitySegment_2, 

      wempf              as GoodsRecipientName,

      rsdat              as ReservationDate,
      xcale              as IsCheckedAgainstFactoryCal,

      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      kunnr              as Customer,

      @ObjectModel.foreignKey.association: '_WBSElementByInternalKey'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_WBSElmntByIntKeyStdVH',
                     element: 'WBSElementInternalID' }
        }]
      ps_psp_pnr         as WBSElementInternalID,

      @ObjectModel.foreignKey.association: '_SalesOrder'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesOrderStdVH',
                     element: 'SalesOrder' }
        }]
      kdauf              as SalesOrder,

      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesOrderItemStdVH',
                     element: 'SalesOrderItem' },
          additionalBinding: [{ localElement: 'SalesOrder',
                                element: 'SalesOrder' }]
        }]
      kdpos              as SalesOrderItem,

      @ObjectModel.foreignKey.association: '_SalesOrderScheduleLine'
      kdein              as SalesOrderScheduleLine,

      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MasterFixedAssetStdVH',
                     element: 'MasterFixedAsset' }
        }]
      anln1              as AssetNumber,

      @ObjectModel.foreignKey.association: '_FixedAsset'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FixedAssetStdVH',
                     element: 'FixedAsset' }
        }]
      anln2              as AssetSubNumber,

      nplnr              as NetworkNumberForAcctAssgmt,

      @ObjectModel.foreignKey.association: '_Plant'
      umwrk              as IssuingOrReceivingPlant,

      @ObjectModel.foreignKey.association: '_StorageLocation'
      umlgo              as IssuingOrReceivingStorageLoc,

      parbu              as ResvnVerificationCompanyCode,

      creationdatetime   as CreationDateTime,

      lastchangedbyuser  as LastChangedByUser,

      lastchangedatetime as LastChangeDateTime,


      _CostCenter,
      _ProfitCenter,
      _ControllingArea,
      _Order,
      _GoodsMovementType,
      _Customer,
      _WBSElementByInternalKey,
      _SalesOrder,
      _SalesOrderItem,
      _SalesOrderScheduleLine,
      _MasterFixedAsset,
      _FixedAsset,
      _Plant,
      _StorageLocation,
      _VerificationCompanyCode,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _ReservationItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"RKPF"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CUSTOMER",
"I_FIXEDASSET",
"I_GOODSMOVEMENTTYPE",
"I_LOGISTICSORDER",
"I_MASTERFIXEDASSET",
"I_PLANT",
"I_PROFITCENTER",
"I_RESERVATIONITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SALESORDERSCHEDULELINE",
"I_STORAGELOCATION",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/