@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CLGLTRANSINTEGF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Legal Transaction Integration Facet'
@Metadata.allowExtensions: true
@ObjectModel: { semanticKey: ['LegalTransactionLinkdObjUUID'],
representativeKey: 'LegalTransactionLinkdObjUUID',
usageType.dataClass: #MIXED,
usageType.serviceQuality: #C,
usageType.sizeCategory: #XL }
@AccessControl.privilegedAssociations: [ '_ChangedByContactCard' ]
@Metadata.ignorePropagatedAnnotations: true
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
define view C_LegalTransactionIntegFacet
as select from I_LegalTransaction as LegalTransaction
inner join I_LglCntntMIntegLinkdObj as LinkedObject on LegalTransaction.LegalTransactionUUID = LinkedObject.LegalTransactionUUID
association [1..1] to I_LegalTransactionAggr as _LegalTransactionAggrgn on $projection.LegalTransactionUUID = _LegalTransactionAggrgn.LegalTransactionUUID
association [0..1] to I_LCMUserContactCard as _ChangedByContactCard on _ChangedByContactCard.ContactCardType = 'User'
and _ChangedByContactCard.ContactCardID = $projection.LglCntntMChangedByUser
and _ChangedByContactCard.ContactCardRole = 'Creator'
association [0..*] to I_LegalTransactionHealthText as _LegalTransactionHealthText on $projection.LegalTransactionHealth = _LegalTransactionHealthText.LegalTransactionHealth
association [0..1] to C_LegalTransactionEntityMain as _LegalTransactionEntityMain on $projection.LegalTransactionUUID = _LegalTransactionEntityMain.LegalTransactionUUID
association [0..*] to I_LCMEntityTypeText as _EntityTypeText on $projection.lglcntntmentitytype = _EntityTypeText.LglCntntMEntityType
//language fix (dump on OData GET C_LegalTransactionIntegFacet)
association [0..1] to I_Language as _Language on $projection.LglCntntMLanguage = _Language.Language
// Valuehelps
association [0..1] to C_LglCntntMGovLawVH as _LCMGovLawVH on $projection.LglCntntMGovLaw = _LCMGovLawVH.LglCntntMGovLaw
association [1..1] to I_LglTransToBeUpdated as _LglTransToBeUpdated on $projection.LegalTransaction = _LglTransToBeUpdated.LegalTransaction
and $projection.LglCntntMLinkdObj = _LglTransToBeUpdated.LglCntntMLinkdObj
//Extension
association [1..1] to E_LegalTransaction as _LegalTransactionExtension on $projection.LegalTransactionUUID = _LegalTransactionExtension.LegalTransactionUUID
{
@UI.hidden: true
key LinkedObject.LegalTransactionLinkdObjUUID,
@UI.hidden: true
LinkedObject.LegalTransactionUUID,
@Consumption.semanticObject: 'LegalTransaction'
@UI.lineItem: [{ position: 10, importance: #HIGH }]
@ObjectModel.text.element: [ 'LegalTransactionTitle' ]
@EndUserText.label: 'Legal Transaction'
LegalTransaction.LegalTransaction,
@UI.lineItem: [{ position: 30, importance: #HIGH }]
@UI.textArrangement: #TEXT_ONLY
@ObjectModel: { text.association: '_EntityTypeText' }
_LegalTransactionEntityMain.LglCntntMEntityType,
@UI.lineItem: [{ position: 40, importance: #HIGH }]
@ObjectModel.text.element: [ 'LglCntntMEntityName' ]
@EndUserText.label: 'Main Entity'
@EndUserText.quickInfo: 'Main Entity'
_LegalTransactionEntityMain.LglCntntMEntity,
@UI.hidden: true
@Semantics.text: true
@ObjectModel.readOnly: true
_LegalTransactionEntityMain.LglCntntMEntityName,
@UI.hidden: true
LegalTransaction.LglCntntMChangedByUser,
@UI.lineItem: [{ position: 60 }]
@Semantics.systemDate.lastChangedAt: true
@EndUserText.label: 'Last Changed On'
@EndUserText.quickInfo: 'Last Changed On'
LegalTransaction.LglCntntMChangedUTCDateTime,
@UI.hidden: true
LegalTransaction.LegalTransactionTitle,
@UI.hidden: true
LinkedObject.LglCntntMLinkdObj as LglCntntMLinkdObj,
@UI.hidden: true
LinkedObject.LglCntntMIntegrationLink as LglCntntMIntegrationLink,
@UI.lineItem: [{ position: 70, criticality: 'LglTransHealthCriticality', criticalityRepresentation: #WITHOUT_ICON }]
@UI.textArrangement: #TEXT_ONLY
@ObjectModel: { text.association: '_LegalTransactionHealthText' }
@EndUserText.label: 'Status' // 'Health'
LegalTransaction.LegalTransactionHealth as LegalTransactionHealth,
@UI.hidden: true
_LegalTransactionAggrgn.LglTransHealthCriticality as LglTransHealthCriticality,
@UI.lineItem:[{value:'_ChangedByContactCard', position: 50, label: 'Last Changed By', type: #AS_CONTACT}]
_ChangedByContactCard,
@UI.lineItem: [{ position: 60 }]
@UI.textArrangement: #TEXT_ONLY
@ObjectModel.foreignKey.association: '_Language'
@Semantics.text: true
@EndUserText.label: 'Language'
LegalTransaction.LglCntntMLanguage,
@UI.lineItem: [{ position: 65 }]
@UI.textArrangement: #TEXT_FIRST
@EndUserText.label: 'Governing Law'
@ObjectModel.text.element: ['LglCntntMGovLawText']
@Semantics.text: true
@ObjectModel.readOnly: true
LegalTransaction.LglCntntMGovLaw,
@ObjectModel.readOnly: true
@Semantics.text: true
@Consumption.filter.hidden: true
@UI.hidden: true
_LCMGovLawVH.LglCntntMGovLawText as LglCntntMGovLawText,
@ObjectModel.text.association: '_LglCntntMMainOrgTypeText'
@UI.lineItem: [{ position: 50 }]
@UI.textArrangement: #TEXT_ONLY
@ObjectModel.readOnly: true
@EndUserText.label: 'Main Organization Type'
@EndUserText.quickInfo: 'Main Organization Type'
LegalTransaction.LglCntntMMainOrgType,
@UI.lineItem: [{ position: 55 }]
@UI.textArrangement: #TEXT_FIRST
@ObjectModel.text.element: [ 'LglCntntMMainOrgName' ]
@ObjectModel.readOnly: true
@EndUserText.label: 'Main Organization'
@EndUserText.quickInfo: 'Main Organization'
_LegalTransactionAggrgn.LglCntntMMainOrg,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LCM_MAIN_ORG_CALC_EXIT'
cast( '' as abap.char(25)) as LglCntntMMainOrgName,
@UI.lineItem: [{ position: 75 }]
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LCM_LT_DATES_CALC_EXIT'
@Semantics.businessDate.from: true
@EndUserText.label: 'Start Date'
@EndUserText.quickInfo: 'Start Date'
cast( '' as lcm_valid_from ) as LglCntntMFromDate,
@UI.lineItem: [{ position: 80 }]
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LCM_LT_DATES_CALC_EXIT'
@Semantics.businessDate.to: true
@EndUserText.label: 'End Date'
@EndUserText.quickInfo: 'End Date'
cast( '' as lcm_valid_to ) as LglCntntMToDate,
@UI.lineItem: [{ position: 85 }]
@Semantics.booleanIndicator: true
LinkedObject.LegalTransactionIsTriggerObj as LegalTransactionIsTriggerObj,
@UI.lineItem: [{ position: 90}]
@ObjectModel.readOnly: true
@EndUserText.label: 'Update Required'
@EndUserText.quickInfo: 'Update Required'
@Semantics.booleanIndicator: true
_LglTransToBeUpdated.LglCntntMLglTransUpdtIsRqd,
@UI.hidden: true
@ObjectModel.readOnly: true
@Consumption.filter.hidden:true
_LegalTransactionHealthText,
@UI.hidden: true
@ObjectModel.readOnly: true
@Consumption.filter.hidden:true
_EntityTypeText,
@UI.hidden: true
@ObjectModel.readOnly: true
@Semantics.booleanIndicator: true
LegalTransaction.IsEndOfPurposeBlocked,
@UI.hidden: true
@ObjectModel.readOnly: true
LegalTransaction.LglCntntMProfile,
@UI.hidden: true
@ObjectModel.readOnly: true
LegalTransaction.LglTransAccessLvl,
@UI.hidden: true
@ObjectModel.readOnly: true
LegalTransaction.LglCntntMMainOrgCoCode,
@UI.hidden: true
@ObjectModel.readOnly: true
LegalTransaction.LglCntntMMainOrgSalesOrg,
@UI.hidden: true
@ObjectModel.readOnly: true
LegalTransaction.LglCntntMMainOrgPurOrg,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// @Consumption.filter.hidden:true
// _LanguageText,
_Language,
@UI.hidden: true
@ObjectModel.readOnly: true
@Consumption.filter.hidden:true
LegalTransaction._LglCntntMMainOrgTypeText
// @Consumption.filter.hidden: true
// _LegalDocumentIntegFacet
}
where
LglCntntMLinkdObj <> ''