C_CAInvcgDocItem

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel: {
  usageType:{
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  },
  semanticKey: ['CAInvcgDocItem'],
  representativeKey: 'CAInvcgDocItem'
}
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Fakturierungsbelegposition'

define view entity C_CAInvcgDocItem
  as select from P_CAInvcgDocItem as _CAInvcgDocItem

  association [0..1] to C_CAInvcgDocHeader as _CAInvcgDocHeader on  $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument


  // extension

  association [0..1] to E_CAInvcgDocItem   as _Extension        on  $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
                                                                and $projection.CAInvcgDocItem      = _Extension.CAInvcgDocItem
{
      //INVDOCNO      

  key _CAInvcgDocItem.CAInvoicingDocument,

      //INVDOCITEM      

  key _CAInvcgDocItem.CAInvcgDocItem,

      //ITEM_SIMULATED

      _CAInvcgDocItem.CAIsDocItemSimulated,

      //ITEMTYPE    

      @ObjectModel.text.element: ['CAInvcgDocItemTypeText']
      _CAInvcgDocItem.CAInvcgDocumentItemType,

      //VTREF      

      _CAInvcgDocItem.CAContract,

      
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_CINV_VTREF_SEMOBJ'
      }
      cast ( '' as vtref_semobj_kk )                                      as CAContractSemanticObject,

      //BUKRS      

      @ObjectModel.text.element: ['CompanyCodeName']
      _CAInvcgDocItem.CompanyCode,

      //HVORG      

      @ObjectModel.text.element: ['CAMainTransactionName']
      _CAInvcgDocItem.CAMainTransaction,

      //TVORG      

      @ObjectModel.text.element: ['CASubTransactionName']
      _CAInvcgDocItem.CASubTransaction,

      //POSTREL      

      _CAInvcgDocItem.CAInvcgIsItemPostingRelevant,

      //PRINTREL      

      _CAInvcgDocItem.CAInvcgIsItemPrintingRelevant,

      //TOTALREL      

      _CAInvcgDocItem.CAInvcgIsInFinalAmt,

      //Amount and Currency

      _CAInvcgDocItem.TransactionCurrency,
      
      _CAInvcgDocItem.CAAmountInTransactionCurrency,

      // INVWAERH and INVBETRH

      _CAInvcgDocItem.CAInvcgDocItmLoclCurrency,
      _CAInvcgDocItem.CAInvcgDocItmAmtInLoclCurrency,
      _CAInvcgDocItem.CAInvcgDocItmTaxBaseAmtInLCrcy,

      //TAX_INCLUDED

      _CAInvcgDocItem.CATaxIsIncluded,

      //TAXGR

      _CAInvcgDocItem.CAInvcgTaxGroupingKey,

      //MWSKZ

      @ObjectModel.text.element: ['TaxCodeName']
      _CAInvcgDocItem.TaxCode,

      //TAX_PERC

      _CAInvcgDocItem.CATaxRateInPercent,

      //TAX_COUNTRY

      @ObjectModel.text.element: ['TaxCountryName']
      TaxCountry,

      //OFFSET_ACTION

      @ObjectModel.text.element: ['CAInvcgOffsettingActionText']
      CAInvcgOffsettingAction,

      //OFFSET_CAT

      @ObjectModel.text.element: ['CAInvcgOffsettingCategoryTxt']
      CAInvcgOffsettingCategory,

      //OFFSET_PROC

      @ObjectModel.text.element: ['CAInvcgOffsettingProcedText']
      CAInvcgOffsettingProcedure,


      //MENGE

      _CAInvcgDocItem.Quantity,

      //FAEDN

      _CAInvcgDocItem.CANetDueDate,

      //SPART

      @ObjectModel.text.element: ['DivisionName']
      _CAInvcgDocItem.Division,

      //VTPOS

      _CAInvcgDocItem.CAProviderContractItemNumber,

      //SUBAP

      @ObjectModel.text.element: ['CASubApplicationText']
      _CAInvcgDocItem.CASubApplication,

      //GPART_A      

      @ObjectModel.text.association: '_CAInvcgItmAltvBusinessPartner'
      _CAInvcgDocItem.CAInvcgItmAltvBusinessPartner,

      //VKONT_A      

      @ObjectModel.text.association: '_CAInvcgItmAltvContractAccount'
      _CAInvcgDocItem.CAInvcgItmAltvContractAccount,

      //GPVKT_A_CAT

      @ObjectModel.text.element: ['CAInvcgDocItmAltvMDCatText']
      _CAInvcgDocItem.CAInvcgDocItmAltvMDCat,

      //REVERSALITEM

      _CAInvcgDocItem.CAInvcgDocItemIsReversal,

      //NOT_BPREL

      _CAInvcgDocItem.CAInvcgIsNotBPRelevant,

      //PRINT_SUBSTITUTE

      _CAInvcgDocItem.CAInvcgSubstituteGroupPrinting,

      //SRCOC_CURR

      _CAInvcgDocItem.CACurrencySourceDocument,

      //SRCOC_AMT

      @Semantics.amount.currencyCode: 'CACURRENCYSOURCEDOCUMENT'
      _CAInvcgDocItem.CAInvcgSourceDocumentAmount,

      //CURR_GROUP

      _CAInvcgDocItem.CAGroupingCurrencyTranslation,

      //KOFIZ

      _CAInvcgDocItem.CAAccountDeterminationCode,

      //BUPLA

      _CAInvcgDocItem.BusinessPlace,

      //GSBER

      @ObjectModel.text.element: ['BusinessAreaName']
      _CAInvcgDocItem.BusinessArea,

      //TAX_DET_TYPE

      @ObjectModel.text.element: ['CATaxDetnTypeText']
      _CAInvcgDocItem.CATaxDetnType,

      // STRKZ

      @ObjectModel.text.element: ['CAOtherTaxCodeName']
      @ObjectModel.foreignKey.association: '_CAOtherTaxCode'
      _CAInvcgDocItem.CAOtherTaxCode,

      //ERMWSKZ

      _CAInvcgDocItem.CATaxDeterminationCode,

      //TXJCD

      @ObjectModel.text.element: ['TaxJurisdictionName']
      _CAInvcgDocItem.TaxJurisdiction,

      //KTOSL

      @ObjectModel.text.element: ['CATransactionKeyAcctDetnText']
      _CAInvcgDocItem.CATransactionKeyAccountDetn,

      //KSCHL

      @ObjectModel.text.element: ['ConditionTypeName']
      _CAInvcgDocItem.CAConditionType,

      //TXCAT

      _CAInvcgDocItem.CATaxDate,

      //SBASW

      _CAInvcgDocItem.CATaxBaseAmount,

      //SBETW

      _CAInvcgDocItem.CATaxAmountInTransCurrency,

      //STTAX

      _CAInvcgDocItem.CATaxPortionInTransCurrency,

      //QSSKZ

      _CAInvcgDocItem.WithholdingTaxCode,

      //XANZA

      _CAInvcgDocItem.CAIsDownPaymentRequest,

      //STAKZ

      @ObjectModel.text.element: ['CAStatisticalItemCodeText']
      _CAInvcgDocItem.CAStatisticalItemCode,

      //OFFSET_INV_GR

      _CAInvcgDocItem.CAInvcgOffsettingGroup,

      //DEFREV_STAT

      @ObjectModel.text.element: ['CADeferredRevenueStatusText']
      _CAInvcgDocItem.CAInvcgDfrrdRevenueStatus,

      //RAREL

      _CAInvcgDocItem.CAIsRevenueAccountingRelevant,

      //RA_INVGR

      _CAInvcgDocItem.CAInvcgRevenueGrouping,

      //SERVICE_TYPE

      @ObjectModel.text.element: ['CARevnAcctgServiceTypeText']
      _CAInvcgDocItem.CARevenueAccountingServiceType,

      //BILLAC_TYPE

      @ObjectModel.text.element: ['CAInvcgAccrualPostingTypeTxt']
      _CAInvcgDocItem.CAInvcgAccrualPostingType,

      //PREPAID

      _CAInvcgDocItem.CAIsPrepaid,

      //MEINS

      @ObjectModel.text.element: ['UnitOfMeasureName']
      _CAInvcgDocItem.UnitOfMeasure,

      //FAEDS

      _CAInvcgDocItem.CACashDiscountDueDate,

      //SKTPZ

      _CAInvcgDocItem.CACashDiscountRate,

      //XSTUND

      @ObjectModel.text.element: ['CAInvcgDocItmDefStatusText']
      _CAInvcgDocItem.CAInvcgDocItemDefStatus,

      //DATE_FROM

      _CAInvcgDocItem.CAItemPeriodStartDate,

      //DATE_TO

      _CAInvcgDocItem.CAItemPeriodEndDate,

      //CADOCTYPE

      @ObjectModel.text.element: ['CAInvcgRefPostgDocTypeTxt']
      _CAInvcgDocItem.CAInvcgRefPostingDocType,

      //OPBEL      

      _CAInvcgDocItem.CADocumentNumber,

      //PSGRP

      _CAInvcgDocItem.CAGroupingKeyDocumentItems,

      //INVGR

      _CAInvcgDocItem.CAInvcgGroupingKey,

      //AUGBL

      _CAInvcgDocItem.CAClearingDocumentNumber,

      //AUGBW

      _CAInvcgDocItem.CAClearingAmountInTransCrcy,

      //CRMET

      @ObjectModel.text.element: ['CAInvcgDocItmCrtnMethodText']
      _CAInvcgDocItem.CAInvcgDocItemCrtnMethod,

      //INV_FUNCTION

      @ObjectModel.text.element: ['CAInvcgFunctionText']
      _CAInvcgDocItem.CAInvcgFunction,

      //SRCDOCCAT

      @ObjectModel.text.element: ['CAInvcgSourceDocCatText']
      _CAInvcgDocItem.CAInvcgSourceDocumentCat,

      //SRCDOCNO

      _CAInvcgDocItem.CAInvcgSourceDocumentNumber,
      
      _CAInvcgDocItem._CAInvcgSourceDocCat.CAInvcgSourceDocumentSemObj,

      //SRCITEMCAT

      @ObjectModel.text.element: ['CAInvcgDocItmSrceItmCatText']
      _CAInvcgDocItem.CAInvcgDocItemSourceItmCat,

      //SRDOCITEM

      _CAInvcgDocItem.CAInvcgSourceDocumentItem,

      //DISCKEY

      @ObjectModel.text.element: ['CABllbleItmDiscountKeyText']
      _CAInvcgDocItem.CABllbleItmDiscountKey,

      //DISCKEY_VERSNO

      _CAInvcgDocItem.CABllbleItmDiscountVersion,

      //CORRCAT

      @ObjectModel.text.element: ['CAInvcgCorrectionCatText']
      _CAInvcgDocItem.CAInvcgCorrectionCategory,

      //applk

      @Consumption.hidden: true
      CAApplicationArea,
      @Consumption.hidden: true
      TaxCalculationProcedure,
      @Consumption.hidden: true
      CompanyCodeCountry,

      
      _CAInvcgDocItem._CompCode.CompanyCodeName,
      
      _CAMainTransaction._Text[1: Language=$session.system_language].CAMainTransactionName,
      
      _CASubTransaction._Text[1: Language=$session.system_language].CASubTransactionName,
      
      _CAInvcgDocItemType._CAInvcgDocItemTypeText[1: Language=$session.system_language].CAInvcgDocItemTypeText,
      
      _CASubApplication._CASubApplicationText[1: Language=$session.system_language].CASubApplicationText,
      
      _Division._Text[1: Language=$session.system_language].DivisionName,
      
      _CAInvcgDocItmAltvMDCat._CAInvcgDocItmAltvMDCatText[1: Language=$session.system_language].CAInvcgDocItmAltvMDCatText,
      
      _BusinessArea._Text[1: Language=$session.system_language].BusinessAreaName,
      
      _TaxCountry._Text[1: Language=$session.system_language].CountryName as TaxCountryName,
      
      _CAInvcgOffsettingAction._Text[1: Language=$session.system_language].CAInvcgOffsettingActionText,
      
      _CAInvcgOffsettingCategory._Text[1: Language=$session.system_language].CAInvcgOffsettingCategoryTxt,
      
      _CAInvcgOffsettingProcedure._Text[1: Language=$session.system_language].CAInvcgOffsettingProcedText,
      
      _CATaxDetnType._CATaxDetnTypeText[1: Language=$session.system_language].CATaxDetnTypeText,
      
      _CAOtherTaxCode._Text[1: Language=$session.system_language].CAOtherTaxCodeName,
      
      _TaxCode._Text[1: Language=$session.system_language].TaxCodeName,
      
      _TaxJurisdiction._Text[1: Language=$session.system_language].TaxJurisdictionName,
      
      _CAConditionType._Text[1: Language=$session.system_language].ConditionTypeName,
      
      _CATransactionKeyAcctDetn._CATransactionKeyAcctDetnText[1: Language=$session.system_language].CATransactionKeyAcctDetnText,
      
      _CAStatisticalItemCode._CAStatisticalItemCodeText[1: Language=$session.system_language].CAStatisticalItemCodeText,
      
      _CADeferredRevenueStatus._CADeferredRevenueStatusText[1: Language=$session.system_language].CADeferredRevenueStatusText,
      
      _CAInvcgDocItmDefStatus._CAInvcgDocItmDefStatusText[1: Language=$session.system_language].CAInvcgDocItmDefStatusText,
      
      _CARevnAcctgServiceType._CARevnAcctgServiceTypeText[1: Language=$session.system_language].CARevnAcctgServiceTypeText,
      
      _CAInvcgAccrualPostingType._Text[1: Language=$session.system_language].CAInvcgAccrualPostingTypeTxt,
      
      _CAInvcgRefPostgDocTyp._CAInvcgRefPostgDocTypTxt[1: Language=$session.system_language].CAInvcgRefPostgDocTypeTxt,
      
      _CAInvcgDocItmCrtnMethod._CAInvcgDocItmCrtnMethodText[1: Language=$session.system_language].CAInvcgDocItmCrtnMethodText,
      
      _CAInvcgFunction._CAInvcgFunctionText[1: Language=$session.system_language].CAInvcgFunctionText,
      
      _CAInvcgSourceDocCat._CAInvcgSourceDocCatText[1: Language=$session.system_language].CAInvcgSourceDocCatText,
      
      _CAInvcgDocItmSrceItmCat._CAInvcgDocItmSrceItmCatText[1: Language=$session.system_language].CAInvcgDocItmSrceItmCatText,
      
      _CABllbleItmDiscountKey._CABllbleItmDiscountKeyText[1: Language=$session.system_language].CABllbleItmDiscountKeyText,
      
      _UnitOfMeasure._Text[1: Language=$session.system_language].UnitOfMeasureName,
      
      _CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,

      _CAInvcgDocHeader,
      _CAMainTransaction,
      _CASubTransaction,
      _CAOtherTaxCode,
      _TaxCode,
      _WithholdingTaxCode,
      _TaxJurisdiction,

      _BusinessArea,
      _CAAccountDetnCode,
      _CABllbleItmDiscountKey,
      _CAConditionType,
      _CACurrencySourceDocument,
      _CADeferredRevenueStatus,
      _CADocument,
      _CAInvcgDocItemType,
      _CAInvcgDocItmAltvMDCat,
      _CAInvcgDocItmCrtnMethod,
      _CAInvcgDocItmDefStatus,
      _CAInvcgDocItmSrceItmCat,
      _CAInvcgFunction,
      _CAInvcgItmAltvBusinessPartner,
      _CAInvcgItmAltvContractAccount,
      _CAInvcgRefPostgDocTyp,
      _CAInvcgSourceDocCat,
      _CARevnAcctgServiceType,
      _CAInvcgAccrualPostingType,
      _CAStatisticalItemCode,
      _CASubApplication,
      _CATaxDetnType,
      _CATransactionKeyAcctDetn,
      _CompCode,
      _Division,
      _TaxCountry,
      _TransactionCurrency,
      _UnitOfMeasure,
      _CAInvcgCorrectionCat,
      _CAInvcgOffsettingAction,
      _CAInvcgOffsettingCategory,
      _CAInvcgOffsettingProcedure,

      // Moved from Extension View X_S4C_C_CAINVCGDOCITEM

      _CAInvcgDocItem.CABillToParty,
      _CAInvcgDocItem.CABillToRegion,
      _CAInvcgDocItem.CABillFromRegion,
      _CAInvcgDocItem.CAControlCode,
      _CAInvcgDocItem.CASupplyRegion,
      _CAInvcgDocItem.CABillToCountry,
      @UI.hidden: true
      _CAInvcgDocItem.WBSElementInternalID,
      @ObjectModel.text.element: [ 'WBSDescription' ]
      _WBSElementBasicData.WBSElementExternalID,
      _WBSElementBasicData.WBSDescription,
      _WBSElementBasicData
}