I_TaxCode

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.technicalName: 'IFITAXCODE'

@EndUserText.label: 'Tax Code'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'TaxCode'
@ObjectModel.sapObjectNodeType.name: 'SalesTaxCode'

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING }

@Search.searchable: true

@VDM.viewType: #BASIC

define view entity I_TaxCode
  as select from t007a

  association [0..*] to I_TaxCodeText             as _Text
    on  $projection.TaxCalculationProcedure = _Text.TaxCalculationProcedure
    and $projection.TaxCode                 = _Text.TaxCode

  association [0..1] to I_TaxType                 as _TaxType
    on $projection.TaxType = _TaxType.TaxType

  association [0..1] to I_TaxCalculationProcedure as _TaxCalculationProcedure
    on $projection.TaxCalculationProcedure = _TaxCalculationProcedure.TaxCalculationProcedure

{
      /* start suppress warning shlporigin_not_inherited */
      @ObjectModel.foreignKey.association: '_TaxCalculationProcedure'
  key kalsm                                                as TaxCalculationProcedure,

      /* end suppress warning shlporigin_not_inherited */
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key cast(mwskz as fis_mwskz preserving type)             as TaxCode,

      @ObjectModel.foreignKey.association: '_TaxType'
      mwart                                                as TaxType,

      cast(zmwsk as farp_dzmwsk preserving type)           as TargetTaxCode,
      egrkz                                                as EUTaxClassification,
      xslta                                                as IsSalesTaxes,

      @API.element: { releaseState: #DEPRECATED, successor: 'UnitedStatesTaxCategory' }
      @Consumption.filter.hidden: true
      cast(txind as smwsk)                                 as TaxCategory,

      cast(txind as txind_007a preserving type)            as UnitedStatesTaxCategory,
      /* start suppress warning shlporigin_not_inherited */
      lstml                                                as TaxReturnCountry,
      /* end suppress warning shlporigin_not_inherited */
      cast(tolerance as fot_tax_tolerance preserving type) as TaxTolerancePercent,
      /* start suppress warning shlporigin_not_inherited */
      zmwsk_ese                                            as EUAcqnInputTaxCode,
      zmwsk_esa                                            as EUAcqnOutputTaxCode,
      /* end suppress warning shlporigin_not_inherited */
      xinact                                               as TaxCodeIsInactive,

      @API.element: { releaseState: #DEPRECATED, successor: 'OneStopShopTaxReportingCountry' }
      @Consumption.filter.hidden: true
      mossc                                                as MiniOneStopShopTxRptgCntry,

      mossc                                                as OneStopShopTaxReportingCountry,
      oss_classification                                   as OneStopShopScheme,

      _TaxCalculationProcedure,
      _TaxType,
      _Text
}