I_REObjectTypeText

@AbapCatalog.sqlViewName: 'IREOBJTYPET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED // #CHECK

@EndUserText.label: 'Real Estate Object Type - Text'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'RealEstateObjectType'
@VDM.viewType: #BASIC
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@Search.searchable: true

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass:  #META

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.modelingPattern:           #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities:  [  #LANGUAGE_DEPENDENT_TEXT, 
                                        #SQL_DATA_SOURCE, 
                                        #EXTRACTION_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE, 
                                        #CDS_MODELING_ASSOCIATION_TARGET ]

@Analytics:{
    dataExtraction: {
        enabled: true
    }
}

define view I_REObjectTypeText

  as select from tbo01
  association [1..1] to I_REObjectType as _REObjectType on $projection.RealEstateObjectType = _REObjectType.RealEstateObjectType
  association [0..1] to I_Language     as _Language     on $projection.Language = _Language.Language
{

      @Semantics.language: true
  key spras                                              as Language,
      @ObjectModel.text.element: 'RealEstateObjectTypeDesc'
  key cast(obart as recaobjtype preserving type )            as RealEstateObjectType,
      obart_ld as REObjectTypePrefix,
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      cast(txt20 as recavdmxobjtype preserving type )  as RealEstateObjectTypeName,
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      cast (txt60 as recadesc60 preserving type ) as RealEstateObjectTypeDesc,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _REObjectType,
      _Language 
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TBO01"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_REOBJECTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/