I_LocationAnalytics

@EndUserText.label:                             'Location'

@AccessControl: {authorizationCheck:             #CHECK,
                 personalData.blocking:          #REQUIRED,
                 personalData.blockingIndicator: [ 'IsBusinessPurposeCompleted', '_BusinessPartner.IsBusinessPurposeCompleted', '_CollaborationPartner.IsBusinessPurposeCompleted' ]}

@ClientHandling.algorithm:                       #SESSION_VARIABLE

@Metadata:          {allowExtensions:             true,
                     ignorePropagatedAnnotations: true}

@AbapCatalog:       {sqlViewName:                 'ILOCATIONANA',
                     compiler.compareFilter:      true,
                     buffering:                   {status: #NOT_ALLOWED},
                     preserveKey:                 true}

@ObjectModel:       {representativeKey:           'Location',
                     semanticKey:                  [ 'Location' ],
                     usageType:                   {serviceQuality: #C,
                                                   sizeCategory:   #L,
                                                   dataClass:      #MASTER},
                     supportedCapabilities:        [ #ANALYTICAL_DIMENSION,
                                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                                     #SQL_DATA_SOURCE,
                                                     #CDS_MODELING_DATA_SOURCE,
                                                     #EXTRACTION_DATA_SOURCE] }

@VDM:               {viewType:                    #COMPOSITE}

@Analytics:         {dataCategory:                #DIMENSION,
                     dataExtraction:              {enabled: true},
                     internalName:                #LOCAL}

define view I_LocationAnalytics
  as select from I_LocationBasic as _Location
  association [0..1] to I_BusinessPartner       as _BusinessPartner      on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_BusinessPartner       as _CollaborationPartner on $projection.CollaborationPartner = _CollaborationPartner.BusinessPartner
  association [0..1] to I_UnitOfMeasure         as _GeoCoordinatesUnit   on $projection.GeoCoordinatesUnit = _GeoCoordinatesUnit.UnitOfMeasure
  association [0..*] to I_LocationAnalyticsText as _Text                 on $projection.Location = _Text.Location
  association [0..1] to I_LocationType          as _LocationType         on $projection.LocationType = _LocationType.LocationType

{
      @ObjectModel.text.association: '_Text'
  key Location,
      @Semantics.uuid:true
      LocationUUID,
      @ObjectModel.foreignKey.association: '_LocationType'
      LocationType,
      @Semantics.uuid:true
      LocationAdditionalUUID,
      AddressID,
      @ObjectModel.foreignKey.association: '_CollaborationPartner'
      CollaborationPartner,
      @Semantics.uuid:true
      BusinessPartnerUUID,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      _Location._BusinessPartner.BusinessPartner  as BusinessPartner,
      _Location.AuthorizationGroup                as AuthorizationGroup,
      @Semantics.booleanIndicator
      _Location.IsBusinessPurposeCompleted        as IsBusinessPurposeCompleted,

      @Semantics.geoLocation.latitude: true
      @Semantics.quantity.unitOfMeasure: 'GeoCoordinatesUnit'
      Latitude,
      @Semantics.geoLocation.longitude: true
      @Semantics.quantity.unitOfMeasure: 'GeoCoordinatesUnit'
      Longitude,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_GeoCoordinatesUnit'
      cast ( 'DEG' as /scmtms/vdm_geocoord_unit ) as GeoCoordinatesUnit, // /scmtms/vdm_geocoord_unit C1 released


      /* Associations */
      _BusinessPartner,
      _CollaborationPartner,
      _GeoCoordinatesUnit,
      _LocationType,
      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONBASIC",
"I_TMBUSINESSPARTNERBYINTKEY"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_LOCATIONANALYTICSTEXT",
"I_LOCATIONTYPE",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/