R_ReservationDocumentHeaderTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Reservation Document Header'
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['Reservation'],
    representativeKey: 'Reservation'
}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser',
                                         '_ControllingArea', '_CostCenter', 
                                         '_VerificationCompanyCode',
                                         '_Order', '_WBSElementBasicData' ]
@ObjectModel.sapObjectNodeType.name : 'ReservationDocument'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'RDH',
  quota: {
    maximumFields: 404,
    maximumBytes: 24080
  } }
define root view entity R_ReservationDocumentHeaderTP
  as select from I_ReservationDocumentHeader 
    inner join   P_ResvnDocRqmtType on I_ReservationDocumentHeader.Reservation = P_ResvnDocRqmtType.Reservation
  //                                              and P_ResvnDocRqmtType.RequirementType      = 'MR'

  //    inner join   P_ResvnDocManualGoodsMvtType on I_ReservationDocumentHeader.GoodsMovementType = P_ResvnDocManualGoodsMvtType.GoodsMovementType


  composition [0..*] of R_ReservationDocumentItemTP as _ReservationDocumentItemTP

  //  association [0..1] to I_ResvnDocAccountAssignment as _ResvnDocAccountAssignment    on  $projection.Reservation = _ResvnDocAccountAssignment.Reservation


  association [0..1] to I_ResvnDocHeaderStatus      as _ResvnCalculatedFilters       on  $projection.Reservation = _ResvnCalculatedFilters.Reservation

  association [0..1] to I_UserDescription           as _CreatedByUser                on  $projection.UserID = _CreatedByUser.UserID

  association [0..1] to I_UserDescription           as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [0..1] to I_Plant                     as _IssuingOrReceivingPlant      on  $projection.IssuingOrReceivingPlant = _IssuingOrReceivingPlant.Plant

  association [0..1] to I_StorageLocation           as _IssuingOrReceivingStorageLoc on  $projection.IssuingOrReceivingStorageLoc = _IssuingOrReceivingStorageLoc.StorageLocation
                                                                                     and $projection.IssuingOrReceivingPlant      = _IssuingOrReceivingStorageLoc.Plant

  association [0..1] to I_ResvnCategoryDetermination as _ResvnCategoryDetermination    on  $projection.Reservation = _ResvnCategoryDetermination.Reservation

  //Extension

  association [1..1] to E_ReservationDocument       as _Extension                    on  $projection.Reservation = _Extension.Reservation
 // interface association

 // association [1..1] to R_ReservationDocumentHeaderTP   as _Interface                    on  $projection.Reservation = _Interface.Reservation


{
      //I_ReservationDocumentHeader

  key I_ReservationDocumentHeader.Reservation,
      I_ReservationDocumentHeader.ReservationCreationCode,
//      I_ReservationDocumentHeader.ReservationOrigin,

      cast ( I_ReservationDocumentHeader.ReservationOrigin as imrs_reservation_origin preserving type) as ReservationOrigin,
      I_ReservationDocumentHeader.GoodsMovementType                                                                                                     as GoodsMovementType,
      I_ReservationDocumentHeader.ResvnVerificationCompanyCode,
      I_ReservationDocumentHeader.OrderID,
      I_ReservationDocumentHeader.CostCenter,
      I_ReservationDocumentHeader.ProfitCenter,
      I_ReservationDocumentHeader.ControllingArea,
      I_ReservationDocumentHeader.GoodsRecipientName,
      I_ReservationDocumentHeader.ReservationDate,
      I_ReservationDocumentHeader.IsCheckedAgainstFactoryCal,
//      I_ReservationDocumentHeader.Customer, // Not needed

      cast ( I_ReservationDocumentHeader.WBSElementInternalID as ps_s4_pspnr preserving type )                                                          as WBSElementInternalID,
      I_ReservationDocumentHeader._WBSElementBasicData.WBSElementExternalID                                                                             as WBSElement,
      I_ReservationDocumentHeader.SalesOrder,
      I_ReservationDocumentHeader.SalesOrderItem,
      I_ReservationDocumentHeader.SalesOrderScheduleLine,
      I_ReservationDocumentHeader.AssetNumber,
      I_ReservationDocumentHeader.AssetSubNumber,
      I_ReservationDocumentHeader.NetworkNumberForAcctAssgmt,
      I_ReservationDocumentHeader.IssuingOrReceivingPlant,
      I_ReservationDocumentHeader.IssuingOrReceivingStorageLoc,
      I_ReservationDocumentHeader.ProfitabilitySegment_2                                                                                                as ProfitabilitySegment,
      cast ( I_ReservationDocumentHeader._ReservationDocumentItem [ 1: ReservationItem = '0001' and RecordType = '' ].Plant as werks_d preserving type) as Plant,
      //      P_ResvnDocRqmtType.RecordType,

      P_ResvnDocRqmtType.RequirementType,
      P_ResvnDocRqmtType.ReservationItemCreationCode,
      @Semantics.user.createdBy: true
      I_ReservationDocumentHeader.UserID,
      @Semantics.systemDateTime.createdAt: true
      I_ReservationDocumentHeader.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      I_ReservationDocumentHeader.LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      I_ReservationDocumentHeader.LastChangeDateTime,

      /* Associations */
      //I_ReservationDocumentHeader

      _ReservationDocumentItemTP,
      I_ReservationDocumentHeader._ControllingArea,
      I_ReservationDocumentHeader._CostCenter,
//      I_ReservationDocumentHeader._Customer,

      I_ReservationDocumentHeader._GoodsMovementType,
      I_ReservationDocumentHeader._VerificationCompanyCode,
      I_ReservationDocumentHeader._Order,
      I_ReservationDocumentHeader._WBSElementBasicData,
      I_ReservationDocumentHeader._ReservationCreationCode,
      //      _ResvnDocAccountAssignment,

      _ResvnCalculatedFilters,
      _CreatedByUser,
      _LastChangedByUser,
      _IssuingOrReceivingPlant,
      _IssuingOrReceivingStorageLoc,
      _ResvnCategoryDetermination
  //    _Interface

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RESERVATIONDOCUMENTHEADER",
"I_RESERVATIONDOCUMENTITEM",
"I_WBSELEMENTBASICDATA",
"P_RESVNDOCRQMTTYPE"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_GOODSMOVEMENTTYPE",
"I_LOGISTICSORDER",
"I_PLANT",
"I_RESERVATIONCREATIONCODE",
"I_RESVNCATEGORYDETERMINATION",
"I_RESVNDOCHEADERSTATUS",
"I_STORAGELOCATION",
"I_USERDESCRIPTION",
"I_WBSELEMENTBASICDATA",
"R_RESERVATIONDOCUMENTITEMTP"
],
"BASE":
[
"I_RESERVATIONDOCUMENTHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/