R_PurchaseContract

@AbapCatalog.sqlViewName: 'RPURCHASECTR'
@AbapCatalog.preserveKey:true
@VDM.viewType : #BASIC
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchase Contract Base View'
@ObjectModel.representativeKey: 'PurchaseContract'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL


define view R_PurchaseContract
  as select from R_PurchasingDocument
{
  key cast (PurchasingDocument as vdm_purchasecontract preserving type) as PurchaseContract,

      PurchasingDocumentType                                            as PurchaseContractType,

      PurchasingDocumentCategory,

      LastChangeDateTime,

      @Semantics.businessDate.createdAt: true
      CreationDate,

      Supplier,

      CompanyCode,

      PurchasingOrganization,

      PurchasingGroup,

      @Semantics.currencyCode:true
      DocumentCurrency,

      IncotermsClassification,

      IncotermsTransferLocation,

      PaymentTerms,

      CashDiscount1Days,

      CashDiscount2Days,

      NetPaymentDays,

      CashDiscount1Percent,

      CashDiscount2Percent,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation: #NONE
      TargetAmount                                                      as PurchaseContractTargetAmount,

      ValidityStartDate,

      ValidityEndDate,

      @ObjectModel.foreignKey.association: '_ReleaseCode'
      ReleaseCode,

      @Semantics.user.createdBy: true
      CreatedByUser,

      PurchasingDocumentDeletionCode,

      SupplyingSupplier,

      InvoicingParty,
      ExchangeRate,
      ExchangeRateIsFixed,
      QuotationSubmissionDate,
      SupplierQuotationExternalID                                       as SupplierQuotation,
      CorrespncExternalReference,
      CorrespncInternalReference,
      SupplierRespSalesPersonName,
      SupplierPhoneNumber,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      IncotermsSupChnLoc1AddlUUID,
      IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,
      PurchasingDocumentName,
      PurchasingDocumentOrigin,
      ReleaseIsNotCompleted,
      PurchasingProcessingStatus,
      ManualSupplierAddressID,
      IsEndOfPurposeBlocked,
      PurgDocExternalReference,

      // fields from product compliance

      PurgAggrgdProdCmplncSuplrSts,
      PurgAggrgdProdMarketabilitySts,
      PurgAggrgdSftyDataSheetStatus,
      PurgProdCmplncTotDngrsGoodsSts,
      
      PurgHasCatalogRelevantItems,
      //Versionining 

      ActivePurchasingDocument, 
      PurchasingDocumentVersion,
      PurgDocChangeRequestStatus,
      case PurgDocChangeRequestStatus
        when '2' then cast( 'X' as xfeld )
        else cast( '' as xfeld ) end                                           as PurgDocIsChgVers,      

      _PurchasingDocumentCategory,
      _PurchasingDocumentType,
      _IncotermsClassification,
      _Supplier,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _CreatedByUser,
      _DocumentCurrency,
      _ReleaseCode,
      _SupplyingSupplier,
      _InvoicingParty,
      _PaymentTerms
}
where
      PurchasingDocumentCategory = 'K'
  and IsEndOfPurposeBlocked      = ''
  and ( PurgDocChangeRequestStatus = '' or
        PurgDocChangeRequestStatus = '1' or
        PurgDocChangeRequestStatus = '2' or
        PurgDocChangeRequestStatus = '4' )     
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PURCHASINGDOCUMENT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_INCOTERMSCLASSIFICATION",
"I_PAYMENTTERMS",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_RELEASECODE",
"I_SUPPLIER",
"I_USER"
],
"BASE":
[
"R_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/