I_REBuilding

@AbapCatalog.sqlViewName: 'IREBUILDING'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: ['_REPartnerAssgmt._BusinessPartner.IsBusinessPurposeCompleted']

@EndUserText.label: 'Real Estate Building'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.semanticKey: ['CompanyCode', 'REBusinessEntity', 'RealEstateBuilding']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #BASIC
@Analytics.internalName:#LOCAL
@Analytics:{
    dataCategory: #DIMENSION,

    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}

@Metadata.allowExtensions: true
@AccessControl.privilegedAssociations: [ '_StatusObject', '_StatusObjectStatus'  ]


define view I_REBuilding
  as select from vibdbu as _REBuilding
  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_User                       as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _ChangedByUser              on  $projection.LastChangedByUser = _ChangedByUser.UserID
  association [0..1] to I_User                       as _ResponsibleUser            on  $projection.Responsible = _ResponsibleUser.UserID
  association [0..1] to I_Currency                   as _Currency                   on  $projection.Currency = _Currency.Currency
  association [0..1] to I_UnitOfMeasure              as _UnitOfMeasureCubic         on  $projection.RECubicUnit = _UnitOfMeasureCubic.UnitOfMeasure
  association [0..1] to I_RECreationType             as _RECreationType             on  $projection.RECreationType = _RECreationType.RECreationType
  association [1..1] to I_REKeyAssgmt                as _REKeyAssgmt                on  $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
  association [1..1] to I_REObjectType               as _REObjectType               on  $projection.RealEstateObjectType = _REObjectType.RealEstateObjectType
  association [0..1] to I_REAuthorizationGroup       as _REAuthorizationGroup       on  $projection.REAuthorizationGroup = _REAuthorizationGroup.REAuthorizationGroup
                                                                                    and $projection.RealEstateObjectType = _REAuthorizationGroup.RealEstateObjectType
  association [0..1] to I_StatusObject               as _StatusObject               on  $projection.REStatusObject = _StatusObject.StatusObject
  association [1..*] to I_StatusObjectStatus         as _StatusObjectStatus         on  $projection.REStatusObject = _StatusObjectStatus.StatusObject
  association [0..1] to I_REObjectAddress            as _REObjectAddress            on  $projection.InternalRealEstateNumber = _REObjectAddress.InternalRealEstateNumber
  association [1..1] to I_REBusinessEntity           as _REBusinessEntity           on  $projection.CompanyCode      = _REBusinessEntity.CompanyCode
                                                                                    and $projection.REBusinessEntity = _REBusinessEntity.REBusinessEntity

  association [0..1] to I_REObjectClassification     as _REObjectClassification     on  $projection.REBuildingType = _REObjectClassification.REObjectClassification
  association [0..1] to I_RELocationClass            as _RELocationClass            on  $projection.REListOfRentsLocationClass = _RELocationClass.REListOfRentsLocationClass
                                                                                    and $projection.REListOfRents              = _RELocationClass.REListOfRents
  association [0..1] to I_REMunicipality             as _REMunicipality             on  $projection.REMunicipalityKey = _REMunicipality.REMunicipalityKey
  association [0..1] to I_REObjectState              as _REObjectState              on  $projection.REBuildingStatus = _REObjectState.REObjectState
  association [0..1] to I_REInsuranceValueType       as _REInsuranceValueType       on  $projection.REInsuranceValueType = _REInsuranceValueType.REInsuranceValueType
  association [0..1] to I_REListOfRents              as _REListOfRents              on  $projection.REListOfRents = _REListOfRents.REListOfRents

  //  children

  association [0..*] to I_REPartnerAssgmt            as _REPartnerAssgmt            on  $projection.InternalRealEstateNumber = _REPartnerAssgmt.InternalRealEstateNumber
  association [0..*] to I_REObjectAssgmt             as _REObjectAssgmt             on  $projection.REStatusObject = _REObjectAssgmt.REStatusObjectSource
  association [1..*] to I_REOrganizationalAssgmtTerm as _REOrganizationalAssgmtTerm on  $projection.InternalRealEstateNumber = _REOrganizationalAssgmtTerm.InternalRealEstateNumber
  association [0..*] to I_REReminderObjRule          as _REReminderRule             on  $projection.InternalRealEstateNumber = _REReminderRule.InternalRealEstateNumber
  association [0..*] to I_REMeasurement              as _REMeasurement              on  $projection.InternalRealEstateNumber = _REMeasurement.InternalRealEstateNumber

