I_RESettlementUnit

@AbapCatalog.sqlViewName: 'IRESETTLUNIT'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: ['_REPartnerAssgmt._BusinessPartner.IsBusinessPurposeCompleted']
@EndUserText.label: 'Real Estate Settlement Unit'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: ['InternalRealEstateNumber']
@ObjectModel.semanticKey: ['CompanyCode', 'REBusinessEntity', 'REServiceChargeKey' , 'RESettlementUnitID']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #BASIC
@Analytics.internalName:#LOCAL
@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}

@Metadata.allowExtensions: true
@AccessControl.privilegedAssociations: [ '_StatusObject', '_StatusObjectStatus'  ]


define view I_RESettlementUnit
  as select from viscsu as _RESettlementUnit
  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_User                       as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _ChangedByUser              on  $projection.LastChangedByUser = _ChangedByUser.UserID
  association [0..1] to I_User                       as _ResponsibleUser            on  $projection.Responsible = _ResponsibleUser.UserID
  association [0..1] to I_RECreationType             as _RECreationType             on  $projection.RECreationType = _RECreationType.RECreationType
  association [1..1] to I_REKeyAssgmt                as _REKeyAssgmt                on  $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
  association [1..1] to I_REObjectType               as _REObjectType               on  $projection.RealEstateObjectType = _REObjectType.RealEstateObjectType
  association [0..1] to I_REAuthorizationGroup       as _REAuthorizationGroup       on  $projection.REAuthorizationGroup = _REAuthorizationGroup.REAuthorizationGroup
                                                                                    and $projection.RealEstateObjectType = _REAuthorizationGroup.RealEstateObjectType
  association [0..1] to I_RETenancyLaw               as _RETenancyLaw               on  $projection.RETenancyLaw = _RETenancyLaw.RETenancyLaw
  association [0..1] to I_StatusObject               as _StatusObject               on  $projection.REStatusObject = _StatusObject.StatusObject
  association [1..*] to I_StatusObjectStatus         as _StatusObjectStatus         on  $projection.REStatusObject = _StatusObjectStatus.StatusObject
  association [0..1] to I_REObjectAddress            as _ObjectAddress              on  $projection.InternalRealEstateNumber = _ObjectAddress.InternalRealEstateNumber
  association [1..1] to I_REBusinessEntity           as _REBusinessEntity           on  $projection.CompanyCode    = _REBusinessEntity.CompanyCode
                                                                                    and $projection.REBusinessEntity = _REBusinessEntity.REBusinessEntity
  association [1..1] to I_REServiceChargeKey         as _REServiceChargeKey         on  $projection.REServiceChargeKey = _REServiceChargeKey.REServiceChargeKey

  association [0..1] to I_REDataExchangeType         as _REDataExchangeType         on  $projection.REDataExchangeType = _REDataExchangeType.REDataExchangeType
  association [0..1] to I_REAdvancedPaytSetldByCo    as _REAdvancedPaytSetldByCo    on  $projection.REAdvancedPaytSetldByCo = _REAdvancedPaytSetldByCo.REAdvancedPaytSetldByCo

  //  children

  association [0..*] to I_REPartnerAssgmt            as _REPartnerAssgmt            on  $projection.InternalRealEstateNumber = _REPartnerAssgmt.InternalRealEstateNumber
  association [1..*] to I_REOrganizationalAssgmtTerm as _REOrganizationalAssgmtTerm on  $projection.InternalRealEstateNumber = _REOrganizationalAssgmtTerm.InternalRealEstateNumber
  association [0..*] to I_REReminderObjRule          as _REReminderRule             on  $projection.InternalRealEstateNumber = _REReminderRule.InternalRealEstateNumber
{
  key intreno                                      as InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      bukrs                                        as CompanyCode,
      cast(swenr as rebdvdmbeno preserving type)   as REBusinessEntity,
      @ObjectModel.foreignKey.association: '_REServiceChargeKey'
      cast(snksl as rescvdmsckey preserving type ) as REServiceChargeKey,
      cast(sempsl as rescvdmsuid preserving type ) as RESettlementUnitID,
      @ObjectModel.foreignKey.association: '_StatusObject'
      objnr                                        as REStatusObject,
      cast(imkey as recaimkeyfi preserving type)   as REInternalFinNumber,
      @ObjectModel.foreignKey.association: '_RECreationType'
      creationtype                                 as RECreationType,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      rerf                                         as CreatedByUser,
      derf                                         as CreationDate,
      terf                                         as CreationTime,
      reher                                        as RESourceOfCreation,
      @ObjectModel.foreignKey.association: '_ChangedByUser'
      rbear                                        as LastChangedByUser,
      dbear                                        as LastChangeDate,
      tbear                                        as LastChangeTime,
      rbher                                        as RESourceOfChange,
      @ObjectModel.foreignKey.association: '_ResponsibleUser'
      responsible                                  as Responsible,
      userexclusive                                as REUserExclusive,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      authgrp                                      as REAuthorizationGroup,
      @Semantics.businessDate.from: true
      cast( validfrom as rebdvdmvalidfrom )        as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( validto as rebdvdmvalidto )            as ValidityEndDate,
      xsu                                          as RESettlementUnitName,
      sutype                                       as RESettlementUnitType,
      @ObjectModel.foreignKey.association: '_RETenancyLaw'
      tenancylaw                                   as RETenancyLaw,
      hascostobject                                as RESettlementUnitHasCostObject,
      notaxcorr                                    as RESettlementUnitHasNoInputTax,
      @ObjectModel.foreignKey.association: '_REDataExchangeType'
      exchangetype                                 as REDataExchangeType,
      @ObjectModel.foreignKey.association: '_REAdvancedPaytSetldByCo'
      settladvpay                                  as REAdvancedPaytSetldByCo,
      perheating                                   as RERateOfBasicHeatingCostValue,
      perhotwater                                  as RERateOfHotWaterBasicCostValue,
      msucrossovercc                               as REIndepMasterSettlmtIsAllowed,
      
      @ObjectModel.foreignKey.association: '_REObjectType'
      _REKeyAssgmt.RealEstateObjectType            as RealEstateObjectType,
      _REKeyAssgmt.REIdentificationKey             as REIdentificationKey,

      _CompanyCode,
      _CreatedByUser,
      _ChangedByUser,
      _ResponsibleUser,
      _RECreationType,
      _REAuthorizationGroup,
      _REKeyAssgmt,
      _RETenancyLaw,
      _StatusObject,
      _StatusObjectStatus,
      _ObjectAddress,
      _REBusinessEntity,
      _REServiceChargeKey,

      _REDataExchangeType,
      _REAdvancedPaytSetldByCo,
      _REObjectType,

      _REPartnerAssgmt,
      _REOrganizationalAssgmtTerm,
      _REReminderRule

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REKEYASSGMT",
"VISCSU"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_READVANCEDPAYTSETLDBYCO",
"I_REAUTHORIZATIONGROUP",
"I_REBUSINESSENTITY",
"I_RECREATIONTYPE",
"I_REDATAEXCHANGETYPE",
"I_REKEYASSGMT",
"I_REOBJECTADDRESS",
"I_REOBJECTTYPE",
"I_REORGANIZATIONALASSGMTTERM",
"I_REPARTNERASSGMT",
"I_REREMINDEROBJRULE",
"I_RESERVICECHARGEKEY",
"I_RETENANCYLAW",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/