I_NotificationPartner

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: ['_User']
@EndUserText.label: 'Notification Partner'
@VDM.viewType: #BASIC

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L, 
        serviceQuality: #C }
} 

define view entity I_NotificationPartner as select from ihpa 
//=== associations to other partner related views 

  association [0..1] to I_PartnerFunction  as _PartnerFunction  on  _PartnerFunction.PartnerFunction = $projection.PartnerFunction

//=== associations to DPP relevant views

  association [0..1] to I_ContactPerson    as _ContactPerson    on  _ContactPerson.ContactPerson = $projection.Partner
  association [0..1] to I_Customer         as _Customer         on  _Customer.Customer = $projection.Partner
  association [0..1] to I_WorkforcePerson  as _Employee         on  _Employee.PersonExternalID = $projection.Partner
  association [0..1] to I_Supplier         as _Supplier         on  _Supplier.Supplier = $projection.Partner
  association [0..1] to I_User             as _User             on  _User.UserID = $projection.Partner
  
{
//=== key fields

  key objnr     as NotificationPartnerObject,
  @ObjectModel.foreignKey.association: '_PartnerFunction'
  key parvw     as PartnerFunction,
  key counter   as NotificationPartnerObjectNmbr,
  
//=== common fields

      obtyp     as  NotificationObjectType,

      // Better use NotificationPartner

      // GFN Partner has assigned BU_PARTNER (CHAR 10) as default data element and is not owned by us 

      parnr     as  Partner,
      // GFN NotificationPartner has assigned I_PARNR (CHAR 12) as default data element like in table IHPA 

      parnr     as  NotificationPartner,

      ernam     as  CreatedByUser,
      erdat     as  CreationDate,
      erzeit    as  CreationTime,
      aenam     as  LastChangedByUser,
      aezeit    as  LastChangeTime,
      aedat     as  LastChangeDate,
      kzloesch  as  IsDeleted,

//=== expose relevant associations

  _PartnerFunction,
  _ContactPerson,
  _Customer,
  _Employee,
  _Supplier,
  _User
}
where obtyp = 'NO1'
   or obtyp = 'QM1'
   or obtyp = 'QMI'