C_MM_LegalTransactionVH

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CMMLEGALTRVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Procurement Legal Transaction Value Help'
@ObjectModel: { semanticKey: 'LegalTransaction',
                representativeKey: 'LegalTransactionUUID',

                usageType.dataClass: #TRANSACTIONAL,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #XL  }

@Search.searchable: true

define view C_MM_LegalTransactionVH
  as select from I_LegalTransaction as LegalTransaction

  association [1..1] to I_LegalTransactionAggr       as _LegalTransactionAggrgn     on  $projection.LegalTransactionUUID = _LegalTransactionAggrgn.LegalTransactionUUID
  association [0..1] to C_LegalTransactionEntityMain as _LegalTransactionEntityMain on  $projection.LegalTransactionUUID = _LegalTransactionEntityMain.LegalTransactionUUID
  association [0..1] to I_LcmContext                 as _LCMContext                 on  $projection.LglCntntMContextUUID = _LCMContext.LglCntntMContextUUID
  association [0..1] to I_LCMUserContactCard         as _CreatedByContactCard       on  _CreatedByContactCard.ContactCardType = 'User'
                                                                                    and _CreatedByContactCard.ContactCardID   = $projection.LglCntntMCreatedByUser
                                                                                    and _CreatedByContactCard.ContactCardRole = 'Creator'
  association [0..1] to I_LegalTransactionHealthText   as _LegalTransactionHealthText   on  $projection.LegalTransactionHealth = _LegalTransactionHealthText.LegalTransactionHealth
                                                                                        and Language                           = $session.system_language
  //association [0..1] to C_LegalTransactionHealthVH     as _LegalTransactionHealthVH     on  $projection.LegalTransactionHealth = _LegalTransactionHealthVH.LegalTransactionHealth                                                                                    


{
      @UI.hidden: true
  key LegalTransaction.LegalTransactionUUID,

      @UI.lineItem: { position: 10, importance: #HIGH, label:'Legal Transaction' }
      @UI.selectionField.position: 10
      @Consumption.semanticObject: 'LegalTransaction'
      @ObjectModel.text.element:  [ 'LegalTransactionTitle' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      LegalTransaction.LegalTransaction,

      @UI.lineItem: { position: 15, importance: #HIGH , 
                      criticality: 'LglTransHealthCriticality', criticalityRepresentation: #WITHOUT_ICON 
                      }
      @UI.textArrangement: #TEXT_ONLY
      @ObjectModel: { text.element: ['LegalTransactionHealthName'] }
      @EndUserText.label: 'Status' // 'Health'     

      //@Consumption.valueHelp: '_LegalTransactionHealthVH'

      @Consumption.filter.hidden: true
      LegalTransaction.LegalTransactionHealth as LegalTransactionHealth,
      
      @Consumption.filter.hidden: true
      @UI.hidden: true
      _LegalTransactionHealthText.LegalTransactionHealthName as LegalTransactionHealthName,

      _LegalTransactionAggrgn.LglTransHealthCriticality,

      @UI.hidden: true
      LegalTransaction.LglCntntMContextUUID,

      @UI.lineItem: { position: 20, importance: #HIGH, label: 'Context' }
      @UI.selectionField.position: 20
      @ObjectModel.text.element:  [ 'LglCntntMContextTitle' ]
      _LCMContext.LglCntntMContext,

      @UI.lineItem: { position: 30, importance: #HIGH, label: 'Main Entity' }
      @UI.selectionField.position: 30
      @ObjectModel.text.element:  [ 'LglCntntMEntityName' ]
      _LegalTransactionEntityMain.LglCntntMEntity,

      @UI.hidden: true
      @Semantics.text: true
      @ObjectModel.readOnly: true
      //no search due to case statement

      _LegalTransactionEntityMain.LglCntntMEntityName,


      @UI.lineItem: { position: 40, importance: #HIGH }
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.filter.hidden: true
      @ObjectModel.text.element:  [ 'FullName' ]
      LegalTransaction.LglCntntMCreatedByUser,

      @UI.lineItem: { position: 50, importance: #HIGH }
      @Consumption.filter.hidden: true
      @Semantics.systemDate.createdAt: true
      LegalTransaction.LglCntntMCreatedUTCDateTime,

      @UI.hidden: true
      _CreatedByContactCard.FullName,
      @UI.hidden: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      _CreatedByContactCard.FirstName,
      @UI.hidden: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      _CreatedByContactCard.LastName,

      @UI.hidden: true
      LegalTransaction.LglCntntMChangedByUser,

      @UI.hidden: true
      @Semantics.systemDate.lastChangedAt: true
      LegalTransaction.LglCntntMChangedUTCDateTime,

      @UI.hidden: true
      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      LegalTransaction.LegalTransactionTitle,

      @UI.hidden: true
      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      _LCMContext.LglCntntMContextTitle,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      LegalTransaction.IsEndOfPurposeBlocked,

      @UI.hidden: true
      LegalTransaction.LglCntntMProfile,

      @UI.hidden: true
      LglTransAccessLvl,

      @UI.hidden: true
      LglCntntMMainOrgCoCode,

      @UI.hidden: true
      LglCntntMMainOrgSalesOrg,

      @UI.hidden: true
      LglCntntMMainOrgPurOrg,
      
      _LegalTransactionHealthText /*,
      
      @Consumption.filter.hidden: true
      _LegalTransactionHealthVH   */

}