R_LocationTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@VDM.viewType                                : #TRANSACTIONAL
@ObjectModel.usageType                       : { serviceQuality: #C,sizeCategory : #M,dataClass: #TRANSACTIONAL}
@AccessControl.authorizationCheck            : #MANDATORY
@ObjectModel.transactionalProcessingEnabled  : true
@ObjectModel.sapObjectNodeType.name          : 'Location'
@VDM.lifecycle.contract.type                 : #SAP_INTERNAL_API

define root view entity R_LocationTP 
  as select from I_LocationBasic                   as _LocationBasic
  
  composition [0..*] of R_LocationTextTP           as _LocationTextTP
  composition [0..1] of R_LocationAddressTP        as _LocationAddressTP
  composition [0..*] of R_LocationGeoCoordinatesTP as _LocationGeoCoordinatesTP
  
  association [0..1] to I_TranspUNLocationCode    as _TranspUNLocationCode   on _TranspUNLocationCode.LocationUNCode     = $projection.LocationUNCode
  association [0..1] to I_TranspIATALocationCode  as _TranspIATALocationCode on _TranspIATALocationCode.LocationIATACode = $projection.LocationIATACode
  association [0..1] to E_LocationBasic as _Extension on $projection.LocationUUID = _Extension.LocationUUID
  
{
  key LocationUUID,
      cast( Location as /sapapo/locno preserving type )              as Location,
      _LocationBasic.LocationType                                    as LocationType,
      LocationAdditionalUUID,
      cast( LocationTimeZone as tznzone preserving type )            as LocationTimeZone,
      GlobalLocationNumber,
      LocationDUNSNumber,
      cast( LocationUNCode as /sapapo/loc_unlocode preserving type ) as LocationUNCode,
      LocationIATACode,
      Longitude,
      Latitude,
      GeoCoordsValidityEndDateTime,
      GeoCoordinatesLevel,
      GeoCoordinatesStrategy,
      GeoCoordinatesMatchPercent,
      GeoCoordinatesDataSource,
      GeogrlInformationSystemZone,
      GeoCoordinatesPrecision,
      GeoCoordsAreManuallyChanged,
      GeoCoordsAreLocallyChanged,
      CreationDateTime                                               as CreationDateTime,
      CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      ChangedDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      ChangedDateTime                                                as LocalLastChangeDateTime,
      LastChangedByUser,
      LocationIsTemporary,
      IsBusinessPurposeCompleted,
      _LocationBasic.AddressID                                       as AddressID,
             
      /* Associations */
      _LocationType, 
      _TranspUNLocationCode,
      _TranspIATALocationCode,
          
      /* Composition */
      _LocationTextTP,
      _LocationAddressTP,
      _LocationGeoCoordinatesTP
}
where LocationType = '1001' or
      LocationType = '1002' or
      LocationType = '1003' or
      LocationType = '1020' or
      LocationType = '1021' or
      LocationType = '1030' or
      LocationType = '1040' or
      LocationType = '1100' or
      LocationType = '1110' or
      LocationType = '1120' or
      LocationType = '1130' or
      LocationType = '1140' or
      LocationType = '1150' or
      LocationType = '1160' or
      LocationType = '1170' or
      LocationType = '1180' or
      LocationType = '1190' or
      LocationType = '1191' or
      LocationType = '1200'
      
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONBASIC"
],
"ASSOCIATED":
[
"I_LOCATIONTYPE",
"I_TRANSPIATALOCATIONCODE",
"I_TRANSPUNLOCATIONCODE",
"R_LOCATIONADDRESSTP",
"R_LOCATIONGEOCOORDINATESTP",
"R_LOCATIONTEXTTP"
],
"BASE":
[
"I_LOCATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/