I_PurchasingDocumentTypeText

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.dataCategory: #TEXT
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PurchasingDocumentType'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.supportedCapabilities: [ #SEARCHABLE_ENTITY, #LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@AbapCatalog.sqlViewName: 'IMMPURGDOCTYPTXT'
@EndUserText.label: 'Purchasing Document Type - Text'
@AccessControl.authorizationCheck:#NOT_REQUIRED
@VDM.viewType : #BASIC
@Search.searchable: true
@Analytics.dataExtraction.enabled: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations:true

define view I_PurchasingDocumentTypeText
  as select from t161t
  association        to parent I_PurchasingDocumentType as _PurchasingDocumentType     on  $projection.PurchasingDocumentCategory = _PurchasingDocumentType.PurchasingDocumentCategory
                                                                                       and $projection.PurchasingDocumentType     = _PurchasingDocumentType.PurchasingDocumentType
  association [1..1] to I_PurchasingDocumentCategory    as _PurchasingDocumentCategory on  $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory

  association [0..1] to I_Language                      as _Language                   on  $projection.Language = _Language.Language


{
      @ObjectModel.foreignKey.association: '_PurchasingDocumentType'
      @ObjectModel.text.element: ['PurchasingDocumentTypeName']
  key bsart as PurchasingDocumentType,
      @ObjectModel.foreignKey.association: '_PurchasingDocumentCategory'
  key bstyp as PurchasingDocumentCategory,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key spras as Language,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @Semantics.text: true
      batxt as PurchasingDocumentTypeName,

      _PurchasingDocumentType,
      _PurchasingDocumentCategory,
      _Language

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T161T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/