P_ShopFloorItemComponent

@AbapCatalog.sqlViewName: 'PMPESFICMP'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view P_ShopFloorItemComponent
  as select from           I_MfgOrderCompAssemblyAggrgn as MfgOrderCompAssemblyAggrgn
    left outer to one join I_OpActyNtwkInstanceBasic    as OpActyNtwkInstance        on OpActyNtwkInstance.OpActyNtwkInstance = MfgOrderCompAssemblyAggrgn.OpActyNtwkInstance
    left outer to one join I_OpActyComponentAssignment  as OpActyComponentAssignment on  OpActyComponentAssignment.OpActyNtwkInstance = MfgOrderCompAssemblyAggrgn.OpActyNtwkInstance
                                                                                     and OpActyComponentAssignment.OpActyNtwkElement  = MfgOrderCompAssemblyAggrgn.OpActyNtwkElement
                                                                                     and OpActyComponentAssignment.Reservation        = MfgOrderCompAssemblyAggrgn.Reservation
                                                                                     and OpActyComponentAssignment.ReservationItem    = MfgOrderCompAssemblyAggrgn.ReservationItem
                                                                                     and OpActyComponentAssignment.RecordType         = MfgOrderCompAssemblyAggrgn.RecordType
  association [0..1] to I_Plant                     as _Plant                     on  $projection.Plant = _Plant.Plant
  association [0..1] to I_ProductPlant              as _ProductPlant              on  $projection.Material = _ProductPlant.Product
                                                                                  and $projection.Plant    = _ProductPlant.Plant
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                  and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
{
  key MfgOrderCompAssemblyAggrgn.Reservation,
  key MfgOrderCompAssemblyAggrgn.ReservationItem,
  key MfgOrderCompAssemblyAggrgn.RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key MfgOrderCompAssemblyAggrgn.OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key MfgOrderCompAssemblyAggrgn.OpActyNtwkElement,
  key MfgOrderCompAssemblyAggrgn.AssemblyShopFloorItem,
  key MfgOrderCompAssemblyAggrgn.ShopFloorItem,
  key MfgOrderCompAssemblyAggrgn.Batch,
  key MfgOrderCompAssemblyAggrgn.Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key MfgOrderCompAssemblyAggrgn.Plant,
  key MfgOrderCompAssemblyAggrgn.OriglDgtlMockUpCharcsUUID,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(round(fltp_to_dec( OpActyComponentAssignment.MfgOrderComponentUsageNetQty as abap.dec(13,4) ), 3)
        as co_menge )                                       as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      MfgOrderCompAssemblyAggrgn.MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      MfgOrderCompAssemblyAggrgn.MaterialBaseUnit,
      OpActyNtwkInstance.ManufacturingOrder,
      OpActyNtwkInstance.OrderInternalID,
      OpActyNtwkInstance.OrderOperationInternalID,
      OpActyNtwkInstance.OperationActivityNetwork,
      OpActyNtwkInstance.OpActyNtwkVersionCounter,
      MfgOrderCompAssemblyAggrgn._ShopFloorItem.SerialNumber,
      MfgOrderCompAssemblyAggrgn.DgtlMockUpCharcsUUID,
      MfgOrderCompAssemblyAggrgn.ReferenceDesignatorValue,
      cast('' as mpe_comp_is_for_backflush preserving type) as MatlCompIsMarkedForBackflush,
      MfgOrderCompAssemblyAggrgn.DebitCreditCode            as DebitCreditCode,
      OpActyComponentAssignment.RelatedOpActyNtwkElement,
      OpActyComponentAssignment.RelatedOpActyNtwkInstance,
      OpActyComponentAssignment.RelatedRecordType,
      OpActyComponentAssignment.RelatedReservation,
      OpActyComponentAssignment.RelatedReservationItem,
      OpActyComponentAssignment.LeadingOpActyNtwkElement,
      OpActyComponentAssignment.LeadingOpActyNtwkInstance,
      OpActyComponentAssignment.LeadingReservationRecordType,
      OpActyComponentAssignment.LeadingReservation,
      OpActyComponentAssignment.LeadingReservationItem,

      MfgOrderCompAssemblyAggrgn._Material,
      _Plant,
      _ProductPlant,
      _OpActyNtwkInstance,
      _OperationActivityInstance

}

-- add backflushed components

union all

