I_RESERVATIONITEM

@AbapCatalog.sqlViewName: 'IRESERVATIONIT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Reservation Item'

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define view I_ReservationItem
  as select from resb

  association [0..1] to I_DebitCreditCode           as _DebitCreditCode              on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [0..1] to I_Plant                     as _IssuingOrReceivingPlant      on  $projection.IssuingOrReceivingPlant = _IssuingOrReceivingPlant.Plant
  association [0..1] to I_Plant                     as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation           as _StorageLocation              on  $projection.StorageLocation = _StorageLocation.StorageLocation
                                                                                     and $projection.Plant           = _StorageLocation.Plant
  association [0..1] to I_StorageLocation           as _IssuingOrReceivingStorageLoc on  $projection.IssuingOrReceivingStorageLoc = _IssuingOrReceivingStorageLoc.StorageLocation
                                                                                     and $projection.IssuingOrReceivingPlant      = _IssuingOrReceivingStorageLoc.Plant
  association [0..1] to I_Material                  as _Material                     on  $projection.Material = _Material.Material
  association [0..1] to I_GoodsMovementType         as _GoodsMovementType            on  $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType
  association [0..1] to I_Currency                  as _Currency                     on  $projection.CompanyCodeCurrency = _Currency.Currency
  association [0..1] to I_PurchasingDocument        as _PurchasingDocument           on  $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
  association [0..1] to I_PurchasingDocumentItem    as _PurchasingDocumentItem       on  $projection.PurchasingDocument     = _PurchasingDocumentItem.PurchasingDocument
                                                                                     and $projection.PurchasingDocumentItem = _PurchasingDocumentItem.PurchasingDocumentItem
  association [0..1] to I_UnitOfMeasure             as _BaseUnit                     on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure             as _EntryUnit                    on  $projection.EntryUnit = _EntryUnit.UnitOfMeasure

  //RESB is a shared table and not every reservation item has a reservation header, hence 0..1 cardinality

  association [0..1] to I_ReservationHeader         as _ReservationHeader            on  $projection.Reservation = _ReservationHeader.Reservation

  association [0..1] to I_Supplier                  as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_SupplierCompanyByPlant    as _SupplierCompanyByPlant       on  $projection.Supplier = _SupplierCompanyByPlant.Supplier
                                                                                     and $projection.Plant    = _SupplierCompanyByPlant.Plant
  association [0..1] to I_InventorySpecialStockType as _InventorySpecialStockType    on  $projection.InventorySpecialStockType = _InventorySpecialStockType.InventorySpecialStockType
  association [0..1] to I_WBSElementBasicData       as _WBSElementBasicData          on  $projection.SpecialStockIdfgWBSElement = _WBSElementBasicData.WBSElementInternalID
  association [0..1] to I_Batch                     as _Batch                        on  $projection.Material = _Batch.Material
                                                                                     and $projection.Plant    = _Batch.Plant
                                                                                     and $projection.Batch    = _Batch.Batch
  association [0..1] to I_RecipientLocationCode    as _RecipientLocationCode         on  $projection.RecipientLocationCode = _RecipientLocationCode.RecipientLocationCode
  association [0..1] to I_ServiceDocumentItem       as _ServiceDocumentItem          on  $projection.ServiceObjectType   = _ServiceDocumentItem.ServiceObjectType
                                                                                     and $projection.ServiceDocument     = _ServiceDocumentItem.ServiceDocument
                                                                                     and $projection.ServiceDocumentItem = _ServiceDocumentItem.ServiceDocumentItem

