P_CAInvcgDocItem

@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
  usageType:{
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  },
  representativeKey: 'CAInvcgDocItem'
}

define view entity P_CAInvcgDocItem
  as select from I_CAInvcgDocItem as _CAInvcgDocItem

  -- further associations (not on I-level due to view complexity)
  association [0..1] to I_CAMainTransaction  as _CAMainTransaction  on  $projection.CAApplicationArea = _CAMainTransaction.CAApplicationArea
                                                                    and $projection.CAMainTransaction = _CAMainTransaction.CAMainTransaction
  association [0..1] to I_CASubTransaction   as _CASubTransaction   on  $projection.CAApplicationArea = _CASubTransaction.CAApplicationArea
                                                                    and $projection.CAMainTransaction = _CASubTransaction.CAMainTransaction
                                                                    and $projection.CASubTransaction  = _CASubTransaction.CASubTransaction
  association [0..1] to I_CAOtherTaxCode     as _CAOtherTaxCode     on  $projection.CompanyCodeCountry = _CAOtherTaxCode.Country
                                                                    and $projection.CAOtherTaxCode     = _CAOtherTaxCode.CAOtherTaxCode
  association [0..1] to I_TaxCode            as _TaxCode            on  $projection.TaxCalculationProcedure = _TaxCode.TaxCalculationProcedure
                                                                    and $projection.TaxCode                 = _TaxCode.TaxCode
  association [0..1] to I_TaxJurisdiction    as _TaxJurisdiction    on  $projection.TaxCalculationProcedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
                                                                    and $projection.TaxJurisdiction         = _TaxJurisdiction.TaxJurisdiction
  association [0..1] to I_WithholdingTaxCode as _WithholdingTaxCode on  $projection.WithholdingTaxCode = _WithholdingTaxCode.WithholdingTaxCode
                                                                    and $projection.CompanyCodeCountry = _WithholdingTaxCode.Country
                                                                    
