I_LEGALTRANSACTION
Basic View for LCM Legal Transaction
I_LEGALTRANSACTION is a CDS View in S/4HANA. Basic View for LCM Legal Transaction. It contains 19 fields. 17 CDS views read from this table.
CDS Views using this table (17)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_LegalContentRequest | view | from | CONSUMPTION | Legal Content Request |
| C_LegalDocumentIntegFacet | view | from | CONSUMPTION | Legal Document Integration Facet |
| C_LegalTransactionIdValueHelp | view | from | CONSUMPTION | Value Help for LCM Legal Transaction ID |
| C_LegalTransactionIntegFacet | view | from | CONSUMPTION | Legal Transaction Integration Facet |
| C_LegalTransLinkedObjCube | view | from | CONSUMPTION | Legal Transaction Linked Obj - Cube |
| C_LglCntntMReltdLglTransList | view | union | CONSUMPTION | Related Legal Transactions of a Legal Transaction |
| C_MM_LegalTransactionVH | view | from | CONSUMPTION | Procurement Legal Transaction Value Help |
| ESH_N_LEGAL_TRANSACTION | view | from | ||
| I_LegalTransactionAggr | view | from | COMPOSITE | View for I_LegalTransaction Aggr |
| I_LegalTransactionAPI01 | view | from | BASIC | Legal Transaction |
| I_LegalTransactionQuickView | view | from | COMPOSITE | Composite view for Legal Transaction Quick View |
| I_LegalTransactionTP | view | from | TRANSACTIONAL | TP View for LCM Legal Transaction |
| I_LglCntntMNotesLglTransObj | view | from | BASIC | Related Objects for Legal Transactions |
| I_LglCntntMRelshpUseCaseStatus | view | from | COMPOSITE | Basic view for all Legal Transactions and usecases |
| I_LglTransDocCntntCpyPndgSitn | view | from | COMPOSITE | Situation for Document Content Copy Pending in LT |
| P_LegalTransactionCube | view | from | CONSUMPTION | Cube - View for Legal Transaction |
| R_LegalTransactionTP | view_entity | from | TRANSACTIONAL | Legal Transactions |
Fields (19)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | LegalTransactionUUID | LegalTransactionUUID,LglCntntMObjUUID,LglCntntMParApplObjUUID,LglCntntMParObjUUID,RelshpLegalTransactionUUID | 5 |
| _LglCntntMMainOrgTypeText | _LglCntntMMainOrgTypeText | 1 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 2 | |
| LegalTransaction | LegalTransaction,LglCntntMObjectID,LglCntntMParObjID,RelshpLegalTransaction | 5 | |
| LegalTransactionHealth | LegalTransactionHealth | 2 | |
| LegalTransactionTitle | LegalTransactionTitle | 3 | |
| LglCntntMChangedByUser | LglCntntMChangedByUser | 2 | |
| LglCntntMChangedUTCDateTime | LglCntntMChangedUTCDateTime | 2 | |
| LglCntntMContextUUID | LglCntntMContextUUID | 1 | |
| LglCntntMCreatedByUser | LglCntntMCreatedByUser | 1 | |
| LglCntntMCreatedUTCDateTime | LglCntntMCreatedUTCDateTime | 1 | |
| LglCntntMGovLaw | LglCntntMGovLaw | 2 | |
| LglCntntMLanguage | LglCntntMLanguage | 1 | |
| LglCntntMMainOrgCoCode | LglCntntMMainOrgCoCode | 2 | |
| LglCntntMMainOrgPurOrg | LglCntntMMainOrgPurOrg | 2 | |
| LglCntntMMainOrgSalesOrg | LglCntntMMainOrgSalesOrg | 2 | |
| LglCntntMMainOrgType | LglCntntMMainOrgType | 1 | |
| LglCntntMProfile | LglCntntMProfile | 3 | |
| LglTransAccessLvl | LglTransAccessLvl | 2 |
@AbapCatalog.sqlViewName: 'ILEGALTR'
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #BASIC
@ObjectModel: {
representativeKey: 'LegalTransactionUUID',
usageType.serviceQuality: #B,
usageType.sizeCategory: #XL,
usageType.dataClass: #TRANSACTIONAL
}
@AccessControl.personalData.blocking: #REQUIRED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.privilegedAssociations: [ '_CreatedBy', '_ChangedBy' ]
@EndUserText.label: 'Basic View for LCM Legal Transaction'
define view I_LegalTransaction
as select from lcm_legaltr
association [0..1] to Sgbt_Nte_Cds_Cont as _Note on _Note.noteid = $projection.LglCntntMLongTextUUID
and _Note.objectnodetype = 'LegalTransaction'
and _Note.notetype = 'LCM_LONGTEXT'
//Extension
association [1..1] to E_LegalTransaction as _Extenstion on $projection.LegalTransactionUUID = _Extenstion.LegalTransactionUUID
// ESH associations
association [1..1] to I_LglCntntMContextBasic as _Context on $projection.LglCntntMContextUUID = _Context.LglCntntMContextUUID
association [1..1] to I_LegalTransactionEntity as _MainLegalTransactionEntity on $projection.LegalTransactionUUID = _MainLegalTransactionEntity.LegalTransactionUUID
and _MainLegalTransactionEntity.LglCntntMIsMainEntity = 'X'
association [1..*] to I_LegalTransactionEntity as _LegalTransactionEntity on $projection.LegalTransactionUUID = _LegalTransactionEntity.LegalTransactionUUID
association [1..*] to I_LegalTrParentCategory as _LegalTrParentCategory on $projection.LegalTransactionUUID = _LegalTrParentCategory.LegalTransactionUUID
association [1..*] to I_LegalTransactionCategory as _LegalTransactionCategory on $projection.LegalTransactionUUID = _LegalTransactionCategory.LegalTransactionUUID
association [0..*] to I_LegalTrLinkedObjects as _LegalTrLinkedObjects on $projection.LegalTransactionUUID = _LegalTrLinkedObjects.LegalTransactionUUID
association [0..*] to I_LegalTrRelationship as _LegalTrRelationship on $projection.LegalTransactionUUID = _LegalTrRelationship.LegalTransactionUUID
association [0..*] to I_LegalTransactionIntContact as _LegalTransactionIntContact on $projection.LegalTransactionUUID = _LegalTransactionIntContact.LegalTransactionUUID
association [0..1] to I_LglCntntMMainOrgTypeText as _LglCntntMMainOrgTypeText on $projection.LglCntntMMainOrgType = _LglCntntMMainOrgTypeText.LglCntntMMainOrgType
and _LglCntntMMainOrgTypeText.Language = $session.system_language
association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.LglCntntMMainOrgPurOrg = _PurchasingOrganization.PurchasingOrganization
association [0..1] to I_SalesOrganizationText as _SalesOrganizationText on $projection.LglCntntMMainOrgSalesOrg = _SalesOrganizationText.SalesOrganization
and _SalesOrganizationText.Language = $session.system_language
association [0..1] to I_CompanyCode as _CompanyCode on $projection.LglCntntMMainOrgCoCode = _CompanyCode.CompanyCode
association [0..1] to I_LegalTransactionHealthText as _LegalTransactionHealthText on $projection.LegalTransactionHealth = _LegalTransactionHealthText.LegalTransactionHealth
and _LegalTransactionHealthText.Language = $session.system_language
association [0..1] to I_LanguageText as _LanguageText on $projection.LglCntntMLanguage = _LanguageText.LanguageCode
and _LanguageText.Language = $session.system_language
association [0..1] to I_LglCntntMAccessLvlText as _LglCntntMAccessLvlText on $projection.LglTransAccessLvl = _LglCntntMAccessLvlText.LglCntntMAccessLvl
and _LglCntntMAccessLvlText.Language = $session.system_language
association [0..1] to I_LCMUserAddressAssignment as _CreatedBy on $projection.LglCntntMCreatedByUser = _CreatedBy.ContactCardID
association [0..1] to I_LCMUserAddressAssignment as _ChangedBy on $projection.LglCntntMChangedByUser = _ChangedBy.ContactCardID
association [0..1] to I_LglCntntMGovLawText as _LglCntntMGovLawText on $projection.LglCntntMGovLaw = _LglCntntMGovLawText.LglCntntMGovLaw
and _LglCntntMGovLawText.Language = $session.system_language
association [0..1] to I_LglCntntMIntegTypeText as _LglCntntMIntegTypeText on $projection.LglCntntMIntegrationType = _LglCntntMIntegTypeText.LglCntntMIntegrationType
and Language = $session.system_language
{
@Consumption.filter.hidden : true
key legaltransactionuuid as LegalTransactionUUID,
legaltransaction as LegalTransaction,
@Semantics.text: true
legaltransactiontitle as LegalTransactionTitle,
legaltransactionhealth as LegalTransactionHealth,
lglcntntmlanguage as LglCntntMLanguage,
lglcntntmcreatedbyuser as LglCntntMCreatedByUser,
@Consumption.filter.hidden : true
lglcntntmcontextuuid as LglCntntMContextUUID,
@Consumption.filter.hidden : true
lgltranswrkflwmodinstce as LglTransWrkFlwModInstce,
// @Consumption.filter.hidden : true
lglcntntmcreatedutcdatetime as LglCntntMCreatedUTCDateTime,
lglcntntmchangedbyuser as LglCntntMChangedByUser,
// @Consumption.filter.hidden : true
lglcntntmchangedutcdatetime as LglCntntMChangedUTCDateTime,
lglcntntmprofile as LglCntntMProfile,
// @Consumption.filter.hidden: true
legaltransactionsource as LegalTransactionSource,
@Consumption.filter.hidden: true
@Semantics.booleanIndicator: true
isendofpurposeblocked as IsEndOfPurposeBlocked,
@Consumption.filter.hidden : true
_dataaging as LglCntntMAgingTemperature,
lglcntntmrtntnperdstartdate as LglCntntMRtntnPerdStartDate,
lglcntntmgovlaw as LglCntntMGovLaw,
lgltransaccesslvl as LglTransAccessLvl,
lglcntntmmainorgtype as LglCntntMMainOrgType,
lglcntntmmainorgcocode as LglCntntMMainOrgCoCode,
lglcntntmmainorgsalesorg as LglCntntMMainOrgSalesOrg,
lglcntntmmainorgpurorg as LglCntntMMainOrgPurOrg,
@Consumption.filter.hidden : true
lglcntntmlongtextuuid as LglCntntMLongTextUUID,
lglcntntmintegrationtype as LglCntntMIntegrationType,
//copiedfromlegaltransactionuuid as CopiedFromLegalTransactionUUID,
lglcntntmcrtedfrmlgltransuuid as LglCntntMCrtedFrmLglTransUUID,
_Note.content as LglCntntMLongText,
_Note.mimetype as LglCntntMLongTextMimeType,
_Context,
_MainLegalTransactionEntity,
_LegalTransactionEntity,
_LegalTrParentCategory,
_LegalTransactionCategory,
_LegalTrLinkedObjects,
_LegalTrRelationship,
_LegalTransactionIntContact,
_LglCntntMMainOrgTypeText,
_PurchasingOrganization,
_SalesOrganizationText,
_CompanyCode,
_LegalTransactionHealthText,
_LanguageText,
_LglCntntMAccessLvlText,
_CreatedBy,
_ChangedBy,
_LglCntntMGovLawText,
_LglCntntMIntegTypeText
}