P_ReservationItem

@AbapCatalog.sqlViewName: 'PRESERVITM'
@VDM.private: true
@VDM.viewType: #CONSUMPTION

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
--@AccessControl.authorizationCheck: #NOT_ALLOWED


@EndUserText.label: 'Reservation Item'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.status:#DEPRECATED
@VDM.lifecycle.successor: 'P_ProcmtDocSubcontrg'
define view P_ReservationItem
  as select from I_ReservationItem

  association [0..*] to I_MRPAreaSubcontractor as _MRPAreaSubcontractor on  _MRPAreaSubcontractor.MRPAreaPlant         = $projection.Plant
                                                                 and _MRPAreaSubcontractor.MRPAreaSubcontractor = $projection.Supplier


{

  key  Reservation,
  key  ReservationItem,
  key  RecordType,

       @ObjectModel.foreignKey.association: '_Material'
       Material,

       _MRPAreaSubcontractor.MRPArea,

       RequirementType,

       MatlCompRequirementDate,

       @ObjectModel.foreignKey.association: '_Plant'
       Plant,

       ManufacturingOrderOperation,

       GoodsMovementIsAllowed,

       @ObjectModel.foreignKey.association: '_StorageLocation'
       StorageLocation,

       @ObjectModel.foreignKey.association: '_Batch'
       Batch,

       @ObjectModel.foreignKey.association: '_DebitCreditCode'
       DebitCreditCode,

       @ObjectModel.foreignKey.association: '_BaseUnit'
       @Semantics.unitOfMeasure:true
       BaseUnit,

       GLAccount,

       @ObjectModel.foreignKey.association: '_GoodsMovementType'
       GoodsMovementType,

       @Semantics.unitOfMeasure: true
       @ObjectModel.foreignKey.association: '_EntryUnit'
       EntryUnit,

       QuantityIsFixed,

       @Semantics.currencyCode: true
       @ObjectModel.foreignKey.association: '_Currency'
       CompanyCodeCurrency,

       @ObjectModel.foreignKey.association: '_IssuingOrReceivingPlant'
       IssuingOrReceivingPlant,

       @ObjectModel.foreignKey.association: '_IssuingOrReceivingStorageLoc'
       IssuingOrReceivingStorageLoc,

       @ObjectModel.foreignKey.association: '_PurchasingDocument'
       PurchasingDocument,

       @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
       PurchasingDocumentItem,


       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       ResvnItmRequiredQtyInBaseUnit,

       ReservationItemIsFinallyIssued,

       ReservationItmIsMarkedForDeltn,

       @Semantics.quantity.unitOfMeasure: 'EntryUnit'
       ResvnItmRequiredQtyInEntryUnit,


       ResvnItmWithdrawnQtyInBaseUnit,

       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       ResvnItmWithdrawnAmtInCCCrcy,

       @ObjectModel.foreignKey.association: '_Supplier'
       Supplier,

       @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
       InventorySpecialStockType,


       MaterialComponentIsPhantomItem,

       IsBulkMaterialComponent,

       MatlCompIsTextItem,

       PurchaseRequisition,

       PurchaseRequisitionItem,

       ReferenceOrder,

       MaterialGroup,

       ReservationQuantityRqmtTime,

       MaterialComponentIsMissing,

       PlannedOrder,

       ScheduleLine,

       ProductionSupplyArea,

       IsComponentQuantityFixed,

       IsMaterialProvision,

//       PriceUnit,


       GoodsRecipientName,
       UnloadingPointName,
       ReservationItemText,

       MaterialCompIsProcuredDirectly,

       IssgOrRcvgSpclStockInd,

       _DebitCreditCode,
       _Plant,
       _IssuingOrReceivingPlant,
       _Material,
       _StorageLocation,
       _IssuingOrReceivingStorageLoc,
       _GoodsMovementType,
       _Currency,
       _PurchasingDocument,
       _PurchasingDocumentItem,
       _BaseUnit,
       _EntryUnit,
       _Supplier,
       _InventorySpecialStockType,
       _Batch,
       _MRPAreaSubcontractor,

       @Consumption.hidden: true
       _SupplierCompanyByPlant,

       _ReservationHeader

}

where
            I_ReservationItem.Supplier                             <> ''
  and       I_ReservationItem.Material                             <> ''
  and       I_ReservationItem.Plant                                <> ''
  and       PurchaseRequisition                                    =  ''

  and       ResvnItmWithdrawnQtyInBaseUnit                         <  ResvnItmRequiredQtyInEntryUnit

  and       ReservationItemIsFinallyIssued                         =  ''
  and       ReservationItmIsMarkedForDeltn                         =  ''

  and       MaterialComponentIsPhantomItem                         =  ' '
  and       DebitCreditCode                                        =  'H'
  and       IsBulkMaterialComponent                                =  ' '
  and       MatlCompIsTextItem                                     =  ' '
  and       InventorySpecialStockType                              =  ' '



  and(
    (
      (
            //Subcontracting PO and SA - adopted from I_SubcontractingComponent

            RecordType                                             =  ' '
        and RequirementType                                        =  'BB'
        and I_ReservationItem.PurchasingDocument                   <> ''

        //Removing Blocked supplier

        and _PurchasingDocumentItem.PurchasingDocumentDeletionCode =  ''

        and _PurchasingDocumentItem.IsCompletelyDelivered          =  ''

        and _PurchasingDocument.PurchasingDocumentDeletionCode     =  ''

      )
      or(
            // Subcontracting Stock Transfer Reservations

            IssgOrRcvgSpclStockInd                                 =  'O'

      )
    )
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MRPAREASUBCONTRACTOR",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_RESERVATIONITEM"
],
"ASSOCIATED":
[
"I_BATCH",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_GOODSMOVEMENTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_MATERIAL",
"I_MRPAREASUBCONTRACTOR",
"I_PLANT",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_RESERVATIONHEADER",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_RESERVATIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/