C_PurchaseContractValHelp

@AbapCatalog.sqlViewName: 'CPURCONTRVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Value help for Purchase Contract'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.dataCategory:#VALUE_HELP
@AccessControl.personalData.blocking:  #NOT_REQUIRED
@Search.searchable: true
@Consumption.ranked: true
define view C_PurchaseContractValHelp
  as select from I_PurchaseContract as PurchaseContract

  association [0..1] to C_PurchasingOrgValueHelp   as _PurchasingOrgValueHelp   on _PurchasingOrgValueHelp.PurchasingOrganization = $projection.PurchasingOrganization

  association [0..1] to C_PurchasingGroupValueHelp as _PurchasingGroupValueHelp on _PurchasingGroupValueHelp.PurchasingGroup = $projection.PurchasingGroup

  association [0..*] to C_MM_SupplierValueHelp     as _SupplierValueHelp        on _SupplierValueHelp.Supplier = $projection.Supplier

{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }          //2725448

      @UI.lineItem: { position: 10, importance: #HIGH }
      @EndUserText.quickInfo: 'Purchase Contract'
  key PurchaseContract.PurchaseContract,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @UI.lineItem: { position: 30, importance: #HIGH }
      @Consumption.valueHelp: '_SupplierValueHelp'
      PurchaseContract.Supplier,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
      @Semantics.currencyCode: true
      PurchaseContract.DocumentCurrency,
      
      @UI.lineItem: { position: 50, importance: #HIGH }
      case PurchaseContract.ValidityStartDate
       when (' ') then '00000000'
       else PurchaseContract.ValidityStartDate
       end as ValidityStartDate,

      @UI.lineItem: { position: 60, importance: #HIGH }
      case PurchaseContract.ValidityEndDate
      when (' ') then '00000000'
      else PurchaseContract.ValidityEndDate
      end  as ValidityEndDate,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
      @ObjectModel.foreignKey.association: '_PurchasingOrgValueHelp'
      @Consumption.valueHelp: '_PurchasingOrgValueHelp'
      @UI.lineItem: { position: 45, importance: #HIGH }
      PurchaseContract.PurchasingOrganization,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
      @ObjectModel.foreignKey.association: '_PurchasingGroupValueHelp'
      @Consumption.valueHelp: '_PurchasingGroupValueHelp'
      PurchaseContract.PurchasingGroup,

      _PurchasingOrgValueHelp,
      _PurchasingGroupValueHelp,
      _SupplierValueHelp
}
where
      PurchaseContract.PurchasingDocumentDeletionCode = ' '
  and PurchaseContract.PurchasingDocumentCategory     = 'K'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASECONTRACT"
],
"ASSOCIATED":
[
"C_MM_SUPPLIERVALUEHELP",
"C_PURCHASINGGROUPVALUEHELP",
"C_PURCHASINGORGVALUEHELP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/