select from  I_ShopFloorItemStatus       as ShopFloorItemStatus
  inner join I_OpActyNtwkInstanceBasic   as OpActyNtwkInstanceBasic   on OpActyNtwkInstanceBasic.OpActyNtwkInstance = ShopFloorItemStatus.OpActyNtwkInstance
  inner join I_OpActyComponentAssignment as OpActyComponentAssignment on  OpActyComponentAssignment.OpActyNtwkInstance = ShopFloorItemStatus.OpActyNtwkInstance
                                                                      and OpActyComponentAssignment.OpActyNtwkElement  = ShopFloorItemStatus.OpActyNtwkElement
  inner join I_ReservationItem           as ReservationItem           on  ReservationItem.Reservation                  = OpActyComponentAssignment.Reservation
                                                                      and ReservationItem.ReservationItem              = OpActyComponentAssignment.ReservationItem
                                                                      and ReservationItem.RecordType                   = OpActyComponentAssignment.RecordType
                                                                      and ReservationItem.MatlCompIsMarkedForBackflush = 'X' --backflushed
association [0..1] to I_Plant                     as _Plant                     on  $projection.Plant = _Plant.Plant
association [1..1] to I_Material                  as _Material                  on  $projection.Material = _Material.Material
association [0..1] to I_ProductPlant              as _ProductPlant              on  $projection.Material = _ProductPlant.Product
                                                                                and $projection.Plant    = _ProductPlant.Plant
association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
association [1..1] to I_OperationActivityInstance as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
{
      @UI.hidden:true
  key OpActyComponentAssignment.Reservation,
  key OpActyComponentAssignment.ReservationItem,
  key OpActyComponentAssignment.RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key OpActyComponentAssignment.OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key OpActyComponentAssignment.OpActyNtwkElement,
  key ShopFloorItemStatus.ShopFloorItem                                                 as AssemblyShopFloorItem,
  key 0                                                                                 as ShopFloorItem,
  key cast('' as charg_d)                                                               as Batch,
  key ReservationItem.Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key ReservationItem.Plant,
  key cast(hextobin('00000000000000000000000000000000') as dmu_guid16 preserving type ) as OriglDgtlMockUpCharcsUUID,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(round(fltp_to_dec( OpActyComponentAssignment.MfgOrderComponentUsageNetQty as abap.dec(13,4) ), 3)
        as co_menge )                                                                   as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      OpActyComponentAssignment.MfgOrderComponentUsageQuantity                          as MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      ReservationItem.BaseUnit                                                          as MaterialBaseUnit,
      OpActyNtwkInstanceBasic.ManufacturingOrder,
      OpActyNtwkInstanceBasic.OrderInternalID,
      OpActyNtwkInstanceBasic.OrderOperationInternalID,
      OpActyNtwkInstanceBasic.OperationActivityNetwork,
      OpActyNtwkInstanceBasic.OpActyNtwkVersionCounter,
      cast('' as gernr)                                                                 as SerialNumber,
      cast(hextobin('00000000000000000000000000000000') as dmu_guid16 preserving type ) as DgtlMockUpCharcsUUID,
      cast('' as char128)                                                               as ReferenceDesignatorValue,
      cast('X' as mpe_comp_is_for_backflush preserving type)                            as MatlCompIsMarkedForBackflush,
      ReservationItem.DebitCreditCode                                                   as DebitCreditCode,
      OpActyComponentAssignment.RelatedOpActyNtwkElement                                as RelatedOpActyNtwkElement,
      OpActyComponentAssignment.RelatedOpActyNtwkInstance                               as RelatedOpActyNtwkInstance,
      OpActyComponentAssignment.RelatedRecordType                                       as RelatedRecordType,
      OpActyComponentAssignment.RelatedReservation                                      as RelatedReservation,
      OpActyComponentAssignment.RelatedReservationItem                                  as RelatedReservationItem,
      OpActyComponentAssignment.LeadingOpActyNtwkElement                                as LeadingOpActyNtwkElement,
      OpActyComponentAssignment.LeadingOpActyNtwkInstance                               as LeadingOpActyNtwkInstance,
      OpActyComponentAssignment.LeadingReservationRecordType                            as LeadingReservationRecordType,
      OpActyComponentAssignment.LeadingReservation                                      as LeadingReservation,
      OpActyComponentAssignment.LeadingReservationItem                                  as LeadingReservationItem,
      _Material,
      _Plant,
      _ProductPlant,
      _OpActyNtwkInstance,
      _OperationActivityInstance
}
where
        ShopFloorItemStatus._SASStatus.SASStatusCategory = 3 -- Completed
  or(
        ShopFloorItemStatus._SASStatus.SASStatusCategory = 7 -- Scrapped
    and ShopFloorItemStatus._SASStatus.SASStatusCategory = 2 -- from In Process
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDERCOMPASSEMBLYAGGRGN",
"I_OPACTYCOMPONENTASSIGNMENT",
"I_OPACTYNTWKINSTANCEBASIC",
"I_RESERVATIONITEM",
"I_SASSTATUS",
"I_SHOPFLOORITEM",
"I_SHOPFLOORITEMSTATUS"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANT",
"I_PRODUCTPLANT"
],
"BASE":
[
"I_MFGORDERCOMPASSEMBLYAGGRGN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/