I_LocationAddressVH

@AbapCatalog.sqlViewName: 'ILOCADDR_VH'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'Location'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Location Value help with Address Attributes'
define view I_LocationAddressVH
  as select from I_LocationBasic
{

      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @UI: {lineItem: [ {position: 10, label: 'Location'} ]}
  key Location                                                        as Location,
      @Consumption.filter.hidden: true
      @UI.hidden: true
      LocationUUID,
      @Consumption.filter.hidden: true
      @UI.hidden: true
      BusinessPartnerUUID,
      @Consumption.filter.hidden: true
      @UI.hidden: true
      AuthorizationGroup,
      @Consumption.filter.hidden: true
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      IsBusinessPurposeCompleted,
      @UI: {lineItem: [ {position: 20, label: 'Location Description'} ]}
      @Search.defaultSearchElement: true
      _Text[1:Language= $session.system_language].LocationDescription as LocationDescription,

      LocationType                                                    as LocationType,

      @Semantics.address.country: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CountryVH', element: 'Country' } } ]
      _AddrDfltRprstn.Country                                         as Country,

      @Search.defaultSearchElement: true          
      _AddrDfltRprstn.CityName                                        as CityName,

      _AddrDfltRprstn.PostalCode                                      as PostalCode,

      _AddrDfltRprstn.StreetName                                      as StreetName,

      _AddrDfltRprstn.HouseNumber                                     as HouseNumber, 

      _BusinessPartner.BusinessPartner                                as BusinessPartner,

      GlobalLocationNumber                                            as GlobalLocationNumber,

      LocationDUNSNumber                                              as LocationDUNSNumber,

      LocationUNCode                                                  as LocationUNCode,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      LocationIATACode                                                as LocationIATACode,

      _BusinessPartner



}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSDEFAULTREPRESENTATION",
"I_LOCATIONBASIC",
"I_LOCATIONTEXT",
"I_TMBUSINESSPARTNERBYINTKEY"
],
"ASSOCIATED":
[
"I_TMBUSINESSPARTNERBYINTKEY"
],
"BASE":
[
"I_LOCATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/