I_ReservationDocumentItem

@AbapCatalog: {
                sqlViewName: 'IRESVNDOCITM',
                preserveKey: true,
                compiler.compareFilter: true
              }
@EndUserText.label: 'Reservation Document Item'
@AccessControl: {
                  authorizationCheck: #CHECK,
                  personalData.blocking: #BLOCKED_DATA_EXCLUDED
                }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                usageType: {
                             sizeCategory: #L,
                             serviceQuality: #B,
                             dataClass:#TRANSACTIONAL
                           },
                representativeKey: 'ReservationItem',
                semanticKey: ['Reservation', 'ReservationItem', 'RecordType'],
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
}
@VDM: {
        lifecycle.contract.type: #PUBLIC_LOCAL_API, 
        viewType: #BASIC
      }
@Analytics.dataCategory: #DIMENSION
@Metadata: {
             ignorePropagatedAnnotations:true,
             allowExtensions: true
           }

define view I_ReservationDocumentItem 

as select from I_ReservationItem as _ReservationItem
inner join I_ReservationDocumentHeader as _rkpf on _ReservationItem.Reservation = _rkpf.Reservation

association [1..1] to I_ReservationDocumentHeader         as _ReservationDocumentHeader             on  $projection.Reservation = _ReservationDocumentHeader.Reservation
association [0..1] to I_ReservationDocRecordType          as _ReservationDocRecordType              on  $projection.RecordType  = _ReservationDocRecordType.RecordType
association [1..1] to I_Product                           as _Product                               on  $projection.Product     = _Product.Product
association [1..1] to P_ProductPlantBasic                 as _ProductPlant                          on  $projection.Product     = _ProductPlant.Product
                                                                                                   and  $projection.Plant       = _ProductPlant.Plant
association [0..1] to I_BatchPlant                        as _BatchPlant                           on   $projection.Product     = _BatchPlant.Material
                                                                                                   and  $projection.Plant       = _BatchPlant.Plant
                                                                                                   and  $projection.Batch       = _BatchPlant.Batch                                                                                                 
