I_LocationBasic

@AbapCatalog.sqlViewName:                      'ILOCATIONBASIC'

@Analytics:     {dataCategory:                 #DIMENSION,
                 dataExtraction:               {enabled: true}}
@ObjectModel:   {representativeKey:            'LocationUUID',
                 semanticKey:                  [ 'Location' ]}

@AbapCatalog.compiler.compareFilter:           true
@AbapCatalog.preserveKey:                      true
@AccessControl.authorizationCheck:             #CHECK
@AccessControl.personalData.blocking:          #REQUIRED
@AccessControl.personalData.blockingIndicator: [ 'IsBusinessPurposeCompleted', '_BusinessPartner.IsBusinessPurposeCompleted', '_CollaborationPartner.IsBusinessPurposeCompleted' ]
@AccessControl.privilegedAssociations:         [ '_AddrDfltRprstn' , '_AddrAddlRprstn' ]
@ClientHandling.algorithm:                     #SESSION_VARIABLE
@Metadata.allowExtensions:                     true
@ObjectModel.usageType.serviceQuality:         #C
@ObjectModel.usageType.sizeCategory:           #L
@ObjectModel.usageType.dataClass:              #MASTER
@VDM.lifecycle.contract.type:                  #NONE
@VDM.viewType:                                 #BASIC
@EndUserText.label:                            'Location'

// value help for this view:

// I_LocationBasicStdVH


