I_OpActyNtwkInstanceBasic

@AbapCatalog.sqlViewName: 'IMPEOANINSTB'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true 
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@ObjectModel.representativeKey: 'OpActyNtwkInstance'
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Activity Network Instance'
define view I_OpActyNtwkInstanceBasic
  as select from mpe_oan_instance as oan
  association [1..1] to I_OpActyNtwkInternalID        as _OpActyNtwkInternalId     on  $projection.OperationActivityNetwork = _OpActyNtwkInternalId.OperationActivityNetwork
  association [1..1] to I_OperationActivityNetwork    as _OperationActivityNetwork on  $projection.OperationActivityNetwork = _OperationActivityNetwork.OperationActivityNetwork
                                                                                   and $projection.OpActyNtwkVersionCounter = _OperationActivityNetwork.OpActyNtwkVersionCounter
  association [1..1] to I_MfgOrder                    as _MfgOrder                 on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_ManufacturingOrder          as _ManufacturingOrder       on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderOperation           as _MfgOrderOperation        on  $projection.OrderInternalID          = _MfgOrderOperation.OrderInternalBillOfOperations
                                                                                   and $projection.OrderOperationInternalID = _MfgOrderOperation.OrderIntBillOfOperationsItem
  association [1..1] to I_OrderOperation              as _OrderOperation           on  $projection.OrderInternalID          = _OrderOperation.OrderInternalID
                                                                                   and $projection.OrderOperationInternalID = _OrderOperation.OrderOperationInternalID
  association [1..1] to I_OrderOperationBasic         as _OrderOperationBasic      on  $projection.OrderInternalID          = _OrderOperationBasic.OrderInternalID
                                                                                   and $projection.OrderOperationInternalID = _OrderOperationBasic.OrderOperationInternalID

  association [1..1] to I_OrdInternalBillOfOperations as _OrderInternalID          on  $projection.OrderInternalID = _OrderInternalID.OrderInternalBillOfOperations
{
  key oan.oan_instance_id                             as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInternalId'
      oan.oan_id                                      as OperationActivityNetwork,
      @ObjectModel.foreignKey.association: '_OperationActivityNetwork'
      oan.oan_version_no                              as OpActyNtwkVersionCounter,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      oan.aufnr                                       as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_OrderInternalID'
      oan.aufpl                                       as OrderInternalID,
      oan.aplzl                                       as OrderOperationInternalID,
      oan.sfi_conf                                    as OpActyConfIsSFIBased,
      oan.conf_allwd                                  as OpActyConfirmationIsAllowed,
      oan.conf_not_allwd_rsn                          as OpActyConfNotAllowedReason,

      _OpActyNtwkInternalId,
      _OperationActivityNetwork,
      _OrderInternalID,
      _MfgOrder,
      _ManufacturingOrder,
      _MfgOrderOperation,
      _OrderOperation,
      _OrderOperationBasic
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MPE_OAN_INSTANCE"
],
"ASSOCIATED":
[
"I_MANUFACTURINGORDER",
"I_MFGORDER",
"I_MFGORDEROPERATION",
"I_OPACTYNTWKINTERNALID",
"I_OPERATIONACTIVITYNETWORK",
"I_ORDEROPERATION",
"I_ORDEROPERATIONBASIC",
"I_ORDINTERNALBILLOFOPERATIONS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/