{
  key CAInvoicingDocument,
  key CAInvcgDocItem,
      CAInvcgDocumentItemType,
      CompanyCode,
      Division,
      CAContract,
      CAProviderContractItemNumber,
      CASubApplication,
      CAInvcgItmAltvBusinessPartner,
      CAInvcgItmAltvContractAccount,
      CAInvcgDocItmAltvMDCat,
      @ObjectModel.foreignKey.association: '_CAMainTransaction'
      CAMainTransaction,
      @ObjectModel.foreignKey.association: '_CASubTransaction'
      CASubTransaction,
      CAIsDocItemSimulated,
      CAInvcgDocItemIsReversal,
      CAInvcgIsInFinalAmt,
      CAInvcgIsItemPostingRelevant,
      CAInvcgIsNotBPRelevant,
      CAInvcgIsItemPrintingRelevant,
      CAInvcgSubstituteGroupPrinting,
      TransactionCurrency,
      CAAmountInTransactionCurrency,
      CAInvcgDocItmLoclCurrency,
      CAInvcgDocItmAmtInLoclCurrency,
      CAInvcgDocItmTaxBaseAmtInLCrcy,
      CACurrencySourceDocument,
      CAInvcgSourceDocumentAmount,
      CAGroupingCurrencyTranslation,
      CAAccountDeterminationCode,
      BusinessPlace,
      BusinessArea,
      CATaxIsIncluded,
      CATaxDetnType,
      CAInvcgTaxGroupingKey,
      @ObjectModel.foreignKey.association: '_CAOtherTaxCode'
      CAOtherTaxCode,
      @ObjectModel.foreignKey.association: '_TaxCode'
      TaxCode,
      CATaxDeterminationCode,
      @ObjectModel.foreignKey.association: '_TaxJurisdiction'
      TaxJurisdiction,
      CATransactionKeyAccountDetn,
      CAConditionType,
      CATaxRateInPercent,
      TaxCountry,
      TransToTaxCntryCrcyCnvrsnFctr,
      CAInvcgOffsettingCategory,
      CAInvcgOffsettingProcedure,
      CAInvcgOffsettingAction,
      CATaxDate,
      CATaxBaseAmount,
      CATaxAmountInTransCurrency,
      CATaxPortionInTransCurrency,
      @ObjectModel.foreignKey.association: '_WithholdingTaxCode'
      WithholdingTaxCode,
      CAIsDownPaymentRequest,
      CAStatisticalItemCode,
      CAInvcgOffsettingGroup,
      CAInvcgDfrrdRevenueStatus,
      CAIsRevenueAccountingRelevant,
      CAInvcgRevenueGrouping,
      CARevenueAccountingServiceType,
      CAInvcgAccrualPostingType,
      CAIsPrepaid,
      UnitOfMeasure,
      Quantity,
      CANetDueDate,
      CACashDiscountDueDate,
      CACashDiscountRate,
      CAInvcgDocItemDefStatus,
      CAItemPeriodStartDate,
      CAItemPeriodEndDate,
      CAInvcgRefPostingDocType,
      CADocumentNumber,
      CAGroupingKeyDocumentItems,
      CAInvcgGroupingKey,
      CAClearingDocumentNumber,
      CAClearingAmountInTransCrcy,
      CAInvcgDocItemCrtnMethod,
      CAInvcgFunction,
      CAInvcgSourceDocumentCat,
      CAInvcgSourceDocumentNumber,
      CAInvcgDocItemSourceItmCat,
      CAInvcgSourceDocumentItem,
      CABllbleItmDiscountKey,
      CABllbleItmDiscountVersion,
      CAInvcgCorrectionCategory,

      //applk

      _CAInvcgDocItem._CAInvcgDocHeader.CAApplicationArea as CAApplicationArea,

      case when TaxCountry is initial
        then _CAInvcgDocItem._CompCode._Country.TaxCalculationProcedure
        else _CAInvcgDocItem._TaxCountry.TaxCalculationProcedure
      end                                                 as TaxCalculationProcedure,

      _CAInvcgDocItem._CompCode.Country                   as CompanyCodeCountry,

      /* Associations */
      _CAMainTransaction,
      _CASubTransaction,
      _CAOtherTaxCode,
      _TaxCode,
      _WithholdingTaxCode,
      _TaxJurisdiction,

      _BusinessArea,
      _CAAccountDetnCode,
      _CABllbleItmDiscountKey,
      _CAConditionType,
      _CACurrencySourceDocument,
      _CADeferredRevenueStatus,
      _CADocument,
      _CAInvcgDocHeader,
      _CAInvcgDocItemType,
      _CAInvcgDocItmAltvMDCat,
      _CAInvcgDocItmCrtnMethod,
      _CAInvcgDocItmDefStatus,
      _CAInvcgDocItmSrceItmCat,
      _CAInvcgFunction,
      _CAInvcgItmAltvBusinessPartner,
      _CAInvcgItmAltvContractAccount,
      _CAInvcgRefPostgDocTyp,
      _CAInvcgSourceDocCat,
      _CARevnAcctgServiceType,
      _CAInvcgAccrualPostingType,
      _CAStatisticalItemCode,
      _CASubApplication,
      _CATaxDetnType,
      _CATransactionKeyAcctDetn,
      _CompCode,
      _Division,
      _TaxCountry,
      _TransactionCurrency,
      _UnitOfMeasure,
      _CAInvcgCorrectionCat,
      _CAInvcgOffsettingAction,
      _CAInvcgOffsettingCategory,
      _CAInvcgOffsettingProcedure,

      // Moved from Extension View X_S4C_P_CAINVCGDOCITEM

      _CAInvcgDocItem.CABillToParty,
      _CAInvcgDocItem.CABillToRegion,
      _CAInvcgDocItem.CABillFromRegion,
      _CAInvcgDocItem.CAControlCode,
      _CAInvcgDocItem.CASupplyRegion,
      _CAInvcgDocItem.CABillToCountry,
      _CAInvcgDocItem.WBSElementInternalID,
      _WBSElementBasicData
}