C_LegalTransactionIdValueHelp

DDL: C_LEGALTRANSACTIONIDVALUEHELP SQL: CLEGALTRANSIDVH Type: view CONSUMPTION

Value Help for LCM Legal Transaction ID

C_LegalTransactionIdValueHelp is a Consumption CDS View that provides data about "Value Help for LCM Legal Transaction ID" in SAP S/4HANA. It reads from 1 data source (I_LegalTransaction) and exposes 13 fields with key field LegalTransactionUUID.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_LegalTransaction I_LegalTransaction from

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CLEGALTRANSIDVH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Value Help for LCM Legal Transaction ID view
VDM.viewType #CONSUMPTION view
ObjectModel.representativeKey LegalTransactionUUID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.dataCategory #VALUE_HELP view
Search.searchable true view
Consumption.ranked true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY LegalTransactionUUID LegalTransactionUUID
LegalTransaction LegalTransaction Legal Transaction
LegalTransactionTitle LegalTransactionTitle Legal Transaction Name
LglCntntMContextUUID LglCntntMContextUUID
LglCntntMProfile LglCntntMProfile
LglTransAccessLvl LglTransAccessLvl
LglCntntMMainOrgCoCode LglCntntMMainOrgCoCode
LglCntntMMainOrgSalesOrg LglCntntMMainOrgSalesOrg
LglCntntMMainOrgPurOrg LglCntntMMainOrgPurOrg
IsEndOfPurposeBlocked IsEndOfPurposeBlocked
_Context _Context
LglCntntMContext _Context LglCntntMContext Context
LglCntntMContextTitle _Context LglCntntMContextTitle Context Name 
@AbapCatalog.sqlViewName: 'CLEGALTRANSIDVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Value Help for LCM Legal Transaction ID'
@VDM.viewType: #CONSUMPTION

@ObjectModel.semanticKey: [ 'LegalTransaction' ]
@ObjectModel.representativeKey: 'LegalTransactionUUID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
@Consumption.ranked: true

define view C_LegalTransactionIdValueHelp
  as select from I_LegalTransaction
{

        @UI.hidden: true
  key   LegalTransactionUUID           as LegalTransactionUUID,
  
        @Search: {
                  defaultSearchElement: true,
                  ranking: #HIGH ,
                  fuzzinessThreshold: 0.7
                 }
        @EndUserText.label: 'Legal Transaction'
        @UI: {
               lineItem: [{position: 10, criticality: 'LglTransHealthCriticality', importance: #HIGH, criticalityRepresentation: #WITHOUT_ICON }],
               textArrangement: #TEXT_FIRST,
               selectionField: [{ position: 10 }]
           }
        @ObjectModel.text.element:  [ 'LegalTransactionTitle' ]
        LegalTransaction               as LegalTransaction,

        @Semantics.text: true
        @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
        @EndUserText.label: 'Legal Transaction Name'
        @UI.selectionField: [{ position: 20 }]
        @UI.lineItem: [{ position: 40, importance: #LOW }]
        LegalTransactionTitle          as LegalTransactionTitle,

        @UI.hidden: true
        LglCntntMContextUUID,

        @ObjectModel.readOnly: true
        @UI.selectionField: [{ position: 50 }]
        @UI.lineItem: [{ position: 30, importance: #HIGH }]
        LglCntntMProfile,

        @UI.hidden: true
        LglTransAccessLvl,

        @UI.hidden: true
        LglCntntMMainOrgCoCode,

        @UI.hidden: true
        LglCntntMMainOrgSalesOrg,

        @UI.hidden: true
        LglCntntMMainOrgPurOrg,

        @ObjectModel.readOnly: true
        @UI.hidden: true
        IsEndOfPurposeBlocked,

        @Consumption.filter.hidden: true
        _Context,

        @UI: {
               lineItem: [{position: 20, importance: #HIGH }],
               textArrangement: #TEXT_FIRST,
               selectionField: [{ position: 30 }]
           }
        @Consumption.groupWithElement: 'LegalTransactionUUID'
        @EndUserText.label: 'Context'
        @ObjectModel.text.element:  [ 'LglCntntMContextTitle' ]
        _Context.LglCntntMContext as LglCntntMContext,

        @UI.lineItem: [{ position: 50,importance: #HIGH }]
        @Consumption.groupWithElement: 'LegalTransactionUUID'
        @EndUserText.label: 'Context Name'
        @Semantics.text: true
        @UI.selectionField: [{ position: 40 }]
        _Context.LglCntntMContextTitle as LglCntntMContextTitle

}

Learn More