{
  key intreno                                    as InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      bukrs                                      as CompanyCode,
      cast(swenr as rebdvdmbeno preserving type) as REBusinessEntity,
      cast(sgenr as rebdvdmbuno preserving type) as RealEstateBuilding,
      @ObjectModel.foreignKey.association: '_StatusObject'
      objnr                                      as REStatusObject,
      cast(imkey as recaimkeyfi preserving type) as REInternalFinNumber,
      @ObjectModel.foreignKey.association: '_RECreationType'
      creationtype                               as RECreationType,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      rerf                                       as CreatedByUser,
      derf                                       as CreationDate,
      terf                                       as CreationTime,
      reher                                      as RESourceOfCreation,
      @ObjectModel.foreignKey.association: '_ChangedByUser'
      rbear                                      as LastChangedByUser,
      dbear                                      as LastChangeDate,
      tbear                                      as LastChangeTime,
      rbher                                      as RESourceOfChange,
      @ObjectModel.foreignKey.association: '_ResponsibleUser'
      responsible                                as Responsible,
      userexclusive                              as REUserExclusive,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      authgrp                                    as REAuthorizationGroup,
      @Semantics.businessDate.from: true
      cast( validfrom as rebdvdmvalidfrom )      as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( validto as rebdvdmvalidto )          as ValidityEndDate,
      xgetxt                                     as REBuildingName,
      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode
      waers                                      as Currency,
      @ObjectModel.foreignKey.association: '_UnitOfMeasureCubic'
      reins                                      as RECubicUnit,
      @ObjectModel.foreignKey.association: '_REObjectClassification'
      rgebart                                    as REBuildingType,
      jerbbau                                    as REHeritableBuildingRight,
      @ObjectModel.foreignKey.association: '_REObjectState'
      rgebzust                                   as REBuildingStatus,
      ybaujahr                                   as REConstructionDate,
      ymodern                                    as REModernizationDate,
      yaufbau                                    as REReconstructionDate,
      dbaubegi                                   as REConstructionStartDate,
      @Semantics.amount.currencyCode: 'Currency'
      bbauwx                                     as REEstimatedConstructionCost,
      @Semantics.amount.currencyCode: 'Currency'
      bbauwaktx                                  as RECurrentBuildingPrice,
      @Semantics.amount.currencyCode: 'Currency'
      bdmcbmra                                   as REPerCubicMeterCost,
      dbaugene                                   as REBuildingPermitDate,
      xbaugene                                   as BuildingPermitNote,
      dbezugsf                                   as REReadyForOccupancyDate,
      dfertig                                    as RECompletionDate,
      dschluss                                   as REFinalInspectionDate,
      jdenkmal                                   as IsProtectedHistoricalSite,
      dbauvor                                    as REPlanningInquiryDate,
      dvorbes                                    as REPriorNoticeDate,
      dantbau                                    as REBuildingPermitApplDate,
      @Semantics.amount.currencyCode: 'Currency'
      beinheitwx                                 as REAssessedBuildingPrice,
      neinheitw                                  as REDtmndAssessedValueYear,
      @Semantics.amount.currencyCode: 'Currency'
      bverswrtx                                  as REInsurableFireDamageAmount,
      @ObjectModel.foreignKey.association: '_REInsuranceValueType'
      rverswrt                                   as REInsuranceValueType,
      dwirtub                                    as REEconomicTransferDate,
      dverkauf                                   as RESaleDate,
      dvrkplan                                   as REPlannedSaleDate,
      dnutzend                                   as REPlannedEndOfUsageDate,
      dfrdvon                                    as REPublicFundingStartDate,
      dfrdbis                                    as REPublicFundingEndDate,
      banzge                                     as NumberOfFloors,
      sunutza                                    as REMainUsageType,
      sstckbis                                   as HighestFloor,
      sliftbis                                   as ElevatorToFloor,
      augesch                                    as NumberOfBasements,
      @ObjectModel.foreignKey.association: '_RELocationClass'
      rlraloc                                    as REListOfRentsLocationClass,
      usesrlra                                   as REListOfRentsIsUsed,
      @ObjectModel.foreignKey.association: '_REMunicipality'
      gemeinde                                   as REMunicipalityKey,
      hascop                                     as RECurOccupancyPrincipleIsUsed,
      usgfunction                                as REFunctionOfObject,
      @ObjectModel.foreignKey.association: '_REListOfRents'
      _RELocationClass.REListOfRents             as REListOfRents,

      @ObjectModel.foreignKey.association: '_REObjectType'
      _REKeyAssgmt.RealEstateObjectType          as RealEstateObjectType,
      _REKeyAssgmt.REIdentificationKey,

      _CompanyCode,
      _CreatedByUser,
      _ChangedByUser,
      _ResponsibleUser,
      _Currency,
      _UnitOfMeasureCubic,
      _RECreationType,
      _REAuthorizationGroup,
      _REKeyAssgmt,
      _StatusObject,
      _StatusObjectStatus,
      _REObjectAddress,
      _REBusinessEntity,

      _REObjectClassification,
      _REObjectState,
      _REInsuranceValueType,
      _RELocationClass,
      _REMunicipality,
      _REListOfRents,
      _REObjectType,

      _REPartnerAssgmt,
      _REObjectAssgmt,
      _REOrganizationalAssgmtTerm,
      _REReminderRule,
      _REMeasurement

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REKEYASSGMT",
"I_RELOCATIONCLASS",
"VIBDBU"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_REAUTHORIZATIONGROUP",
"I_REBUSINESSENTITY",
"I_RECREATIONTYPE",
"I_REINSURANCEVALUETYPE",
"I_REKEYASSGMT",
"I_RELISTOFRENTS",
"I_RELOCATIONCLASS",
"I_REMEASUREMENT",
"I_REMUNICIPALITY",
"I_REOBJECTADDRESS",
"I_REOBJECTASSGMT",
"I_REOBJECTCLASSIFICATION",
"I_REOBJECTSTATE",
"I_REOBJECTTYPE",
"I_REORGANIZATIONALASSGMTTERM",
"I_REPARTNERASSGMT",
"I_REREMINDEROBJRULE",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/