R_LegalTransactionTP

@AccessControl:{
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
    }
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    }
}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.sapObjectNodeType.name:'LegalTransaction'
@EndUserText.label: 'Legal Transactions'
define root view entity R_LegalTransactionTP
  as select from I_LegalTransaction
  composition [1..*] of R_LegalTransCategoryGroupTP   as _LegalTransCategoryGroup
  composition [1..*] of R_LegalTransEntityTP          as _LegalTransEntity
  composition [1..*] of R_LegalTransInternalContactTP as _LegalTransInternalContact
  composition [1..*] of R_LegalTransExternalContactTP as _LegalTransExternalContact
  composition [1..*] of R_LegalTransRelationshipTP    as _LegalTransRelationship
  composition [1..*] of R_LegalTransLinkedObjectsTP   as _LegalTransLinkedObjects
  composition [1..*] of R_LegalTransDateTP            as _LegalTransDate
  composition [1..1] of R_LegalTransRnwlAndTermnTP    as _LegalTransRnwlAndTermn
  composition [1..*] of R_LegalTransDocLinkTP         as _LegalTransDocLink
  composition [1..*] of R_LegalTransactionReminderTP  as _LegalTransactionReminder
  //Extension

  association [1..1] to E_LegalTransaction            as _Extenstion on $projection.LegalTransactionUUID = _Extenstion.LegalTransactionUUID
{
  key LegalTransactionUUID        as LegalTransactionUUID,
      LegalTransaction            as LegalTransaction,
      LegalTransactionTitle       as LegalTransactionTitle,
      LglCntntMLanguage           as LglCntntMLanguage,
      LegalTransactionHealth      as LegalTransactionHealth,
      LglCntntMContextUUID        as LglCntntMContextUUID,
      LglCntntMProfile            as LglCntntMProfile,
      LegalTransactionSource      as LegalTransactionSource,
      @Semantics.booleanIndicator: true
      IsEndOfPurposeBlocked       as IsEndOfPurposeBlocked,
      LglCntntMCreatedUTCDateTime as LglCntntMCreatedUTCDateTime,
      LglCntntMCreatedByUser      as LglCntntMCreatedByUser,
      LglCntntMChangedUTCDateTime as LglCntntMChangedUTCDateTime,
      LglCntntMChangedByUser      as LglCntntMChangedByUser,
      LglCntntMGovLaw             as LglCntntMGovLaw,
      LglTransAccessLvl           as LglTransAccessLvl,
      LglCntntMMainOrgCoCode      as LglCntntMMainOrgCoCode,
      LglCntntMMainOrgSalesOrg    as LglCntntMMainOrgSalesOrg,
      LglCntntMMainOrgPurOrg      as LglCntntMMainOrgPurOrg,
      LglCntntMIntegrationType    as LglCntntMIntegrationType,

      //LglCntntMContext as LglCntntMContext,


      // Associations

      _LegalTransCategoryGroup,
      _LegalTransEntity,
      _LegalTransInternalContact,
      _LegalTransExternalContact,
      _LegalTransRelationship,
      _LegalTransLinkedObjects,
      _LegalTransDate,
      _LegalTransRnwlAndTermn,
      _LegalTransDocLink,
      _LegalTransactionReminder

}