define view I_LocationBasic
  as select from /sapapo/loc
  /* Business Object related Node Associations*/
  association [0..1] to I_BusinessPartner               as _CollaborationPartner  on $projection.CollaborationPartner = _CollaborationPartner.BusinessPartner
  association [0..1] to I_AddressDefaultRepresentation  as _AddrDfltRprstn        on $projection.AddressID = _AddrDfltRprstn.AddressID
  association [0..*] to I_Address_2                     as _AddrAddlRprstn        on $projection.AddressID = _AddrAddlRprstn.AddressID
                                                                                 and _AddrAddlRprstn.AddressRepresentationCode is not initial
  /* For given join condition, association cardinality is 0 to 1 only, so hinding cardinality warning message */
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to I_AddrOrgNamePostalAddress      as _PostalAddrDfltRprstn  on $projection.AddressID = _PostalAddrDfltRprstn.AddressID
                                                                                 and _PostalAddrDfltRprstn.AddressRepresentationCode is initial

  /* we use the view I_TMBusinessPartnerByIntKey instead of I_BusinessPartner here, because we have to resolve the asssociation
     via the BusinessPartnerUUID, which is not a key field in I_BusinessPartner */
  association [0..1] to I_TMBusinessPartnerByIntKey    as _BusinessPartner       on $projection.BusinessPartnerUUID = _BusinessPartner.BusinessPartnerUUID
  /* Foreign Key and Text Associations */
  association [0..*] to I_LocationText                 as _Text                  on $projection.LocationUUID = _Text.LocationUUID
  association [0..1] to I_LocationType                 as _LocationType          on $projection.LocationType = _LocationType.LocationType
  association [1..1] to P_LocationAuthGroupEval        as _LocationAuthGroupEval on $projection.LocationUUID = _LocationAuthGroupEval.LocationUUID
{
      @ObjectModel.text.association: '_Text'
  key cast( locid as /sapapo/location_id preserving type )             as LocationUUID,
      locno                                                            as Location,
      @ObjectModel.foreignKey.association: '_LocationType'
      loctype                                                          as LocationType,
      cast( loc_uuid as /sapapo/location_uuid preserving type )        as LocationAdditionalUUID,
      unlocode                                                         as LocationUNCode,
      iatacode                                                         as LocationIATACode,
      tzone                                                            as LocationTimeZone,
      osta_flag                                                        as LocationIsTemporary,
      @ObjectModel.foreignKey.association: '_AddrDfltRprstn'
      adrnummer                                                        as AddressID,
      locprio                                                          as LocationProcessingPriority,
      @ObjectModel.foreignKey.association: '_CollaborationPartner'
      cast( partner as /sapapo/collaboration_partner preserving type ) as CollaborationPartner,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      partner_guid                                                     as BusinessPartnerUUID,
      trailer_handling                                                 as LocationTrailerHandling,
      locloadprofile                                                   as LocationLoadingProfile,
      attequiprofile                                                   as AttachedEquipmentProfile,
      shipper_sec_sts                                                  as HandoverPartySecurityStatus,
      shipper_code                                                     as HandoverParty,
      shipper_validity                                                 as HandoverPartyExpiryDate,
      @Semantics.geoLocation.longitude: true
      @DefaultAggregation: #MIN
      xpos                                                             as Longitude,
      @Semantics.geoLocation.latitude: true
      @DefaultAggregation: #MIN
      ypos                                                             as Latitude,
      @Semantics.dateTime:true
      cast( geo_validity_end as tzntstmps preserving type )            as GeoCoordsValidityEndDateTime,
      gc_level                                                         as GeoCoordinatesLevel,
      strategy                                                         as GeoCoordinatesStrategy,
      match_gc                                                         as GeoCoordinatesMatchPercent,
      srcid                                                            as GeoCoordinatesDataSource,
      gis_zone                                                         as GeogrlInformationSystemZone,
      precisid                                                         as GeoCoordinatesPrecision,
      manually_changed_gc                                              as GeoCoordsAreManuallyChanged,
      locally_changed_gc                                               as GeoCoordsAreLocallyChanged,
      cast( createutc    as tzntstmpl )                                as CreationDateTime,
      createuser                                                       as CreatedByUser,
      cast( changeutc    as tzntstmps )                                as ChangedDateTime,
      changeuser                                                       as LastChangedByUser,
      lvorm                                                            as LocationIsMarkedForDeletion,
      cast( tpres_inb    as /sapapo/tpres_inb    preserving type )     as InboundLoadingResourceUUID,
      cast( tpres_out    as /sapapo/tpres_out    preserving type )     as OutboundLoadingResourceUUID,
      resflag                                                          as ResourceValidity,
      cast( time_res     as /sapapo/time_res_inb preserving type )     as InboundCalendarResourceUUID,
      cast( time_res_out as /sapapo/time_res_out preserving type )     as OutboundCalendarResourceUUID,
      gln                                                              as GlobalLocationNumber,
      duns4                                                            as LocationDUNSNumber,
      dpcal                                                            as SrvcPartsPlanningCalendar,
      capparm                                                          as NumberOfSTOSendingLocation,
      capparm_rcv                                                      as NumberOfSTOReceivingLocation,
      lgrad                                                            as TargetServiceLevelRatio,
      bntyp                                                            as LocationIsContractPackager,
      distr                                                            as LocationDeliveryIsSpecial,
      loc_xblck                                                        as IsBusinessPurposeCompleted,
      adv_shp_recv_rlv                                                 as LocationAdvncdShipgRcvgRlvnce,
      _LocationAuthGroupEval.AuthorizationGroup,

      /* Associations */
      _AddrDfltRprstn,
      _AddrAddlRprstn,
      _PostalAddrDfltRprstn,
      _CollaborationPartner,
      _BusinessPartner,
      _LocationType,
      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_LOCATIONAUTHGROUPEVAL",
"/SAPAPO/LOC"
],
"ASSOCIATED":
[
"I_ADDRESSDEFAULTREPRESENTATION",
"I_ADDRESS_2",
"I_ADDRORGNAMEPOSTALADDRESS",
"I_BUSINESSPARTNER",
"I_LOCATIONTEXT",
"I_LOCATIONTYPE",
"I_TMBUSINESSPARTNERBYINTKEY",
"P_LOCATIONAUTHGROUPEVAL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/