I_Supplier
Supplier
I_Supplier is a Basic CDS View (Dimension) that provides data about "Supplier" in SAP S/4HANA. It reads from 1 data source (lfa1) and exposes 155 fields with key field Supplier. It has 25 associations to related views. It is exposed through 5 OData services (UI_INBOUNDDELIVERYMANAGE, UI_KANBANCONTAINER_MONITOR, UI_KANBANSUMZDJITCALL_MON, ...). Part of development package VDM_MD_COMMON.
Data Sources (1)
| Source | Alias | Join Type |
|---|---|---|
| lfa1 | lfa1 | from |
Associations (25)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [1..1] | I_SupplierToBusinessPartner | _SupplierToBusinessPartner | $projection.Supplier = _SupplierToBusinessPartner.Supplier |
| [0..1] | bp1020 | _FiscalData | lfa1.lifnr = _FiscalData.partnr |
| [0..*] | I_SupplierCompany | _SupplierCompany | $projection.Supplier = _SupplierCompany.Supplier |
| [0..*] | I_SupplierPurchasingOrg | _SupplierPurchasingOrg | $projection.Supplier = _SupplierPurchasingOrg.Supplier |
| [0..*] | I_SupplierBankDetails | _SupplierBankDetails | $projection.Supplier = _SupplierBankDetails.Supplier |
| [0..1] | I_SupplierAccountGroup | _SupplierAccountGroup | $projection.SupplierAccountGroup = _SupplierAccountGroup.SupplierAccountGroup |
| [0..*] | I_Industries | _Industry | $projection.Industry = _Industry.IndustrySector |
| [0..1] | I_Customer | _CorrespondingCustomer | $projection.Customer = _CorrespondingCustomer.Customer |
| [0..*] | I_SupplierAccountGroupText | _SupplierAccountGroupText | $projection.SupplierAccountGroup = _SupplierAccountGroupText.SupplierAccountGroup |
| [0..*] | I_SupplierIndustryText | _SupplierIndustryText | $projection.Industry = _SupplierIndustryText.SupplierIndustry |
| [0..1] | I_ProcurementBlock | _ProcurementBlock | $projection.SupplierProcurementBlock = _ProcurementBlock.ProcurementBlock |
| [0..1] | I_QualityManagementSystem | _QualityManagementSystem | $projection.SuplrQualityManagementSystem = _QualityManagementSystem.QualityManagementSystem |
| [1..1] | I_Address | _StandardAddress | $projection.AddressID = _StandardAddress.AddressID |
| [0..1] | E_Supplier | _SupplierExt | $projection.Supplier = _SupplierExt.Supplier |
| [0..1] | I_OrganizationAddress | _AddressDefaultRepresentation | $projection.AddressID = _AddressDefaultRepresentation.AddressID and _AddressDefaultRepresentation.AddressRepresentationCode is initial |
| [0..1] | I_Address_2 | _AddressRepresentation | $projection.AddressID = _AddressRepresentation.AddressID and _AddressRepresentation.AddressRepresentationCode is initial and _AddressRepresentation.AddressPersonID is initial |
| [0..*] | I_AddressEmailAddress_2 | _EmailAddress | _EmailAddress.AddressID = $projection.AddressID and _EmailAddress.AddressPersonID is initial |
| [0..1] | I_AddrCurDefaultEmailAddress | _CurrentDfltEmailAddress | _CurrentDfltEmailAddress.AddressID = $projection.AddressID and _CurrentDfltEmailAddress.AddressPersonID is initial |
| [0..*] | I_AddressPhoneNumber_2 | _PhoneNumber | _PhoneNumber.AddressID = $projection.AddressID and _PhoneNumber.AddressPersonID is initial |
| [0..1] | I_AddrCurDfltLandlinePhoneNmbr | _CurrentDfltLandlinePhoneNmbr | _CurrentDfltLandlinePhoneNmbr.AddressID = $projection.AddressID and _CurrentDfltLandlinePhoneNmbr.AddressPersonID is initial |
| [0..1] | I_AddrCurDfltMobilePhoneNumber | _CurrentDfltMobilePhoneNumber | _CurrentDfltMobilePhoneNumber.AddressID = $projection.AddressID and _CurrentDfltMobilePhoneNumber.AddressPersonID is initial |
| [0..*] | I_AddressFaxNumber_2 | _FaxNumber | _FaxNumber.AddressID = $projection.AddressID and _FaxNumber.AddressPersonID is initial |
| [0..1] | I_AddrCurDefaultFaxNumber | _CurrentDfltFaxNumber | _CurrentDfltFaxNumber.AddressID = $projection.AddressID and _CurrentDfltFaxNumber.AddressPersonID is initial |
| [0..*] | I_AddressURI | _UniformResourceIdentifier | _UniformResourceIdentifier.AddressID = $projection.AddressID and _UniformResourceIdentifier.AddressPersonID is initial |
| [0..1] | I_AddressMainWebsiteURL | _MainWebsiteURL | _MainWebsiteURL.AddressID = $projection.AddressID and _MainWebsiteURL.AddressPersonID is initial |
Annotations (18)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.sqlViewName | I_SUPPLIER_CDS | view | |
| AbapCatalog.preserveKey | true | view | |
| AccessControl.personalData.blocking | #REQUIRED | view | |
| AccessControl.personalData.blockingIndicator | IsBusinessPurposeCompleted | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| Analytics.dataCategory | #DIMENSION | view | |
| Analytics.dataExtraction.enabled | true | view | |
| ClientHandling.algorithm | #SESSION_VARIABLE | view | |
| EndUserText.label | Supplier | view | |
| Metadata.allowExtensions | true | view | |
| Metadata.ignorePropagatedAnnotations | true | view | |
| ObjectModel.modelingPattern | #ANALYTICAL_DIMENSION | view | |
| ObjectModel.representativeKey | Supplier | view | |
| ObjectModel.usageType.serviceQuality | #A | view | |
| ObjectModel.usageType.sizeCategory | #XL | view | |
| ObjectModel.usageType.dataClass | #MASTER | view | |
| VDM.viewType | #BASIC | view | |
| ObjectModel.sapObjectNodeType.name | Supplier | view |
OData Services (5)
| Service | Binding | Version | Contract | Release |
|---|---|---|---|---|
| UI_INBOUNDDELIVERYMANAGE | UI_INBOUNDDELIVERYMANAGE | V4 | C1 | NOT_RELEASED |
| UI_KANBANCONTAINER_MONITOR | UI_KANBANCONTAINER_MONITOR | V4 | C1 | NOT_RELEASED |
| UI_KANBANSUMZDJITCALL_MON | UI_KANBANSUMZDJITCALL_MON | V4 | C1 | NOT_RELEASED |
| UI_RFM_PO_MNG | UI_RFM_PO_MNG | V2 | C1 | NOT_RELEASED |
| UI_SUPLRUSRDFNDCRITRA_MANAGE | UI_SUPLRUSRDFNDCRITRA | V2 | C1 | NOT_RELEASED |
Fields (155)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | Supplier | |||
| SupplierAccountGroup | ktokk | Account Group | ||
| SupplierName | ||||
| BPSupplierName | Business Partner - Supplier Name | |||
| BPSupplierFullName | Business Partner - Supplier Full Name | |||
| BusinessPartnerName1 | _AddressDefaultRepresentation | AddresseeName1 | Business Partner Organization - Name 1 | |
| BusinessPartnerName2 | _AddressDefaultRepresentation | AddresseeName2 | Business Partner Organization - Name 2 | |
| BusinessPartnerName3 | _AddressDefaultRepresentation | AddresseeName3 | Business Partner Organization - Name 3 | |
| BusinessPartnerName4 | _AddressDefaultRepresentation | AddresseeName4 | Business Partner Organization - Name 4 | |
| BPAddrCityName | _AddressDefaultRepresentation | CityName | Business Partner Address – City | |
| BPAddrStreetName | _AddressDefaultRepresentation | StreetName | Business Partner Address – Street | |
| AddressSearchTerm1 | _AddressDefaultRepresentation | AddressSearchTerm1 | Business Partner Address - Search Term 1 | |
| AddressSearchTerm2 | _AddressDefaultRepresentation | AddressSearchTerm2 | Business Partner Address - Search Term 2 | |
| DistrictName | _AddressDefaultRepresentation | DistrictName | Business Partner Address – District | |
| POBoxDeviatingCityName | _AddressDefaultRepresentation | POBoxDeviatingCityName | Business Partner Address - PO Box Deviating City | |
| BusinessPartnerFormOfAddress | _AddressDefaultRepresentation | FormOfAddress | Business Partner - Form of Address | |
| IsBusinessPurposeCompleted | lfa1 | cvp_xblck | ||
| CreatedByUser | ernam | Created By | ||
| CreationDate | erdat | |||
| IsOneTimeAccount | xcpdk | |||
| AuthorizationGroup | begru | |||
| VATRegistration | stceg | |||
| AccountIsBlockedForPosting | sperr | Posting Block(Deprecated) | ||
| TaxJurisdiction | txjcd | |||
| SupplierStandardCarrierAccess | scacd | |||
| SupplierFwdAgentFreightGroup | sfrgr | |||
| SupplierAgentProcedureGroup | dlgrp | |||
| SupplIsSocialInsuranceRegtrd | regss | |||
| SocialInsuranceActivityCode | actss | |||
| SupplierCorporateGroup | konzs | Group Key | ||
| Customer | kunnr | |||
| Industry | brsch | |||
| TaxNumber1 | stcd1 | |||
| TaxNumber2 | stcd2 | |||
| TaxNumber3 | stcd3 | |||
| TaxNumber4 | stcd4 | |||
| TaxNumber5 | stcd5 | |||
| TaxNumber6 | stcd6 | |||
| PostingIsBlocked | sperr | |||
| PurchasingIsBlocked | sperm | Purch. Block | ||
| InternationalLocationNumber1 | bbbnr | |||
| InternationalLocationNumber2 | bbsnr | |||
| InternationalLocationNumber3 | bubkz | Check Digit | ||
| AddressID | adrnr | |||
| Region | lfa1 | regio | ||
| OrganizationBPName1 | lfa1 | name1 | ||
| OrganizationBPName2 | lfa1 | name2 | ||
| CityName | lfa1 | ort01 | ||
| PostalCode | lfa1 | pstlz | ||
| StreetName | lfa1 | stras | ||
| Country | lfa1 | land1 | ||
| SupplierProcurementBlock | sperq | |||
| SuplrQualityManagementSystem | qssys | |||
| SuplrQltyInProcmtCertfnValidTo | qssysdat | |||
| SupplierLanguage | lfa1 | spras | ||
| AlternativePayeeAccountNumber | lfa1 | lnrza | ||
| PhoneNumber1 | lfa1 | telf1 | ||
| FaxNumber | lfa1 | telfx | ||
| IsNaturalPerson | lfa1 | stkzn | ||
| TaxNumberResponsible | lfa1 | stenr | ||
| UK_ContractorBusinessType | lfa1 | categ | ||
| UK_PartnerTradingName | lfa1 | partner_name | ||
| UK_PartnerTaxReference | lfa1 | partner_utr | ||
| UK_VerificationStatus | lfa1 | status | ||
| UK_VerificationNumber | lfa1 | vfnum | ||
| UK_CompanyRegistrationNumber | lfa1 | crn | ||
| UK_VerifiedTaxStatus | lfa1 | vfnid | ||
| FormOfAddress | lfa1 | anred | ||
| ReferenceAccountGroup | lfa1 | ktock | ||
| VATLiability | lfa1 | stkzu | ||
| ResponsibleType | lfa1 | fityp | Tax Type | |
| TaxNumberType | lfa1 | stcdt | Tax Number Type | |
| FiscalAddress | lfa1 | fiskn | Fiscal Address | |
| BusinessType | lfa1 | j_1kftbus | ||
| BirthDate | lfa1 | gbdat | ||
| CreditorInformationNumber | lfa1 | kraus | ||
| PaymentIsBlockedForSupplier | lfa1 | sperz | Payment Block | |
| SortField | lfa1 | sortl | Search Term | |
| PhoneNumber2 | lfa1 | telf2 | ||
| DeletionIndicator | lfa1 | loevm | ||
| TaxInvoiceRepresentativeName | j_1kfrepre | |||
| IndustryType | j_1kftind | |||
| IN_GSTSupplierClassification | lfa1 | ven_class | ||
| SuplrProofOfDelivRlvtCode | lfa1 | podkzb | ||
| TradingPartner | lfa1 | vbund | ||
| BR_TaxIsSplit | lfa1 | ipisp | Tax Split | |
| AU_PayerIsPayingToCarryOnEnt | lfa1 | au_carrying_ent | ||
| AU_IndividualIsUnder18 | lfa1 | au_ind_under_18 | ||
| AU_PaymentIsExceeding75 | lfa1 | au_payment_not_exceed_75 | Payment Does not Exc | |
| AU_PaymentIsWhollyInputTaxed | lfa1 | au_wholly_inp_taxed | ||
| AU_PartnerIsSupplyWithoutGain | lfa1 | au_partner_without_gain | Individual w/o Gain | |
| AU_SupplierIsEntitledToABN | lfa1 | au_not_entitled_abn | ||
| AU_PaymentIsIncomeExempted | lfa1 | au_payment_exempt | ||
| AU_SupplyIsMadeAsPrivateHobby | lfa1 | au_private_hobby | ||
| AU_SupplyMadeIsOfDmstcNature | lfa1 | au_domestic_nature | ||
| IsToBeAcceptedAtOrigin | lfa1 | weora | ||
| BPIsEqualizationTaxSubject | ||||
| BRSpcfcTaxBasePercentageCode | lfa1 | taxbs | ||
| SupplierProfession | lfa1 | profs | ||
| SuplrManufacturerExternalName | lfa1 | emnfr | ||
| DataMediumExchangeIndicator | lfa1 | dtams | ||
| DataExchangeInstructionKey | lfa1 | dtaws | ||
| SupplierIsSubRangeRelevant | lfa1 | ltsna | VSR Relevant | |
| TrainStationName | lfa1 | bahns | Train Station | |
| AlternativePayeeIsAllowed | lfa1 | xzemp | ||
| PaytSlipWthRefSubscriber | lfa1 | esrnr | ||
| TranspServiceAgentStstcGrp | lfa1 | stgdl | Stat. Grp, Agent | |
| SupplierIsPlantRelevant | lfa1 | werkr | Plant Level Relevant | |
| SuplrTaxAuthorityAccountNumber | lfa1 | fisku | ||
| SuplrCarrierConfirmIsExpected | carrier_conf | |||
| SupplierPlant | lfa1 | werks | ||
| FactoryCalendar | lfa1 | plkal | ||
| PaymentReason | lfa1 | paytrsn | ||
| SupplierCentralDeletionIsBlock | lfa1 | nodel | Central Del. Block | |
| DataControllerSet | lfa1 | xdcset | ||
| DataController1 | lfa1 | data_ctrlr1 | ||
| DataController2 | lfa1 | data_ctrlr2 | ||
| DataController3 | lfa1 | data_ctrlr3 | ||
| DataController4 | lfa1 | data_ctrlr4 | ||
| DataController5 | lfa1 | data_ctrlr5 | ||
| DataController6 | lfa1 | data_ctrlr6 | ||
| DataController7 | lfa1 | data_ctrlr7 | ||
| DataController8 | lfa1 | data_ctrlr8 | ||
| DataController9 | lfa1 | data_ctrlr9 | ||
| DataController10 | lfa1 | data_ctrlr10 | ||
| SupplierTransportationChain | lfa1 | transport_chain | ||
| SupplierStagingTimeInDays | lfa1 | staging_time | ||
| SupplierSchedulingProcedure | lfa1 | scheduling_type | ||
| CollectiveNumberingIsRelevant | lfa1 | submi_relevant | ||
| BusinessPartnerPanNumber | lfa1 | j_1ipanno | ||
| BPPanReferenceNumber | lfa1 | j_1ipanref | ||
| BPPanValidFromDate | lfa1 | j_1ipanvaldt | ||
| _SupplierCompany | _SupplierCompany | |||
| _SupplierPurchasingOrg | _SupplierPurchasingOrg | |||
| _SupplierBankDetails | _SupplierBankDetails | |||
| _SupplierAccountGroup | _SupplierAccountGroup | |||
| _SupplierAccountGroupText | _SupplierAccountGroupText | |||
| _SupplierIndustryText | _SupplierIndustryText | |||
| _Industry | _Industry | |||
| _StandardAddress | _StandardAddress | |||
| _CorrespondingCustomer | _CorrespondingCustomer | |||
| _SupplierToBusinessPartner | _SupplierToBusinessPartner | |||
| _ProcurementBlock | _ProcurementBlock | |||
| _QualityManagementSystem | _QualityManagementSystem | |||
| _AddressDefaultRepresentation | _AddressDefaultRepresentation | |||
| _AddressRepresentation | _AddressRepresentation | |||
| _EmailAddress | _EmailAddress | |||
| _CurrentDfltEmailAddress | _CurrentDfltEmailAddress | |||
| _PhoneNumber | _PhoneNumber | |||
| _CurrentDfltLandlinePhoneNmbr | _CurrentDfltLandlinePhoneNmbr | |||
| _CurrentDfltMobilePhoneNumber | _CurrentDfltMobilePhoneNumber | |||
| _FaxNumber | _FaxNumber | |||
| _CurrentDfltFaxNumber | _CurrentDfltFaxNumber | |||
| _UniformResourceIdentifier | _UniformResourceIdentifier | |||
| _MainWebsiteURL | _MainWebsiteURL |
@AbapCatalog.sqlViewName: 'I_SUPPLIER_CDS'
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_AddressDefaultRepresentation','_AddressRepresentation']
@Analytics: {
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
mapping:[
{
table: 'LFA1', role: #MAIN,
viewElement: ['Supplier'],
tableElement: ['lifnr']
},
{
table: 'ADRC', role: #LEFT_OUTER_TO_ONE_JOIN,
viewElement: ['AddressID'],
tableElement: ['Addrnumber']
} ]
}
}
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Supplier'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET,
#ANALYTICAL_DIMENSION,
#EXTRACTION_DATA_SOURCE]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'Supplier'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #BASIC
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@ObjectModel.sapObjectNodeType.name: 'Supplier'
define view I_Supplier
as select from lfa1
//private associations
association [1..1] to I_SupplierToBusinessPartner as _SupplierToBusinessPartner on $projection.Supplier = _SupplierToBusinessPartner.Supplier
association [0..1] to bp1020 as _FiscalData on lfa1.lifnr = _FiscalData.partnr // technically wrong for lifnr<>but000.partner, but usage of $projection.BusinessPartner is not allowed. H
//public composition associations
association [0..*] to I_SupplierCompany as _SupplierCompany on $projection.Supplier = _SupplierCompany.Supplier
association [0..*] to I_SupplierPurchasingOrg as _SupplierPurchasingOrg on $projection.Supplier = _SupplierPurchasingOrg.Supplier
association [0..*] to I_SupplierBankDetails as _SupplierBankDetails on $projection.Supplier = _SupplierBankDetails.Supplier
//public value helps
association [0..1] to I_SupplierAccountGroup as _SupplierAccountGroup on $projection.SupplierAccountGroup = _SupplierAccountGroup.SupplierAccountGroup
association [0..*] to I_Industries as _Industry on $projection.Industry = _Industry.IndustrySector
//public foreign key associations
association [0..1] to I_Customer as _CorrespondingCustomer on $projection.Customer = _CorrespondingCustomer.Customer
////public texts
association [0..*] to I_SupplierAccountGroupText as _SupplierAccountGroupText on $projection.SupplierAccountGroup = _SupplierAccountGroupText.SupplierAccountGroup
association [0..*] to I_SupplierIndustryText as _SupplierIndustryText on $projection.Industry = _SupplierIndustryText.SupplierIndustry
////public foreign key associations
//quality management
association [0..1] to I_ProcurementBlock as _ProcurementBlock on $projection.SupplierProcurementBlock = _ProcurementBlock.ProcurementBlock
association [0..1] to I_QualityManagementSystem as _QualityManagementSystem on $projection.SuplrQualityManagementSystem = _QualityManagementSystem.QualityManagementSystem
association [1..1] to I_Address as _StandardAddress on $projection.AddressID = _StandardAddress.AddressID
// association [1..1] to I_BusinessPartnerAddress as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
// and $projection.AddressID = _BusinessPartnerAddress.AddressNumber
association [0..1] to E_Supplier as _SupplierExt on $projection.Supplier = _SupplierExt.Supplier
// association added for I_ADDRESS_2 adoption
association [0..1] to I_OrganizationAddress as _AddressDefaultRepresentation on $projection.AddressID = _AddressDefaultRepresentation.AddressID
and _AddressDefaultRepresentation.AddressRepresentationCode is initial
association [0..1] to I_Address_2 as _AddressRepresentation on $projection.AddressID = _AddressRepresentation.AddressID
and _AddressRepresentation.AddressRepresentationCode is initial
and _AddressRepresentation.AddressPersonID is initial
//Adoption from I_Address_2
association [0..*] to I_AddressEmailAddress_2 as _EmailAddress on _EmailAddress.AddressID = $projection.AddressID
and _EmailAddress.AddressPersonID is initial
association [0..1] to I_AddrCurDefaultEmailAddress as _CurrentDfltEmailAddress on _CurrentDfltEmailAddress.AddressID = $projection.AddressID
and _CurrentDfltEmailAddress.AddressPersonID is initial
association [0..*] to I_AddressPhoneNumber_2 as _PhoneNumber on _PhoneNumber.AddressID = $projection.AddressID
and _PhoneNumber.AddressPersonID is initial
association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on _CurrentDfltLandlinePhoneNmbr.AddressID = $projection.AddressID
and _CurrentDfltLandlinePhoneNmbr.AddressPersonID is initial
association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on _CurrentDfltMobilePhoneNumber.AddressID = $projection.AddressID
and _CurrentDfltMobilePhoneNumber.AddressPersonID is initial
association [0..*] to I_AddressFaxNumber_2 as _FaxNumber on _FaxNumber.AddressID = $projection.AddressID
and _FaxNumber.AddressPersonID is initial
association [0..1] to I_AddrCurDefaultFaxNumber as _CurrentDfltFaxNumber on _CurrentDfltFaxNumber.AddressID = $projection.AddressID
and _CurrentDfltFaxNumber.AddressPersonID is initial
association [0..*] to I_AddressURI as _UniformResourceIdentifier on _UniformResourceIdentifier.AddressID = $projection.AddressID
and _UniformResourceIdentifier.AddressPersonID is initial
association [0..1] to I_AddressMainWebsiteURL as _MainWebsiteURL on _MainWebsiteURL.AddressID = $projection.AddressID
and _MainWebsiteURL.AddressPersonID is initial
{
@ObjectModel.text.element: ['SupplierName']
@Consumption.labelElement: 'SupplierName'
key cast(lfa1.lifnr as lifnr preserving type) as Supplier,
// _SupplierToBusinessPartner._BusinessPartner.BusinessPartner as BusinessPartner,
@EndUserText.label: 'Account Group'
ktokk as SupplierAccountGroup,
@Semantics.text: true
cast(substring(rtrim(replace(concat(name1, concat(' &@', name2)), '&@', ''),' '),1,80) as md_supplier_name) as SupplierName,
cast(concat( concat( concat( concat( concat( concat_with_space( anred, name1, 1 ), name2 ), name3 ), name4 ), '/' ),
concat_with_space( pstlz, ort01 , 1 ) ) as md_supplier_full_name) as SupplierFullName,
// // For increase in field length
//@Semantics.text: true
@EndUserText.label: 'Business Partner - Supplier Name'
cast(substring(rtrim(replace(concat(_AddressDefaultRepresentation.AddresseeName1, concat(' &@', _AddressDefaultRepresentation.AddresseeName2)), '&@', ''),' '),1,81) as suppliername_2) as BPSupplierName,
@EndUserText.label: 'Business Partner - Supplier Full Name'
cast(concat( concat_with_space( concat_with_space( concat_with_space(_AddressDefaultRepresentation.AddresseeName1, _AddressDefaultRepresentation.AddresseeName2,1 ), _AddressDefaultRepresentation.AddresseeName3,1 ), _AddressDefaultRepresentation.AddresseeName4,1 ), ' ' ) as supplierfullname_2) as BPSupplierFullName,
// _AddressRepresentation.OrganizationName1 as BusinessPartnerName1,
// _AddressRepresentation.OrganizationName2 as BusinessPartnerName2,
// _AddressRepresentation.OrganizationName3 as BusinessPartnerName3,
// _AddressRepresentation.OrganizationName4 as BusinessPartnerName4,
//Adoption of Name and Address fields
@EndUserText.label: 'Business Partner Organization - Name 1'
_AddressDefaultRepresentation.AddresseeName1 as BusinessPartnerName1,
@EndUserText.label: 'Business Partner Organization - Name 2'
_AddressDefaultRepresentation.AddresseeName2 as BusinessPartnerName2,
@EndUserText.label: 'Business Partner Organization - Name 3'
_AddressDefaultRepresentation.AddresseeName3 as BusinessPartnerName3,
@EndUserText.label: 'Business Partner Organization - Name 4'
_AddressDefaultRepresentation.AddresseeName4 as BusinessPartnerName4,
@EndUserText.label: 'Business Partner Address – City'
_AddressDefaultRepresentation.CityName as BPAddrCityName,
@EndUserText.label: 'Business Partner Address – Street'
_AddressDefaultRepresentation.StreetName as BPAddrStreetName,
@EndUserText.label: 'Business Partner Address - Search Term 1'
_AddressDefaultRepresentation.AddressSearchTerm1 as AddressSearchTerm1,
@EndUserText.label: 'Business Partner Address - Search Term 2'
_AddressDefaultRepresentation.AddressSearchTerm2 as AddressSearchTerm2,
@EndUserText.label: 'Business Partner Address – District'
_AddressDefaultRepresentation.DistrictName as DistrictName,
@EndUserText.label: 'Business Partner Address - PO Box Deviating City'
_AddressDefaultRepresentation.POBoxDeviatingCityName as POBoxDeviatingCityName,
@EndUserText.label: 'Business Partner - Form of Address'
_AddressDefaultRepresentation.FormOfAddress as BusinessPartnerFormOfAddress,
lfa1.cvp_xblck as IsBusinessPurposeCompleted,
@EndUserText.label: 'Created By'
ernam as CreatedByUser,
erdat as CreationDate,
xcpdk as IsOneTimeAccount,
begru as AuthorizationGroup,
stceg as VATRegistration,
@EndUserText.label: 'Posting Block(Deprecated)'
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'PostingIsBlocked'
sperr as AccountIsBlockedForPosting,
txjcd as TaxJurisdiction,
scacd as SupplierStandardCarrierAccess,
sfrgr as SupplierFwdAgentFreightGroup,
dlgrp as SupplierAgentProcedureGroup,
regss as SupplIsSocialInsuranceRegtrd,
actss as SocialInsuranceActivityCode,
@EndUserText.label: 'Group Key'
konzs as SupplierCorporateGroup, //to be used
kunnr as Customer,
brsch as Industry, // siehe Anmerkung
stcd1 as TaxNumber1, // tax number 1&2: siehe Anmerkung
stcd2 as TaxNumber2,
stcd3 as TaxNumber3,
stcd4 as TaxNumber4,
stcd5 as TaxNumber5,
stcd6 as TaxNumber6,
sperr as PostingIsBlocked,
@EndUserText.label: 'Purch. Block'
sperm as PurchasingIsBlocked,
@EndUserText.quickInfo: 'International Location Number (Part 1)'
bbbnr as InternationalLocationNumber1,
@EndUserText.quickInfo: 'International Location Number (Part 2)'
bbsnr as InternationalLocationNumber2,
@EndUserText.label: 'Check Digit'
bubkz as InternationalLocationNumber3,
adrnr as AddressID,
lfa1.regio as Region,
lfa1.name1 as OrganizationBPName1,
lfa1.name2 as OrganizationBPName2,
lfa1.ort01 as CityName,
lfa1.pstlz as PostalCode,
lfa1.stras as StreetName,
lfa1.land1 as Country,
cast((concat(concat(bbbnr,concat(' & ', bbsnr)),concat(' & ',bubkz))) as md_international_loc ) as ConcatenatedInternationalLocNo,
//quality management
sperq as SupplierProcurementBlock,
qssys as SuplrQualityManagementSystem,
qssysdat as SuplrQltyInProcmtCertfnValidTo,
//globalization
lfa1.spras as SupplierLanguage,
lfa1.lnrza as AlternativePayeeAccountNumber,
lfa1.telf1 as PhoneNumber1,
lfa1.telfx as FaxNumber,
lfa1.stkzn as IsNaturalPerson,
lfa1.stenr as TaxNumberResponsible,
lfa1.categ as UK_ContractorBusinessType,
lfa1.partner_name as UK_PartnerTradingName,
lfa1.partner_utr as UK_PartnerTaxReference,
lfa1.status as UK_VerificationStatus,
lfa1.vfnum as UK_VerificationNumber,
lfa1.crn as UK_CompanyRegistrationNumber,
lfa1.vfnid as UK_VerifiedTaxStatus,
lfa1.anred as FormOfAddress,
lfa1.ktock as ReferenceAccountGroup,
lfa1.stkzu as VATLiability,
//GS
@EndUserText.label: 'Tax Type'
lfa1.fityp as ResponsibleType,
@EndUserText.label: 'Tax Number Type'
lfa1.stcdt as TaxNumberType,
@EndUserText.label: 'Fiscal Address'
lfa1.fiskn as FiscalAddress,
lfa1.j_1kftbus as BusinessType,
lfa1.gbdat as BirthDate,
lfa1.kraus as CreditorInformationNumber,
@EndUserText.label: 'Payment Block'
lfa1.sperz as PaymentIsBlockedForSupplier,
@EndUserText.label: 'Search Term'
lfa1.sortl as SortField,
lfa1.telf2 as PhoneNumber2,
lfa1.loevm as DeletionIndicator,
//GS FIN
j_1kfrepre as TaxInvoiceRepresentativeName,
j_1kftind as IndustryType,
lfa1.ven_class as IN_GSTSupplierClassification,
lfa1.podkzb as SuplrProofOfDelivRlvtCode,
lfa1.vbund as TradingPartner,
@EndUserText.label: 'Tax Split'
lfa1.ipisp as BR_TaxIsSplit,
lfa1.au_carrying_ent as AU_PayerIsPayingToCarryOnEnt,
lfa1.au_ind_under_18 as AU_IndividualIsUnder18,
@EndUserText.label: 'Payment Does not Exc'
lfa1.au_payment_not_exceed_75 as AU_PaymentIsExceeding75,
lfa1.au_wholly_inp_taxed as AU_PaymentIsWhollyInputTaxed,
@EndUserText.label: 'Individual w/o Gain'
lfa1.au_partner_without_gain as AU_PartnerIsSupplyWithoutGain,
lfa1.au_not_entitled_abn as AU_SupplierIsEntitledToABN,
lfa1.au_payment_exempt as AU_PaymentIsIncomeExempted,
lfa1.au_private_hobby as AU_SupplyIsMadeAsPrivateHobby,
lfa1.au_domestic_nature as AU_SupplyMadeIsOfDmstcNature,
lfa1.weora as IsToBeAcceptedAtOrigin,
// newly added fields
cast (stkza as xfeld preserving type) as BPIsEqualizationTaxSubject,
lfa1.taxbs as BRSpcfcTaxBasePercentageCode,
lfa1.profs as SupplierProfession,
lfa1.emnfr as SuplrManufacturerExternalName,
lfa1.dtams as DataMediumExchangeIndicator,
lfa1.dtaws as DataExchangeInstructionKey,
@EndUserText.label: 'VSR Relevant'
lfa1.ltsna as SupplierIsSubRangeRelevant,
@EndUserText.label: 'Train Station'
lfa1.bahns as TrainStationName,
lfa1.xzemp as AlternativePayeeIsAllowed,
lfa1.esrnr as PaytSlipWthRefSubscriber,
@EndUserText.label: 'Stat. Grp, Agent'
lfa1.stgdl as TranspServiceAgentStstcGrp,
@EndUserText.label: 'Plant Level Relevant'
lfa1.werkr as SupplierIsPlantRelevant,
lfa1.fisku as SuplrTaxAuthorityAccountNumber,
@Semantics.booleanIndicator: true
carrier_conf as SuplrCarrierConfirmIsExpected,
lfa1.werks as SupplierPlant,
lfa1.plkal as FactoryCalendar,
lfa1.paytrsn as PaymentReason,
@EndUserText.label: 'Central Del. Block'
lfa1.nodel as SupplierCentralDeletionIsBlock,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.xdcset as DataControllerSet,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr1 as DataController1,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr2 as DataController2,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr3 as DataController3,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr4 as DataController4,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr5 as DataController5,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr6 as DataController6,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr7 as DataController7,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr8 as DataController8,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr9 as DataController9,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr10 as DataController10,
lfa1.transport_chain as SupplierTransportationChain,
lfa1.staging_time as SupplierStagingTimeInDays,
lfa1.scheduling_type as SupplierSchedulingProcedure,
lfa1.submi_relevant as CollectiveNumberingIsRelevant,
lfa1.j_1ipanno as BusinessPartnerPanNumber,
lfa1.j_1ipanref as BPPanReferenceNumber,
lfa1.j_1ipanvaldt as BPPanValidFromDate,
//
_SupplierCompany,
_SupplierPurchasingOrg,
_SupplierBankDetails,
_SupplierAccountGroup,
_SupplierAccountGroupText, // OBSOLETE to be deleted
_SupplierIndustryText, // OBSOLETE to be deleted
_Industry,
_StandardAddress,
// _Address removed, use _StandardAddress instead
_CorrespondingCustomer,
_SupplierToBusinessPartner,
//quality management
_ProcurementBlock,
_QualityManagementSystem,
_AddressDefaultRepresentation,
_AddressRepresentation,
// _BusinessPartnerAddress
// _SupplierUnprotectedAddr
_EmailAddress,
_CurrentDfltEmailAddress,
_PhoneNumber,
_CurrentDfltLandlinePhoneNmbr,
_CurrentDfltMobilePhoneNumber,
_FaxNumber,
_CurrentDfltFaxNumber,
_UniformResourceIdentifier,
_MainWebsiteURL
}
//TESTING
Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA