I_CAINVCGDOCITEM
Fakturierungsbelegposition
I_CAINVCGDOCITEM is a CDS View in S/4HANA. Fakturierungsbelegposition. It contains 90 fields. 3 CDS views read from this table.
CDS Views using this table (3)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_CABillPrntInvcgDocItem | view_entity | from | COMPOSITE | Fakt.belegposition für Rechnungsausgabe |
| P_CAInvcgDocItem | view_entity | from | COMPOSITE | Invoicing Document Item |
| R_CAInvcgDocItemTP | view_entity | from | TRANSACTIONAL | Invoicing Document Item - TP |
Fields (90)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CAInvcgDocItem | CAInvcgDocItem | 1 |
| KEY | CAInvoicingDocument | CAInvoicingDocument | 1 |
| BusinessArea | BusinessArea | 1 | |
| BusinessPlace | BusinessPlace | 1 | |
| CAAccountDeterminationCode | CAAccountDeterminationCode | 1 | |
| CAAmountInTransactionCurrency | CAAmountInTransactionCurrency | 1 | |
| CABillFromRegion | CABillFromRegion | 1 | |
| CABillToCountry | CABillToCountry | 1 | |
| CABillToParty | CABillToParty | 1 | |
| CABillToRegion | CABillToRegion | 1 | |
| CABllbleItmDiscountKey | CABllbleItmDiscountKey | 1 | |
| CABllbleItmDiscountVersion | CABllbleItmDiscountVersion | 1 | |
| CACashDiscountDueDate | CACashDiscountDueDate | 1 | |
| CACashDiscountRate | CACashDiscountRate | 1 | |
| CAClearingAmountInTransCrcy | CAClearingAmountInTransCrcy | 1 | |
| CAClearingDocumentNumber | CAClearingDocumentNumber | 1 | |
| CAConditionType | CAConditionType | 1 | |
| CAContract | CAContract | 1 | |
| CAControlCode | CAControlCode | 1 | |
| CACurrencySourceDocument | CACurrencySourceDocument | 1 | |
| CADocumentNumber | CADocumentNumber | 1 | |
| CAGroupingCurrencyTranslation | CAGroupingCurrencyTranslation | 1 | |
| CAGroupingKeyDocumentItems | CAGroupingKeyDocumentItems | 1 | |
| CAInvcgAccrualPostingType | CAInvcgAccrualPostingType | 1 | |
| CAInvcgCorrectionCategory | CAInvcgCorrectionCategory | 1 | |
| CAInvcgDfrrdRevenueStatus | CAInvcgDfrrdRevenueStatus | 1 | |
| CAInvcgDocItemCrtnMethod | CAInvcgDocItemCrtnMethod | 1 | |
| CAInvcgDocItemDefStatus | CAInvcgDocItemDefStatus | 1 | |
| CAInvcgDocItemIsReversal | CAInvcgDocItemIsReversal | 1 | |
| CAInvcgDocItemSourceItmCat | CAInvcgDocItemSourceItmCat | 1 | |
| CAInvcgDocItmAltvMDCat | CAInvcgDocItmAltvMDCat | 1 | |
| CAInvcgDocItmAmtInLoclCurrency | CAInvcgDocItmAmtInLoclCurrency | 1 | |
| CAInvcgDocItmLoclCurrency | CAInvcgDocItmLoclCurrency | 1 | |
| CAInvcgDocItmTaxBaseAmtInLCrcy | CAInvcgDocItmTaxBaseAmtInLCrcy | 1 | |
| CAInvcgDocumentItemType | CAInvcgDocumentItemType | 1 | |
| CAInvcgFunction | CAInvcgFunction | 1 | |
| CAInvcgGroupingKey | CAInvcgGroupingKey | 1 | |
| CAInvcgIsInFinalAmt | CAInvcgIsInFinalAmt | 1 | |
| CAInvcgIsItemPostingRelevant | CAInvcgIsItemPostingRelevant | 1 | |
| CAInvcgIsItemPrintingRelevant | CAInvcgIsItemPrintingRelevant | 1 | |
| CAInvcgIsNotBPRelevant | CAInvcgIsNotBPRelevant | 1 | |
| CAInvcgItmAltvBusinessPartner | CAInvcgItmAltvBusinessPartner | 1 | |
| CAInvcgItmAltvContractAccount | CAInvcgItmAltvContractAccount | 1 | |
| CAInvcgOffsettingAction | CAInvcgOffsettingAction | 1 | |
| CAInvcgOffsettingCategory | CAInvcgOffsettingCategory | 1 | |
| CAInvcgOffsettingGroup | CAInvcgOffsettingGroup | 1 | |
| CAInvcgOffsettingProcedure | CAInvcgOffsettingProcedure | 1 | |
| CAInvcgRefPostingDocType | CAInvcgRefPostingDocType | 1 | |
| CAInvcgRevenueGrouping | CAInvcgRevenueGrouping | 1 | |
| CAInvcgSourceDocumentAmount | CAInvcgSourceDocumentAmount | 1 | |
| CAInvcgSourceDocumentCat | CAInvcgSourceDocumentCat | 1 | |
| CAInvcgSourceDocumentItem | CAInvcgSourceDocumentItem | 1 | |
| CAInvcgSourceDocumentNumber | CAInvcgSourceDocumentNumber | 1 | |
| CAInvcgSubstituteGroupPrinting | CAInvcgSubstituteGroupPrinting | 1 | |
| CAInvcgTaxGroupingKey | CAInvcgTaxGroupingKey | 1 | |
| CAIsDocItemSimulated | CAIsDocItemSimulated | 1 | |
| CAIsDownPaymentRequest | CAIsDownPaymentRequest | 1 | |
| CAIsPrepaid | CAIsPrepaid | 1 | |
| CAIsRevenueAccountingRelevant | CAIsRevenueAccountingRelevant | 1 | |
| CAItemPeriodEndDate | CAItemPeriodEndDate | 1 | |
| CAItemPeriodStartDate | CAItemPeriodStartDate | 1 | |
| CAMainTransaction | CAMainTransaction | 1 | |
| CANetDueDate | CANetDueDate | 1 | |
| CAOtherTaxCode | CAOtherTaxCode | 1 | |
| CAProviderContractItemNumber | CAProviderContractItemNumber | 1 | |
| CARevenueAccountingServiceType | CARevenueAccountingServiceType | 1 | |
| CAStatisticalItemCode | CAStatisticalItemCode | 1 | |
| CASubApplication | CASubApplication | 1 | |
| CASubTransaction | CASubTransaction | 1 | |
| CASupplyRegion | CASupplyRegion | 1 | |
| CATaxAmountInTransCurrency | CATaxAmountInTransCurrency | 1 | |
| CATaxBaseAmount | CATaxBaseAmount | 1 | |
| CATaxDate | CATaxDate | 1 | |
| CATaxDeterminationCode | CATaxDeterminationCode | 1 | |
| CATaxDetnType | CATaxDetnType | 1 | |
| CATaxIsIncluded | CATaxIsIncluded | 1 | |
| CATaxPortionInTransCurrency | CATaxPortionInTransCurrency | 1 | |
| CATaxRateInPercent | CATaxRateInPercent | 1 | |
| CATransactionKeyAccountDetn | CATransactionKeyAccountDetn | 1 | |
| CompanyCode | CompanyCode | 1 | |
| Division | Division | 1 | |
| Quantity | Quantity | 1 | |
| TaxCode | TaxCode | 1 | |
| TaxCountry | TaxCountry | 1 | |
| TaxJurisdiction | TaxJurisdiction | 1 | |
| TransactionCurrency | TransactionCurrency | 1 | |
| TransToTaxCntryCrcyCnvrsnFctr | TransToTaxCntryCrcyCnvrsnFctr | 1 | |
| UnitOfMeasure | UnitOfMeasure | 1 | |
| WBSElementInternalID | WBSElementInternalID | 1 | |
| WithholdingTaxCode | WithholdingTaxCode | 1 |
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@Analytics: {
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
mapping: [ {
table: 'dfkkinvdoc_i',
role: #MAIN,
viewElement: ['CAInvoicingDocument', 'CAInvcgDocItem'],
tableElement: ['invdocno', 'invdocitem']
} ]
}
}
}
@VDM.viewType: #BASIC
@ObjectModel: {
usageType: {
serviceQuality: #B,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
},
modelingPattern: #NONE,
representativeKey: 'CAInvcgDocItem',
sapObjectNodeType.name: 'ContrAcctgInvoicingDocumentItm',
supportedCapabilities: [
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET,
#EXTRACTION_DATA_SOURCE
]
}
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@EndUserText.label: 'Fakturierungsbelegposition'
define view entity I_CAInvcgDocItem
as select from dfkkinvdoc_i as invdoc_i
association [1..1] to I_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
association [0..1] to I_CompanyCode as _CompCode on $projection.CompanyCode = _CompCode.CompanyCode
association [0..1] to I_Division as _Division on $projection.Division = _Division.Division
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_BusinessPartner as _CAInvcgItmAltvBusinessPartner on $projection.CAInvcgItmAltvBusinessPartner = _CAInvcgItmAltvBusinessPartner.BusinessPartner
association [0..1] to I_ContractAccountHeader as _CAInvcgItmAltvContractAccount on $projection.CAInvcgItmAltvContractAccount = _CAInvcgItmAltvContractAccount.ContractAccount
association [0..1] to I_CADocument as _CADocument on $projection.CADocumentNumber = _CADocument.CADocumentNumber
association [0..1] to I_CAInvcgDocItmAltvMDCat as _CAInvcgDocItmAltvMDCat on $projection.CAInvcgDocItmAltvMDCat = _CAInvcgDocItmAltvMDCat.CAInvcgDocItmAltvMDCat
association [0..1] to I_CAInvcgDocItemType as _CAInvcgDocItemType on $projection.CAInvcgDocumentItemType = _CAInvcgDocItemType.CAInvcgDocumentItemType
association [0..1] to I_CAInvcgFunction as _CAInvcgFunction on $projection.CAInvcgFunction = _CAInvcgFunction.CAInvcgFunction
association [0..1] to I_CABllbleItmDiscountKey as _CABllbleItmDiscountKey on $projection.CABllbleItmDiscountKey = _CABllbleItmDiscountKey.CABllbleItmDiscountKey
association [0..1] to I_CAInvcgRefPostgDocTyp as _CAInvcgRefPostgDocTyp on $projection.CAInvcgRefPostingDocType = _CAInvcgRefPostgDocTyp.CAInvcgRefPostingDocType
association [0..1] to I_CAInvcgSourceDocCat as _CAInvcgSourceDocCat on $projection.CAInvcgSourceDocumentCat = _CAInvcgSourceDocCat.CAInvcgSourceDocumentCat
association [0..1] to I_ConditionType as _CAConditionType on $projection.CAConditionType = _CAConditionType.ConditionType
and _CAConditionType.ConditionUsage = 'A'
and _CAConditionType.ConditionApplication = 'TX'
association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure
association [0..1] to I_CAStatisticalItemCode as _CAStatisticalItemCode on $projection.CAStatisticalItemCode = _CAStatisticalItemCode.CAStatisticalItemCode
association [0..1] to I_Currency as _TransactionCurrency on $projection.TransactionCurrency = _TransactionCurrency.Currency
association [0..1] to I_Currency as _CACurrencySourceDocument on $projection.CACurrencySourceDocument = _CACurrencySourceDocument.Currency
association [0..1] to I_Currency as _CAInvcgDocItmLoclCurrency on $projection.CAInvcgDocItmLoclCurrency = _CAInvcgDocItmLoclCurrency.Currency
association [0..1] to I_CARevnAcctgServiceType as _CARevnAcctgServiceType on $projection.CARevenueAccountingServiceType = _CARevnAcctgServiceType.CARevenueAccountingServiceType
association [0..1] to I_CAInvcgAccrualPostingType as _CAInvcgAccrualPostingType on $projection.CAInvcgAccrualPostingType = _CAInvcgAccrualPostingType.CAInvcgAccrualPostingType
association [0..1] to I_CAAccountDetnCode as _CAAccountDetnCode on $projection.CAAccountDeterminationCode = _CAAccountDetnCode.CAAccountDeterminationCode
association [0..1] to I_CADeferredRevenueStatus as _CADeferredRevenueStatus on $projection.CAInvcgDfrrdRevenueStatus = _CADeferredRevenueStatus.CAInvcgDfrrdRevenueStatus
association [0..1] to I_CAInvcgDocItmDefStatus as _CAInvcgDocItmDefStatus on $projection.CAInvcgDocItemDefStatus = _CAInvcgDocItmDefStatus.CAInvcgDocItemDefStatus
association [0..1] to I_CAInvcgDocItmCrtnMethod as _CAInvcgDocItmCrtnMethod on $projection.CAInvcgDocItemCrtnMethod = _CAInvcgDocItmCrtnMethod.CAInvcgDocItemCrtnMethod
association [0..1] to I_CAInvcgDocItmSrceItmCat as _CAInvcgDocItmSrceItmCat on $projection.CAInvcgDocItemSourceItmCat = _CAInvcgDocItmSrceItmCat.CAInvcgDocItemSourceItmCat
association [0..1] to I_Country as _TaxCountry on $projection.TaxCountry = _TaxCountry.Country
association [0..1] to I_CATaxDetnType as _CATaxDetnType on $projection.CATaxDetnType = _CATaxDetnType.CATaxDetnType
association [0..1] to I_CASubApplication as _CASubApplication on $projection.CASubApplication = _CASubApplication.CASubApplication
association [0..1] to I_CATransactionKeyAcctDetn as _CATransactionKeyAcctDetn on $projection.CATransactionKeyAccountDetn = _CATransactionKeyAcctDetn.CATransactionKeyAccountDetn
association [0..1] to I_CAInvcgCorrectionCat as _CAInvcgCorrectionCat on $projection.CAInvcgCorrectionCategory = _CAInvcgCorrectionCat.CAInvcgCorrectionCategory
association [0..1] to I_CAInvcgOffsettingAction as _CAInvcgOffsettingAction on $projection.CAInvcgOffsettingAction = _CAInvcgOffsettingAction.CAInvcgOffsettingAction
association [0..1] to I_CAInvcgOffsettingCategory as _CAInvcgOffsettingCategory on $projection.CAInvcgOffsettingCategory = _CAInvcgOffsettingCategory.CAInvcgOffsettingCategory
association [0..1] to I_CAInvcgOffsettingProcedure as _CAInvcgOffsettingProcedure on $projection.CAInvcgOffsettingProcedure = _CAInvcgOffsettingProcedure.CAInvcgOffsettingProcedure
// from X_S4C_I_CAInvcgDocHeader
association [0..1] to I_BusinessPartner as _CABillToParty on $projection.CABillToParty = _CABillToParty.BusinessPartner
association [0..1] to I_Region as _CABillToRegion on $projection.CABillToCountry = _CABillToRegion.Country
and $projection.CABillToRegion = _CABillToRegion.Region
association [0..1] to I_Region as _CABillFromRegion on $projection.CABillToCountry = _CABillFromRegion.Country
and $projection.CABillFromRegion = _CABillFromRegion.Region
association [0..1] to I_Region as _CASupplyRegion on $projection.CABillToCountry = _CASupplyRegion.Country
and $projection.CASupplyRegion = _CASupplyRegion.Region
association [0..1] to I_Country as _CABillToCountry on $projection.CABillToCountry = _CABillToCountry.Country
association [0..1] to I_WBSElementBasicData as _WBSElementBasicData on $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
// extension
association [0..1] to E_CAInvcgDocItem as _Extension on $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
and $projection.CAInvcgDocItem = _Extension.CAInvcgDocItem
// deprecated
association [0..1] to I_CADocumentHeader as _CADocumentHeader on $projection.CADocumentNumber = _CADocumentHeader.CADocumentNumber
{
@ObjectModel.foreignKey.association: '_CAInvcgDocHeader'
key invdocno as CAInvoicingDocument,
key invdocitem as CAInvcgDocItem,
@ObjectModel.foreignKey.association: '_CAInvcgDocItemType'
itemtype as CAInvcgDocumentItemType,
@ObjectModel.foreignKey.association: '_CompCode'
bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_Division'
spart as Division,
vtref as CAContract,
vtpos as CAProviderContractItemNumber,
@ObjectModel.foreignKey.association: '_CASubApplication'
subap as CASubApplication,
@ObjectModel.foreignKey.association: '_CAInvcgItmAltvBusinessPartner'
cast(gpart_a as inv_gpart_a_gfn_kk preserving type) as CAInvcgItmAltvBusinessPartner,
@ObjectModel.foreignKey.association: '_CAInvcgItmAltvContractAccount'
cast(vkont_a as inv_vkont_a_gfn_kk preserving type) as CAInvcgItmAltvContractAccount,
@ObjectModel.foreignKey.association: '_CAInvcgDocItmAltvMDCat'
cast(gpvkt_a_cat as inv_gpvkt_a_cat_gfn_kk preserving type) as CAInvcgDocItmAltvMDCat,
// fkey on upper view
hvorg as CAMainTransaction,
// fkey on upper view
tvorg as CASubTransaction,
item_simulated as CAIsDocItemSimulated,
reversalitem as CAInvcgDocItemIsReversal,
cast(totalrel as totalrel_gfn_kk preserving type) as CAInvcgIsInFinalAmt,
postrel as CAInvcgIsItemPostingRelevant,
not_bprel as CAInvcgIsNotBPRelevant,
printrel as CAInvcgIsItemPrintingRelevant,
print_substitute as CAInvcgSubstituteGroupPrinting,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
waers as TransactionCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
betrw as CAAmountInTransactionCurrency,
@ObjectModel.foreignKey.association: '_CAInvcgDocItmLoclCurrency'
invwaerh as CAInvcgDocItmLoclCurrency,
@Semantics.amount.currencyCode: 'CAInvcgDocItmLoclCurrency'
invbetrh as CAInvcgDocItmAmtInLoclCurrency,
@Semantics.amount.currencyCode: 'CAInvcgDocItmLoclCurrency'
invsbash as CAInvcgDocItmTaxBaseAmtInLCrcy,
@ObjectModel.foreignKey.association: '_CACurrencySourceDocument'
cast(srcdoc_curr as srcdoc_curr_gfn_kk preserving type) as CACurrencySourceDocument,
@Semantics.amount.currencyCode: 'CACurrencySourceDocument'
cast(srcdoc_amt as srcdoc_amt_gfn_kk preserving type) as CAInvcgSourceDocumentAmount,
cast(currc_group as currc_group_gfn_kk preserving type) as CAGroupingCurrencyTranslation,
@ObjectModel.foreignKey.association: '_CAAccountDetnCode'
kofiz as CAAccountDeterminationCode,
cast(bupla as farp_bupla preserving type) as BusinessPlace,
@ObjectModel.foreignKey.association: '_BusinessArea'
cast(gsber as fis_rbusa preserving type) as BusinessArea,
tax_included as CATaxIsIncluded,
@ObjectModel.foreignKey.association: '_CATaxDetnType'
tax_det_type as CATaxDetnType,
taxgr as CAInvcgTaxGroupingKey,
// fkey on upper view
strkz as CAOtherTaxCode,
// fkey on upper view
mwskz as TaxCode,
-- fkey missing
ermwskz as CATaxDeterminationCode,
// fkey on upper view
txjcd as TaxJurisdiction,
@ObjectModel.foreignKey.association: '_CATransactionKeyAcctDetn'
ktosl as CATransactionKeyAccountDetn,
@EndUserText.label: 'Steuerkonditionsart'
@ObjectModel.foreignKey.association: '_CAConditionType'
kschl as CAConditionType,
tax_perc as CATaxRateInPercent,
@ObjectModel.foreignKey.association: '_TaxCountry'
tax_country as TaxCountry,
taxc_factor as TransToTaxCntryCrcyCnvrsnFctr,
@ObjectModel.foreignKey.association: '_CAInvcgOffsettingAction'
offset_action as CAInvcgOffsettingAction,
@ObjectModel.foreignKey.association: '_CAInvcgOffsettingCategory'
offset_cat as CAInvcgOffsettingCategory,
@ObjectModel.foreignKey.association: '_CAInvcgOffsettingProcedure'
offset_proc as CAInvcgOffsettingProcedure,
txdat as CATaxDate,
@Semantics.amount.currencyCode: 'TransactionCurrency'
sbasw as CATaxBaseAmount,
@Semantics.amount.currencyCode: 'TransactionCurrency'
sbetw as CATaxAmountInTransCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
sttax as CATaxPortionInTransCurrency,
// fkey on upper view
qsskz as WithholdingTaxCode,
xanza as CAIsDownPaymentRequest,
@ObjectModel.foreignKey.association: '_CAStatisticalItemCode'
stakz as CAStatisticalItemCode,
offset_invgr as CAInvcgOffsettingGroup,
@ObjectModel.foreignKey.association: '_CADeferredRevenueStatus'
cast(defrev_stat as defrev_stat_gfn_kk preserving type) as CAInvcgDfrrdRevenueStatus,
@Semantics.booleanIndicator:true
rarel as CAIsRevenueAccountingRelevant,
ra_invgr as CAInvcgRevenueGrouping,
@ObjectModel.foreignKey.association: '_CARevnAcctgServiceType'
service_type as CARevenueAccountingServiceType,
@ObjectModel.foreignKey.association: '_CAInvcgAccrualPostingType'
cast(billac_type as billac_type_gfn_kk preserving type) as CAInvcgAccrualPostingType,
prepaid as CAIsPrepaid,
@ObjectModel.foreignKey.association: '_UnitOfMeasure'
meins as UnitOfMeasure,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
menge as Quantity,
faedn as CANetDueDate,
faeds as CACashDiscountDueDate,
sktpz as CACashDiscountRate,
@ObjectModel.foreignKey.association: '_CAInvcgDocItmDefStatus'
xstund as CAInvcgDocItemDefStatus,
date_from as CAItemPeriodStartDate,
date_to as CAItemPeriodEndDate,
@ObjectModel.foreignKey.association: '_CAInvcgRefPostgDocTyp'
cast(cadoctype as cadoctype_gfn_kk preserving type ) as CAInvcgRefPostingDocType,
@ObjectModel.foreignKey.association: '_CADocument'
cast(opbel as opbel_gfn_kk preserving type ) as CADocumentNumber,
psgrp as CAGroupingKeyDocumentItems,
invgr as CAInvcgGroupingKey,
augbl as CAClearingDocumentNumber,
@Semantics.amount.currencyCode: 'TransactionCurrency'
augbw as CAClearingAmountInTransCrcy,
@ObjectModel.foreignKey.association: '_CAInvcgDocItmCrtnMethod'
item_crmet as CAInvcgDocItemCrtnMethod,
@ObjectModel.foreignKey.association: '_CAInvcgFunction'
inv_function as CAInvcgFunction,
@ObjectModel.foreignKey.association: '_CAInvcgSourceDocCat'
cast(srcdoccat as srcdoccat_gfn_kk preserving type) as CAInvcgSourceDocumentCat,
cast(srcdocno as srcdocno_gfn_kk preserving type) as CAInvcgSourceDocumentNumber,
@ObjectModel.foreignKey.association: '_CAInvcgDocItmSrceItmCat'
srcitemcat as CAInvcgDocItemSourceItmCat,
srcdocitem as CAInvcgSourceDocumentItem,
@ObjectModel.foreignKey.association: '_CABllbleItmDiscountKey'
cast(disckey as disckey_gfn_kk preserving type) as CABllbleItmDiscountKey,
disckey_versno as CABllbleItmDiscountVersion,
@ObjectModel.foreignKey.association: '_CAInvcgCorrectionCat'
cast(corrcat as corrcat_gfn_kk preserving type) as CAInvcgCorrectionCategory,
// from X_S4C_I_CAInvcgDocItem
@Feature: 'SW:IN_CONVINV_TAX'
@ObjectModel.foreignKey.association: '_CABillToParty'
bill_to_party as CABillToParty,
@Feature: 'SW:IN_CONVINV_TAX'
@ObjectModel.foreignKey.association: '_CABillToRegion'
bill_to_region as CABillToRegion,
@Feature: 'SW:IN_CONVINV_TAX'
@ObjectModel.foreignKey.association: '_CABillFromRegion'
bill_from_region as CABillFromRegion,
@Feature: 'SW:IN_CONVINV_TAX'
steuc as CAControlCode,
@Feature: 'SW:IN_CONVINV_TAX'
@ObjectModel.foreignKey.association: '_CASupplyRegion'
supply_region as CASupplyRegion,
@Feature: 'SW:IN_CONVINV_TAX'
@ObjectModel.foreignKey.association: '_CABillToCountry'
bill_to_country as CABillToCountry,
@ObjectModel.foreignKey.association: '_WBSElementBasicData'
cast( ps_psp_pnr as fis_wbsint_no_conv preserving type ) as WBSElementInternalID,
// Make association public
_CAInvcgDocHeader,
_CAInvcgFunction,
_CompCode,
_Division,
_BusinessArea,
_TransactionCurrency,
_CAInvcgDocItmLoclCurrency,
_CACurrencySourceDocument,
_CAInvcgItmAltvBusinessPartner,
_CAInvcgItmAltvContractAccount,
_CAStatisticalItemCode,
_CAInvcgDocItemType,
_CABllbleItmDiscountKey,
_CAInvcgSourceDocCat,
_CAInvcgRefPostgDocTyp,
_CADocument,
_CADeferredRevenueStatus,
_CAInvcgDocItmAltvMDCat,
_CAInvcgDocItmDefStatus,
_CAInvcgDocItmCrtnMethod,
_CAInvcgDocItmSrceItmCat,
_CAAccountDetnCode,
_CARevnAcctgServiceType,
_CAInvcgAccrualPostingType,
_CATaxDetnType,
_TaxCountry,
_CASubApplication,
_CATransactionKeyAcctDetn,
_CAConditionType,
_UnitOfMeasure,
_CAInvcgCorrectionCat,
_CAInvcgOffsettingAction,
_CAInvcgOffsettingCategory,
_CAInvcgOffsettingProcedure,
@API.element.releaseState: #DEPRECATED
@API.element.successor: '_CADocument'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_CADocument'
_CADocumentHeader,
@Feature: 'SW:IN_CONVINV_TAX'
_CABillToParty,
@Feature: 'SW:IN_CONVINV_TAX'
_CABillToRegion,
@Feature: 'SW:IN_CONVINV_TAX'
_CABillFromRegion,
@Feature: 'SW:IN_CONVINV_TAX'
_CASupplyRegion,
@Feature: 'SW:IN_CONVINV_TAX'
_CABillToCountry,
_WBSElementBasicData
}