I_REObjectTypeDetails

@AbapCatalog.sqlViewName: 'IREOBJTYPDET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Object Type Details'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.semanticKey: [ 'REStatusObject' ]
@ObjectModel.representativeKey: 'REStatusObject'

define view I_REObjectTypeDetails
  as select from I_REKeyAssgmt as _REObjectTypeDetails

  association [1..1] to I_REKeyAssgmt          as _REKeyAssgmt         on  $projection.REStatusObject = _REKeyAssgmt.REStatusObject
  association [0..1] to I_REObjectTypeText     as _REObjectTypeText    on  _REObjectTypeText.RealEstateObjectType = $projection.RealEstateObjectType
                                                                       and _REObjectTypeText.Language             = $session.system_language
  association [0..1] to I_REContract           as _REContract           on  $projection.REStatusObject = _REContract.REStatusObject
  association [0..1] to I_REBusinessEntity     as _REBusinessEntity     on  $projection.REStatusObject = _REBusinessEntity.REStatusObject
  association [0..1] to I_REBuilding           as _REBuilding           on  $projection.REStatusObject = _REBuilding.REStatusObject
  association [0..1] to I_REProperty           as _REProperty           on  $projection.REStatusObject = _REProperty.REStatusObject
  association [0..1] to I_RERentalObject       as _RERentalObject       on  $projection.REStatusObject = _RERentalObject.REStatusObject
  association [0..1] to I_RESettlementUnit     as _RESettlementUnit     on  $projection.REStatusObject = _RESettlementUnit.REStatusObject
  association [0..1] to I_REIntegrationObject  as _REIntegrationObject  on  $projection.REStatusObject = _REIntegrationObject.REStatusObject
  association [0..1] to I_REServiceGroup       as _REServiceGroup       on  $projection.REStatusObject = _REServiceGroup.REStatusObject
  association [0..1] to I_REUsableObject       as _REUsableObject       on  $projection.REStatusObject = _REUsableObject.REStatusObject
  association [0..1] to I_RERentableObject     as _RERentableObject     on  $projection.REStatusObject = _RERentableObject.REStatusObject
{
  key       REStatusObject                                               as REStatusObject,
            InternalRealEstateNumber,
            RealEstateObjectType,
            REIdentificationKey,
            cast(
            concat_with_space(_REObjectTypeText.REObjectTypePrefix,
            REIdentificationKey,1 ) as recaident)                        as REIdentification,
            cast(
            concat_with_space(_REObjectTypeText.RealEstateObjectTypeName,
            REIdentificationKey,1 ) as recaident)                        as REAccountingObjectName,

            _REKeyAssgmt,

            _REContract,
            _REBusinessEntity,
            _REBuilding,
            _REProperty,
            _RERentalObject,
            _RESettlementUnit,
            _REIntegrationObject,
            _REServiceGroup,
            _REUsableObject,
            _RERentableObject
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REKEYASSGMT",
"I_REOBJECTTYPETEXT"
],
"ASSOCIATED":
[
"I_REBUILDING",
"I_REBUSINESSENTITY",
"I_RECONTRACT",
"I_REINTEGRATIONOBJECT",
"I_REKEYASSGMT",
"I_REOBJECTTYPETEXT",
"I_REPROPERTY",
"I_RERENTABLEOBJECT",
"I_RERENTALOBJECT",
"I_RESERVICEGROUP",
"I_RESETTLEMENTUNIT",
"I_REUSABLEOBJECT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/