--released PO I-views cannot be assiated because not yet marked as dimension
--association [0..1] to I_PurchaseOrderAPI01                as _PurchaseOrder                 on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
--association [0..1] to I_PurchaseOrderItemAPI01            as _PurchaseOrderItem             on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
--                                                                                            and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
{
  @ObjectModel.foreignKey.association: '_ReservationDocumentHeader'
  key  _ReservationItem.Reservation,
  key  _ReservationItem.ReservationItem,
  @ObjectModel.foreignKey.association: '_ReservationDocRecordType'
  key  _ReservationItem.RecordType,

    @ObjectModel.foreignKey.association: '_Plant'
    Plant,
    
    @ObjectModel.foreignKey.association: '_StorageLocation'
    StorageLocation,
    
    @ObjectModel.foreignKey.association: '_Product'
    Material as Product,

    @ObjectModel.foreignKey.association: null
    Batch,
    
    cast( case 
    //Split valuated but not batch managed 

    when  _ProductPlant.ValuationCategory <> '' and _ProductPlant.IsBatchManagementRequired = '' 
    then  Batch
    
    //Split valuated and batch managed 

    when _ProductPlant.ValuationCategory <> '' and _ProductPlant.IsBatchManagementRequired = 'X' 
    then _BatchPlant.InventoryValuationType
    
    else   ''
    end as bwtar_d preserving type ) as ValuationType,    
    
    @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
    InventorySpecialStockType,
    
    SpecialStockIdfgWBSElement,
    
    @ObjectModel.foreignKey.association: '_GoodsMovementType'
    _ReservationItem.GoodsMovementType,

    RequirementType,
    
    ReservationItemCreationCode,
    
    MatlCompRequirementDate,
    
    ManufacturingOrderOperation,
    
    GoodsMovementIsAllowed,
    
    @ObjectModel.foreignKey.association: '_DebitCreditCode'
    DebitCreditCode,
    
    @Semantics.unitOfMeasure: true
    @ObjectModel.foreignKey.association: '_BaseUnit'
    BaseUnit,
    
    GLAccount,

    @Semantics.booleanIndicator: true
    ResvnAccountIsEnteredManually,
    
    @Semantics.unitOfMeasure: true
    @ObjectModel.foreignKey.association: '_EntryUnit'
    EntryUnit,
    
    QuantityIsFixed,
    
    @Semantics.currencyCode: true
    @ObjectModel.foreignKey.association: '_Currency'
    CompanyCodeCurrency,
    
    @ObjectModel.foreignKey.association: '_IssuingOrReceivingPlant'
    _ReservationItem.IssuingOrReceivingPlant,
    
    @ObjectModel.foreignKey.association: '_IssuingOrReceivingStorageLoc'
    _ReservationItem.IssuingOrReceivingStorageLoc,

   @ObjectModel.foreignKey.association: '_PurchasingDocument'
    PurchasingDocument,   
    
    @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
    PurchasingDocumentItem,
    
    @Semantics.quantity.unitOfMeasure: 'BaseUnit'
    ResvnItmRequiredQtyInBaseUnit,
    
    @Semantics.quantity.unitOfMeasure: 'BaseUnit'
    ConfdQtyForATPInBaseUoM,
    
    ReservationItemIsFinallyIssued,
    
    ReservationItmIsMarkedForDeltn,

    @Semantics.quantity.unitOfMeasure: 'EntryUnit'
    ResvnItmRequiredQtyInEntryUnit,

    @Semantics.quantity.unitOfMeasure: 'BaseUnit'
    ResvnItmWithdrawnQtyInBaseUnit,
    
    @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
    ResvnItmWithdrawnAmtInCCCrcy,
    
    @ObjectModel.foreignKey.association: '_Supplier'
    Supplier,
    
    MaterialGroup, 
    @Semantics.booleanIndicator: true
    _ReservationItem.MaterialCompIsProcuredDirectly,
    
    
    _ReservationItem.GoodsRecipientName,
    _ReservationItem.UnloadingPointName,
    _ReservationItem.ReservationItemText,
    @ObjectModel.foreignKey.association: '_RecipientLocationCode'    
    _ReservationItem.RecipientLocationCode,
    
    _ReservationItem.ServiceObjectType,
    _ReservationItem.ServiceDocument,
    _ReservationItem.ServiceDocumentItem,
    _ReservationItem.ResvnItmSrvcDocTypeAsAcctAsgt,
    _ReservationItem.ResvnItmSrvcDocAsAcctAsgt,
    _ReservationItem.ResvnItmSrvcDocItmAsAcctAsgt,   
    
    _DebitCreditCode,
    _Plant,
    _Product,
    _IssuingOrReceivingPlant,
    _StorageLocation,
    _IssuingOrReceivingStorageLoc,
    _ReservationItem._GoodsMovementType,
    _Currency,
    _PurchasingDocument,
    _PurchasingDocumentItem,
    _BaseUnit,
    _EntryUnit,
    _Supplier,
    _InventorySpecialStockType,
    _ReservationItem._WBSElementBasicData,
    _Batch,
    @Consumption.hidden: true
    _SupplierCompanyByPlant,
    
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
    _ReservationDocumentHeader,
    _ReservationDocRecordType,
    _ReservationItem._RecipientLocationCode,
    
    _ReservationItem._ServiceDocumentItem   
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHPLANT",
"I_RESERVATIONDOCUMENTHEADER",
"I_RESERVATIONITEM",
"P_PRODUCTPLANTBASIC"
],
"ASSOCIATED":
[
"I_BATCH",
"I_BATCHPLANT",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_GOODSMOVEMENTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_PLANT",
"I_PRODUCT",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_RECIPIENTLOCATIONCODE",
"I_RESERVATIONDOCRECORDTYPE",
"I_RESERVATIONDOCUMENTHEADER",
"I_SERVICEDOCUMENTITEM",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA",
"P_PRODUCTPLANTBASIC"
],
"BASE":
[
"I_RESERVATIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/