I_PPS_PurContrProcessFlow

//@JIRA_KEY: <S4PPS-7279>

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'PPS Process Flow for Purchase Contract'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #MIXED
}
define view entity I_PPS_PurContrProcessFlow
  as
  //PC

  select distinct from I_PurchaseContractItem as PCItem
    inner join         I_PurchaseContract     as PC on PCItem.PurchaseContract = PC.ActivePurchasingDocument //@JIRA-KEY<S4PPS-15594>

{
  key  PC.ActivePurchasingDocument                                              as PrecedingDocument, //@JIRA-KEY<S4PPS-15594>

  key  cast( cast (PCItem.PurchaseContractItem  as char10 ) as  abap.numc (6) ) as PrecedingDocumentItem,
  key  cast (' '  as vdm_purchaserequisition)                                   as SubsequentDocument,
  key  cast (' '  as  abap.numc (6))                                            as SubsequentDocumentItem,
       cast(cast ('K' as bstyp)    as char4)                                    as PrecedingDocumentCategory,
       cast (cast (' '  as bstyp)  as char4)                                    as SubsequentDocumentCategory,
       PCItem.PurchaseContract,
       PC.ActivePurchasingDocument                                              as ActivePurchasingDocument,
       PCItem.PurchaseContractItem,
       PCItem.PurchaseContractType,
       PC.PurchasingOrganization,
       PC.PurchasingGroup
}

//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

//PR -> PC

union all select distinct from I_Purchaserequisitionitem as PRItem
  //@JIRA-KEY<S4PPS-17802>

  inner join                   I_PurchaseContractItem    as PCItem on PRItem.PurchaseRequisition =  PCItem.PurchaseRequisition
                                                                   and  PRItem.PurchaseRequisitionItem = PCItem.PurchaseRequisitionItem
  inner join                   I_PurchaseContract        as PC     on PCItem.PurchaseContract = PC.ActivePurchasingDocument //@JIRA-KEY<S4PPS-15594>

{
  key  PRItem.PurchaseRequisition                                              as PrecedingDocument,
  key  cast( cast( PRItem.PurchaseRequisitionItem as char6 )as abap.numc (6) ) as PrecedingDocumentItem,
  key  PC.ActivePurchasingDocument                                             as SubsequentDocument, //@JIRA-KEY<S4PPS-15594>

  key  cast( cast( PCItem.PurchaseContractItem  as char6 ) as abap.numc (6) )  as SubsequentDocumentItem,
       cast(cast ('B' as bstyp) as char4)                                      as PrecedingDocumentCategory,
       cast(PCItem.PurchasingObjectCategory as char4)                          as SubsequentDocumentCategory,
       PCItem.PurchaseContract,
       PC.ActivePurchasingDocument                                             as ActivePurchasingDocument,
       PCItem.PurchaseContractItem,
       PCItem.PurchaseContractType,
       PC.PurchasingOrganization,
       PC.PurchasingGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASEREQUISITIONITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/