I_AllocationTableItem

@AbapCatalog.sqlViewName: 'IALLOCTBLITEM'
@EndUserText.label: 'Allocation Table Item'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@ObjectModel: {
    semanticKey: ['AllocationTable', 'AllocationTableItem'],
    representativeKey: 'AllocationTableItem',
    usageType.serviceQuality: #A,
    usageType.sizeCategory: #L,
    usageType.dataClass: #TRANSACTIONAL
}

define view I_AllocationTableItem
  as select from aupo
  association [1..1] to I_AllocationTable              as _AllocationTable              on  $projection.AllocationTable = _AllocationTable.AllocationTable
  association [0..*] to I_AllocationTableItemRcpntGrp  as _AllocationTableItemRcpntGrp  on  $projection.AllocationTable     = _AllocationTableItemRcpntGrp.AllocationTable
                                                                                        and $projection.AllocationTableItem = _AllocationTableItemRcpntGrp.AllocationTableItem
  association [0..*] to I_AllocationTableItemRecipient as _AllocationTableItemRecipient on  $projection.AllocationTable     = _AllocationTableItemRecipient.AllocationTable
                                                                                        and $projection.AllocationTableItem = _AllocationTableItemRecipient.AllocationTableItem
  association [0..*] to I_AllocTableItemSuplgDistrCtr  as _AllocTableItemSuplgDistrCtr  on  $projection.AllocationTable     = _AllocTableItemSuplgDistrCtr.AllocationTable
                                                                                        and $projection.AllocationTableItem = _AllocTableItemSuplgDistrCtr.AllocationTableItem
  association [0..1] to I_UnitOfMeasure                as _QuantityUnit                 on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure
  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_Product                      as _Product                      on  $projection.Product = _Product.Product
  association [0..1] to I_MaterialGroup                as _MaterialGroup                on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_RetailPromotion              as _RetailPromotion              on  $projection.RetailPromotion = _RetailPromotion.RetailPromotion
  association [0..1] to I_AllocTableBlockingReason     as _AllocTableBlockingReason     on  $projection.AllocTblItmBlockReason = _AllocTableBlockingReason.AllocTblBlockReason  
  // Administrative data

  association [0..1] to I_User                         as _CreatedByUser                on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      @ObjectModel.foreignKey.association: '_AllocationTable'
  key abeln                                            as AllocationTable,
  key abelp                                            as AllocationTableItem,

      rfktn                                            as PurchaseContract,
      rfktp                                            as PurchaseContractItem,
      cast(ebeln as vdm_purchaseorder preserving type) as PurchaseOrder,
      cast ( case ebelp
               when '00000' then '' else ebelp
             end as ebelp )                            as PurchaseOrderItem,
      @ObjectModel.foreignKey.association: '_RetailPromotion'
      aktnr                                            as RetailPromotion,
      @ObjectModel.foreignKey.association: '_Product'
      cast(matnr as productnumber preserving type)     as Product,
      vzwrk                                            as DistributionCenter,
      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr                                            as Supplier,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      pmnge                                            as PlannedQuantity,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      imnge                                            as ConfirmedQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_QuantityUnit'
      aufme                                            as QuantityUnit,
      astra                                            as AllocationStrategy,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      matkl                                            as MaterialGroup,
      vbeln                                            as InboundDelivery,
      vbelp                                            as InboundDeliveryItem,
      ervon                                            as AllocTableCreatingApplication,
      sapos                                            as AllocTblItemOfConfigblProduct,
      attyp                                            as ArticleCategory,
      @ObjectModel.foreignKey.association: '_AllocTableBlockingReason'
      sperr                                            as AllocTblItmBlockReason,

      // Administrative Data

      @Semantics.systemDate.createdAt: true
      erdat                                            as CreationDate,
      ernam                                            as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                            as LastChangeDate,
      aenam                                            as LastChangedByUser,
      _CreatedByUser,
      _LastChangedByUser,

      _QuantityUnit,
      _Supplier,
      _Product,
      _MaterialGroup,
      _RetailPromotion,
      _AllocTableBlockingReason,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _AllocationTable,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AllocTableItemSuplgDistrCtr,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AllocationTableItemRcpntGrp
}