{
  key  rsnum                   as Reservation,
  key  rspos                   as ReservationItem,
  key  rsart                   as RecordType,

       @ObjectModel.foreignKey.association: '_Material'
       matnr                   as Material,

       bdart                   as RequirementType,
       rssta                   as ReservationItemCreationCode,

       bdter                   as MatlCompRequirementDate,

       @ObjectModel.foreignKey.association: '_Plant'
       werks                   as Plant,

       vornr                   as ManufacturingOrderOperation,

       xwaok                   as GoodsMovementIsAllowed,

       @ObjectModel.foreignKey.association: '_StorageLocation'
       lgort                   as StorageLocation,

       @ObjectModel.foreignKey.association: '_Batch'
       charg                   as Batch,

       @ObjectModel.foreignKey.association: '_DebitCreditCode'
       shkzg                   as DebitCreditCode,

       @ObjectModel.foreignKey.association: '_BaseUnit'
       @Semantics.unitOfMeasure:true
       meins                   as BaseUnit,

       saknr                   as GLAccount,

       @Semantics.booleanIndicator: true
       ktoma                   as ResvnAccountIsEnteredManually,

       @ObjectModel.foreignKey.association: '_GoodsMovementType'
       bwart                   as GoodsMovementType,

       rgekz                   as MatlCompIsMarkedForBackflush,

       @Semantics.unitOfMeasure: true
       @ObjectModel.foreignKey.association: '_EntryUnit'
       erfme                   as EntryUnit,

       fmeng                   as QuantityIsFixed,

       @Semantics.currencyCode: true
       @ObjectModel.foreignKey.association: '_Currency'
       waers                   as CompanyCodeCurrency,

       @ObjectModel.foreignKey.association: '_IssuingOrReceivingPlant'
       umwrk                   as IssuingOrReceivingPlant,

       @ObjectModel.foreignKey.association: '_IssuingOrReceivingStorageLoc'
       umlgo                   as IssuingOrReceivingStorageLoc,

       @ObjectModel.foreignKey.association: '_PurchasingDocument'
       ebeln                   as PurchasingDocument,

       @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
       ebelp                   as PurchasingDocumentItem,

       @ObjectModel.foreignKey.association: '_BaseUnit'
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       bdmng                   as ResvnItmRequiredQtyInBaseUnit,

       kzear                   as ReservationItemIsFinallyIssued,

       xloek                   as ReservationItmIsMarkedForDeltn,

       @Semantics.quantity.unitOfMeasure: 'EntryUnit'
       erfmg                   as ResvnItmRequiredQtyInEntryUnit,
       @ObjectModel.foreignKey.association: '_BaseUnit'
       enmng                   as ResvnItmWithdrawnQtyInBaseUnit,
       @ObjectModel.foreignKey.association: '_BaseUnit'
       vmeng                   as ConfdQtyForATPInBaseUoM,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       enwrt                   as ResvnItmWithdrawnAmtInCCCrcy,

       @ObjectModel.foreignKey.association: '_Supplier'
       lifnr                   as Supplier,

       @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
       sobkz                   as InventorySpecialStockType,
       
       cast ( pspel as ps_s4_pspnr preserving type ) as SpecialStockIdfgWBSElement,

       dumps                   as MaterialComponentIsPhantomItem,

       schgt                   as IsBulkMaterialComponent,

       txtps                   as MatlCompIsTextItem,

       banfn                   as PurchaseRequisition,

       bnfpo                   as PurchaseRequisitionItem,

       aufnr                   as ReferenceOrder,

       -- for compatibility and performance reason - would be  empty in RAP object otherwise
       matkl                   as MaterialGroup,

       bdztp                   as ReservationQuantityRqmtTime,

       xfehl                   as MaterialComponentIsMissing,

       plnum                   as PlannedOrder,

       ebele                   as ScheduleLine,

       prvbe                   as ProductionSupplyArea,

       fmeng                   as IsComponentQuantityFixed,

       beikz                   as IsMaterialProvision,

       wempf                   as GoodsRecipientName,
       ablad                   as UnloadingPointName,
       sgtxt                   as ReservationItemText,

       dbskz                   as MaterialCompIsProcuredDirectly,

       umsok                   as IssgOrRcvgSpclStockInd,
       @ObjectModel.foreignKey.association: '_RecipientLocationCode'  
       recipient_location_code as RecipientLocationCode,

       header_bus_type         as ServiceObjectType,
       crm_header_id           as ServiceDocument,
       crms4_item_id           as ServiceDocumentItem,
       service_doc_type        as ResvnItmSrvcDocTypeAsAcctAsgt,
       service_doc_id          as ResvnItmSrvcDocAsAcctAsgt,
       service_doc_item_id     as ResvnItmSrvcDocItmAsAcctAsgt,



       _DebitCreditCode,
       _Plant,
       _IssuingOrReceivingPlant,
       _Material,
       _StorageLocation,
       _IssuingOrReceivingStorageLoc,
       _GoodsMovementType,
       _Currency,
       _PurchasingDocument,
       _PurchasingDocumentItem,
       _BaseUnit,
       _EntryUnit,
       _Supplier,
       _InventorySpecialStockType,
       _WBSElementBasicData,
       _Batch,

       @Consumption.hidden: true
       _SupplierCompanyByPlant,

       _ReservationHeader,
       _RecipientLocationCode,
       
       _ServiceDocumentItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"RESB"
],
"ASSOCIATED":
[
"I_BATCH",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_GOODSMOVEMENTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_MATERIAL",
"I_PLANT",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_RECIPIENTLOCATIONCODE",
"I_RESERVATIONHEADER",
"I_SERVICEDOCUMENTITEM",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/