I_AssldReltdCompInstceSrlNmbr

@AbapCatalog.sqlViewName: 'IMPEASSRLTDINST'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Assembled Related Component Instance and/or Serial Number'
define view I_AssldReltdCompInstceSrlNmbr
  -- Assembled related components having instances
  as select from P_AssldReltdComponentInstance as AssldReltdComponentInstance
    inner join   I_ReservationItem             as ReservationItem on  ReservationItem.Reservation     = AssldReltdComponentInstance.Reservation
                                                                  and ReservationItem.ReservationItem = AssldReltdComponentInstance.ReservationItem
                                                                  and ReservationItem.RecordType      = AssldReltdComponentInstance.RecordType

{
  key AssldReltdComponentInstance.Reservation,
  key AssldReltdComponentInstance.ReservationItem,
  key AssldReltdComponentInstance.RecordType,
  key AssldReltdComponentInstance.OpActyNtwkInstance,
  key AssldReltdComponentInstance.OpActyNtwkElement,
  key AssldReltdComponentInstance.AssemblyShopFloorItem,
  key AssldReltdComponentInstance.ShopFloorItem,
  key AssldReltdComponentInstance.OriglDgtlMockUpCharcsUUID,
      AssldReltdComponentInstance.ReltdOriglDgtlMockUpCharcsUUID,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast( 1 as kmpmg )                                      as MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      ReservationItem.BaseUnit                                as MaterialBaseUnit,
      AssldReltdComponentInstance.ReferenceDesignatorName,
      AssldReltdComponentInstance.ReferenceDesignatorValue,
      AssldReltdComponentInstance.Batch,
      AssldReltdComponentInstance._BatchDistinct.BatchBySupplier,
      AssldReltdComponentInstance._ShopFloorItem.SerialNumber as AssembledSerialNumber,
      AssldReltdComponentInstance._ShopFloorItem._Equipment.ManufacturerSerialNumber,

      AssldReltdComponentInstance._ReservationHeader,
      AssldReltdComponentInstance._OpActyNtwkInstance,
      AssldReltdComponentInstance._OperationActivityInstance,
      AssldReltdComponentInstance._ParentShopFloorItem,
      ReservationItem._BaseUnit                               as _MaterialBaseUnit,
      AssldReltdComponentInstance._ShopFloorItem
}

union all

-- Adding assembled serial numbers of related components that do not have instances
select from P_AssldReltdCompSFINoInstce as AssldReltdCompSFINoInstce
{
  key AssldReltdCompSFINoInstce.Reservation,
  key AssldReltdCompSFINoInstce.ReservationItem,
  key AssldReltdCompSFINoInstce.RecordType,
  key AssldReltdCompSFINoInstce.OpActyNtwkInstance,
  key AssldReltdCompSFINoInstce.OpActyNtwkElement,
  key AssldReltdCompSFINoInstce.AssemblyShopFloorItem,
  key AssldReltdCompSFINoInstce.ShopFloorItem,
  key cast(HEXTOBIN('00000000000000000000000000000000') as dmu_guid16 preserving type) as OriglDgtlMockUpCharcsUUID,
      cast(HEXTOBIN('00000000000000000000000000000000') as dmu_guid16 preserving type) as ReltdOriglDgtlMockUpCharcsUUID,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      AssldReltdCompSFINoInstce.MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      AssldReltdCompSFINoInstce.MaterialBaseUnit,
      cast('' as vmp_ref_des)                                                          as ReferenceDesignatorName,
      cast('' as vmp_ref_des)                                                          as ReferenceDesignatorValue,
      AssldReltdCompSFINoInstce.Batch,
      AssldReltdCompSFINoInstce._BatchDistinct.BatchBySupplier,
      AssldReltdCompSFINoInstce._ShopFloorItem.SerialNumber                            as AssembledSerialNumber,
      AssldReltdCompSFINoInstce._ShopFloorItem._Equipment.ManufacturerSerialNumber,

      AssldReltdCompSFINoInstce._ReservationHeader,
      AssldReltdCompSFINoInstce._OpActyNtwkInstance,
      AssldReltdCompSFINoInstce._OperationActivityInstance,
      AssldReltdCompSFINoInstce._ParentShopFloorItem,
      AssldReltdCompSFINoInstce._MaterialBaseUnit,
      AssldReltdCompSFINoInstce._ShopFloorItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHDISTINCT",
"I_EQUIPMENT",
"I_RESERVATIONITEM",
"I_SHOPFLOORITEM",
"P_ASSLDRELTDCOMPONENTINSTANCE",
"P_ASSLDRELTDCOMPSFINOINSTCE"
],
"ASSOCIATED":
[
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_RESERVATIONDOCUMENTHEADER",
"I_SHOPFLOORITEM",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_RESERVATIONITEM",
"P_ASSLDRELTDCOMPONENTINSTANCE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/