I_PurchaseContract

@AbapCatalog.sqlViewName: 'IPURCHASECTR'
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Purchase Contract'
@VDM.viewType : #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.compositionRoot: true
//@ObjectModel.semanticKey:  [ 'PurchaseContract' ]

@ObjectModel.semanticKey:  [ 'ActivePurchasingDocument' ]
@ObjectModel.uniqueIdField: [ 'PurchaseContract' ]
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PurchaseContract'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.entityChangeStateId: 'LastChangeDateTime'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view I_PurchaseContract

  as select from R_PurchaseContract

  association [1..*] to I_PurchaseContractItem        as _PurchaseContractItem       on $projection.PurchaseContract = _PurchaseContractItem.PurchaseContract

  association [1..*] to I_PurchaseContractHistory     as _PurchaseContractHistory    on $projection.PurchaseContract = _PurchaseContractHistory.PurchaseContract

  association [1..1] to I_ReleaseCode                 as _ReleaseCode                on $projection.ReleaseCode = _ReleaseCode.ReleaseCode

  association [0..*] to I_PurchasingDocumentTypeText  as _PurchasingDocumentTypeText on $projection.PurchaseContractType = _PurchasingDocumentTypeText.PurchasingDocumentType

  association [0..*] to I_Purctrnotes                 as _Purctrnotes                on $projection.PurchaseContract = _Purctrnotes.PurchaseContract

  association [0..*] to I_Purctrpartners              as _PurCtrPartners             on $projection.PurchaseContract = _PurCtrPartners.PurchaseContract
  
  association [1..1] to I_PurContrVersionType         as _VersionType                on $projection.PurgDocChangeRequestStatus = _VersionType.PurgDocChangeRequestStatus

  ----Extension Association
  association [1..1] to E_PurchasingDocument          as _PurchasingDocument         on $projection.PurchaseContract = _PurchasingDocument.PurchasingDocument
  
  association [0..1] to I_PurContrVersionHistory      as _PurContrVersionHistory     on  $projection.PurchaseContract = _PurContrVersionHistory.PurchaseContract
                                                                               
  association [0..1] to I_PurgDocVersionReasonValHelp as _VersionReasonValHelp      on  $projection.purchasingdocversionreasoncode = _VersionReasonValHelp.PurchasingDocVersionReasonCode  

  association [0..1] to I_PurContrVersRelevance       as _VersionRelevance           on $projection.PurchaseContract = _VersionRelevance.PurchaseContract
{
  key PurchaseContract,

      PurchaseContractType,

      PurchasingDocumentCategory,

      LastChangeDateTime,

      @Semantics.businessDate.createdAt: true
      CreationDate,

      Supplier,

      CompanyCode,

      PurchasingOrganization,

      PurchasingGroup,

      @Semantics.currencyCode:true
      DocumentCurrency,

      IncotermsClassification,

      IncotermsTransferLocation,

      PaymentTerms,

      CashDiscount1Days,

      CashDiscount2Days,

      NetPaymentDays,

      CashDiscount1Percent,

      CashDiscount2Percent,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation: #NONE
      PurchaseContractTargetAmount,

      ValidityStartDate,

      ValidityEndDate,

      @ObjectModel.foreignKey.association: '_ReleaseCode'
      ReleaseCode,

      @Semantics.user.createdBy: true
      CreatedByUser,

      PurchasingDocumentDeletionCode,

      SupplyingSupplier,

      InvoicingParty,
      cast( ExchangeRate as wkurs) as ExchangeRate,
      ExchangeRateIsFixed,
      QuotationSubmissionDate,
      SupplierQuotation,
      CorrespncExternalReference,
      CorrespncInternalReference,
      SupplierRespSalesPersonName,
      SupplierPhoneNumber,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      IncotermsSupChnLoc1AddlUUID,
      IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,
      PurchasingDocumentName,
      PurchasingDocumentOrigin,
      ReleaseIsNotCompleted,
      PurchasingProcessingStatus,
      case ManualSupplierAddressID
        when '' then  _Supplier.AddressID
        else ManualSupplierAddressID
      end                          as SupplierAddressID,
      IsEndOfPurposeBlocked,
      PurgDocExternalReference,

      // fields from product compliance

      PurgAggrgdProdCmplncSuplrSts,
      PurgAggrgdProdMarketabilitySts,
      PurgAggrgdSftyDataSheetStatus,
      PurgProdCmplncTotDngrsGoodsSts,
      
      PurgHasCatalogRelevantItems,
      
      //Versioning in Purchase Contracts

      ActivePurchasingDocument,
      PurchasingDocumentVersion,
      PurgDocChangeRequestStatus,
      PurgDocIsChgVers,
      _PurContrVersionHistory.PurchasingDocVersionReasonCode,
      _VersionRelevance.VersionIsEnabled,
      
      _PurchasingDocumentCategory,
      _PurchasingDocumentType,
      _IncotermsClassification,
      _Supplier,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _CreatedByUser,
      _DocumentCurrency,
      _ReleaseCode,
      _SupplyingSupplier,
      _InvoicingParty,
      _PaymentTerms,
      //Versioning in Purchase Contracts

      _VersionType,
      _VersionReasonValHelp,
      _VersionRelevance,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _PurchaseContractItem,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Purctrnotes,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _PurCtrPartners
}
//Commented Tmporarily  

where
//Versioning

( PurgDocChangeRequestStatus = '' or PurgDocChangeRequestStatus = '2'  )  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCONTRVERSIONHISTORY",
"I_PURCONTRVERSRELEVANCE",
"I_SUPPLIER",
"R_PURCHASECONTRACT"
],
"ASSOCIATED":
[
"E_PURCHASINGDOCUMENT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_INCOTERMSCLASSIFICATION",
"I_PAYMENTTERMS",
"I_PURCHASECONTRACTHISTORY",
"I_PURCHASECONTRACTITEM",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURCONTRVERSIONHISTORY",
"I_PURCONTRVERSIONTYPE",
"I_PURCONTRVERSRELEVANCE",
"I_PURCTRNOTES",
"I_PURCTRPARTNERS",
"I_PURGDOCVERSIONREASONVALHELP",
"I_RELEASECODE",
"I_SUPPLIER",
"I_USER"
],
"BASE":
[
"R_PURCHASECONTRACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/