I_OpActyComponentAssignment

@AbapCatalog.sqlViewName: 'IMPEOACOMPASS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Activity Instance Comp Assign'
define view I_OpActyComponentAssignment
  as select from mpe_comp_oai as oai
  association [1..1] to I_OpActyNtwkInstance         as _OpActyNtwkInstance         on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OpActyNtwkInstanceBasic    as _OpActyNtwkInstanceBasic    on  $projection.OpActyNtwkInstance = _OpActyNtwkInstanceBasic.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance  as _OperationActivityInstance  on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_ReservationDocumentHeader  as _ReservationHeader          on  $projection.Reservation = _ReservationHeader.Reservation
  association [0..1] to I_OpActyComponentAssignment  as _ReltdOpActyCompAssignment  on  $projection.OpActyNtwkInstance = _ReltdOpActyCompAssignment.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _ReltdOpActyCompAssignment.OpActyNtwkElement
                                                                                    and $projection.Reservation        = _ReltdOpActyCompAssignment.Reservation
                                                                                    and $projection.ReservationItem    = _ReltdOpActyCompAssignment.ReservationItem
                                                                                    and $projection.RecordType         = _ReltdOpActyCompAssignment.RecordType
  association [1..1] to I_PlannedInventoryUsblyCode  as _PlannedInventoryUsblyCode  on  $projection.PlannedInventoryUsabilityCode = _PlannedInventoryUsblyCode.PlannedInventoryUsabilityCode
  association [0..1] to I_BOMItmMfgRefStrucItmAssgmt as _BOMItmMfgRefStrucItmAssgmt on  $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
  association [0..1] to I_MfgRefStrucItemWithDetails as _MfgRefStrucItemWithDetails on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails  as _MfgRefHierItemWithDetails  on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key oai.oan_instance_id           as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key oai.oan_element_number        as OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_ReservationHeader'
  key oai.rsnum                     as Reservation,
  key oai.rspos                     as ReservationItem,
  key oai.rsart                     as RecordType,
      oai.usage_qty                 as MfgOrderComponentUsageQuantity,
      oai.usage_net_qty             as MfgOrderComponentUsageNetQty,
      oai.sequence_no               as AssemblySequenceNumber,
      oai.zuonr                     as BOOOpBOMItemInternalID,
      oai.log_comp_counter          as LogicalComponent,
      oai.assembly_type             as ComponentAssemblyType,
      oai.rsnum_reference           as RelatedReservation,
      oai.rspos_reference           as RelatedReservationItem,
      oai.rsart_reference           as RelatedRecordType,
      oai.oani_id_reference         as RelatedOpActyNtwkInstance,
      oai.oan_elem_no_reference     as RelatedOpActyNtwkElement,
      oai.instance_assembly_rqd     as MatlCompInstceAssyIsRequired,
      oai.mpe_stock_type            as PlannedInventoryUsabilityCode,
      oai.rsnum_top_reference       as LeadingReservation,
      oai.rspos_top_reference       as LeadingReservationItem,
      oai.rsart_top_reference       as LeadingReservationRecordType,
      oai.oani_id_top_reference     as LeadingOpActyNtwkInstance,
      oai.oan_elem_no_top_reference as LeadingOpActyNtwkElement,
      mrs_leaf_assignment_uuid      as MfgRefStrucBOMLeafAssgmtUUID,
      mrs_item_detail_uuid          as MfgRefStructureItemDetailUUID,
      mrs_item_detail_is_contextual as MfgRefStrucItmDetIsContextual,

      _OpActyNtwkInstance,
      _OpActyNtwkInstanceBasic,
      _OperationActivityInstance,
      _ReservationHeader,
      _ReltdOpActyCompAssignment,
      _PlannedInventoryUsblyCode,
      _BOMItmMfgRefStrucItmAssgmt,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MPE_COMP_OAI"
],
"ASSOCIATED":
[
"I_BOMITMMFGREFSTRUCITMASSGMT",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINSTANCEBASIC",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANNEDINVENTORYUSBLYCODE",
"I_RESERVATIONDOCUMENTHEADER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/