R_TrOrdStopLocAddrAddlRprstnTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY }
@EndUserText.label: 'Transp Ord Stop Loc Addr Addl Rpn - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['AddressID'],
    representativeKey: 'TransportationOrderStopUUID'
}

define view entity R_TrOrdStopLocAddrAddlRprstnTP
  as select from I_TransportationOrderStop as _TranspOrderStop
    inner join   I_LocationBasic           as _LocationBasic on _LocationBasic.LocationUUID = _TranspOrderStop.LocationUUID

    inner join   I_Address_2               as _Address_2     on  _Address_2.AddressID                 = _LocationBasic.AddressID
                                                             and _Address_2.AddressPersonID           = ' '
                                                             and _Address_2.AddressRepresentationCode is not initial

  association        to parent R_TrOrdStopLocAddrDfltRprstnTP as _TrOrdStopLocAddrDfltRprstn on $projection.TransportationOrderStopUUID = _TrOrdStopLocAddrDfltRprstn.TransportationOrderStopUUID
  association [1..1] to R_TransportationOrderTP               as _TransportationOrder        on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
{
  key _TranspOrderStop.TransportationOrderStopUUID            as TransportationOrderStopUUID,
      @ObjectModel.foreignKey.association: '_AddressRepresentationCode'
  key _Address_2.AddressRepresentationCode                    as AddressRepresentationCode,
      _TranspOrderStop.TransportationOrderUUID                as TransportationOrderUUID,

      // Identification for Address

      _Address_2.AddressID                                    as AddressID,
      _Address_2.AddressPersonID                              as AddressPersonID,

      // Postal Address

      _Address_2.AddresseeFullName                            as AddresseeFullName,
      _Address_2.AddressTimeZone                              as AddressTimeZone,
      _Address_2.CityName                                     as CityName,
      _Address_2.PostalCode                                   as PostalCode,
      _Address_2.StreetName                                   as StreetName,
      _Address_2.HouseNumber                                  as HouseNumber,
      _Address_2.Country                                      as Country,
      _Address_2.Region                                       as Region,

      // (Technical/Hidden) Attributes

      _TrOrdStopLocAddrDfltRprstn.TransportationOrderCategory as TransportationOrderCategory,

      _TransportationOrder,
      _TrOrdStopLocAddrDfltRprstn,
      _Address_2._AddressRepresentationCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_LOCATIONBASIC",
"I_TRANSPORTATIONORDERSTOP",
"R_TRORDSTOPLOCADDRDFLTRPRSTNTP"
],
"ASSOCIATED":
[
"I_ADDRESSREPRESENTATION",
"R_TRANSPORTATIONORDERTP",
"R_TRORDSTOPLOCADDRDFLTRPRSTNTP"
],
"BASE":
[
"I_ADDRESS_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/