I_OperationActivityPlndMatlRet

@AbapCatalog.sqlViewName: 'IMPEOAPLNDMATRET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Activity Planned Material Return'
define view I_OperationActivityPlndMatlRet
  as select from I_OpActyComponentAssignment as OpActyComponentAssignment
    inner join   P_MfgOrderOpReservationItem as ReservationItem on  ReservationItem.rsnum = OpActyComponentAssignment.Reservation
                                                                and ReservationItem.rspos = OpActyComponentAssignment.ReservationItem
                                                                and ReservationItem.rsart = OpActyComponentAssignment.RecordType

  association [0..1] to I_BillOfMaterialItemCategory as _BOMItemCategory on $projection.BOMItemCategory = _BOMItemCategory.BillOfMaterialItemCategory
{
  key OpActyComponentAssignment.OpActyNtwkInstance,
  key OpActyComponentAssignment.OpActyNtwkElement,
  key OpActyComponentAssignment.Reservation,
  key OpActyComponentAssignment.ReservationItem,
  key OpActyComponentAssignment.RecordType,
  key ReservationItem.matnr                                             as Material,
  key ReservationItem.werks                                             as Plant,
      ReservationItem.pwerk                                             as ProductionPlant,
      cast(ReservationItem.lgort as pph_lgort preserving type)          as StorageLocation,
      cast(ReservationItem.aufnr as manufacturingorder preserving type) as ManufacturingOrder,
      ReservationItem.kzkup                                             as MaterialIsCoProduct,
      ReservationItem.afpos                                             as ManufacturingOrderItem,
      OpActyComponentAssignment.AssemblySequenceNumber                  as AssemblySequenceNumber,
      ReservationItem.meins                                             as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      OpActyComponentAssignment.MfgOrderComponentUsageQuantity          as MfgOrderComponentUsageQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      OpActyComponentAssignment.MfgOrderComponentUsageQuantity          as MfgOrderComponentUsageNetQty,
      cast( ReservationItem.schgt as boolean preserving type )          as IsBulkMaterialComponent,
      cast( ReservationItem.rgekz as boolean preserving type )          as MatlCompIsMarkedForBackflush,
      ReservationItem.xwaok                                             as GoodsMovementIsAllowed,
      ReservationItem.kzaus                                             as MatlCompDiscontinuationType,
      -- Variable-Size Item Fields
      ReservationItem.rohps                                             as MaterialCompIsVariableSized,
      ReservationItem.roame                                             as VariableSizeItemUnit,
      ReservationItem.rform                                             as FormulaKey,
      ReservationItem.roms1                                             as VariableSizeDimension1,
      ReservationItem.roms2                                             as VariableSizeDimension2,
      ReservationItem.roms3                                             as VariableSizeDimension3,
      ReservationItem.romei                                             as VariableSizeDimensionUnit,
      cast(ReservationItem.romen as pph_romen preserving type )         as VariableSizeComponentQuantity,
      cast(ReservationItem.rokme as pph_rokme preserving type )         as VariableSizeComponentUnit,
      ReservationItem.objnr                                             as MaterialComponentObject,
      ReservationItem.aufpl                                             as OrderInternalID,
      ReservationItem.aplzl                                             as OrderOperationInternalID,
      OpActyComponentAssignment.RelatedReservation                      as RelatedReservation,
      OpActyComponentAssignment.RelatedReservationItem                  as RelatedReservationItem,
      OpActyComponentAssignment.RelatedRecordType                       as RelatedRecordType,
      OpActyComponentAssignment.RelatedOpActyNtwkInstance               as RelatedOpActyNtwkInstance,
      OpActyComponentAssignment.RelatedOpActyNtwkElement                as RelatedOpActyNtwkElement,
      OpActyComponentAssignment.LeadingReservation                      as LeadingReservation,
      OpActyComponentAssignment.LeadingReservationItem                  as LeadingReservationItem,
      OpActyComponentAssignment.LeadingReservationRecordType            as LeadingReservationRecordType,
      OpActyComponentAssignment.LeadingOpActyNtwkInstance               as LeadingOpActyNtwkInstance,
      OpActyComponentAssignment.LeadingOpActyNtwkElement                as LeadingOpActyNtwkElement,
      -- Additional data needed for corresponding association
      cast(ReservationItem.stlty as pph_stlty preserving type)          as BillOfMaterialCategory,
      ReservationItem.stlnr                                             as BillOfMaterialInternalID,
      ReservationItem.stlnr2                                            as BillOfMaterial,
      ReservationItem.stlal                                             as BillOfMaterialVariant,
      ReservationItem.stvkn                                             as InheritedBOMItemNode,
      cast(ReservationItem.stlkn as pph_stlkn preserving type)          as BOMItem,
      ReservationItem.bom_versn                                         as BillOfMaterialVersion,
      ReservationItem.stpoz                                             as BOMItemInternalChangeCount,
      cast(ReservationItem.postp as pph_postp preserving type)          as BOMItemCategory,
      OpActyComponentAssignment.BOOOpBOMItemInternalID                  as BOOOpBOMItemInternalID,
      OpActyComponentAssignment.LogicalComponent                        as LogicalComponent,
      OpActyComponentAssignment.MfgRefStrucBOMLeafAssgmtUUID            as MfgRefStrucBOMLeafAssgmtUUID,
      OpActyComponentAssignment.MfgRefStructureItemDetailUUID           as MfgRefStructureItemDetailUUID,
      OpActyComponentAssignment.MfgRefStrucItmDetIsContextual           as MfgRefStrucItmDetIsContextual,

      OpActyComponentAssignment.MatlCompInstceAssyIsRequired            as MatlCompInstceAssyIsRequired,
      OpActyComponentAssignment.PlannedInventoryUsabilityCode           as PlannedInventoryUsabilityCode,

      ReservationItem.techs                                             as EffectivityParameterVariant,
      ReservationItem.baugr                                             as Assembly,

      OpActyComponentAssignment._OpActyNtwkInstance,
      OpActyComponentAssignment._OpActyNtwkInstanceBasic,
      OpActyComponentAssignment._OperationActivityInstance,
      OpActyComponentAssignment._ReservationHeader,
      _BOMItemCategory,
      OpActyComponentAssignment._BOMItmMfgRefStrucItmAssgmt,
      OpActyComponentAssignment._MfgRefStrucItemWithDetails,
      OpActyComponentAssignment._MfgRefHierItemWithDetails
}
where
  ReservationItem.shkzg = 'S'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPACTYCOMPONENTASSIGNMENT",
"P_MFGORDEROPRESERVATIONITEM"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITMMFGREFSTRUCITMASSGMT",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINSTANCEBASIC",
"I_OPERATIONACTIVITYINSTANCE",
"I_RESERVATIONDOCUMENTHEADER"
],
"BASE":
[
"I_OPACTYCOMPONENTASSIGNMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/