I_RetailPromotion

@Analytics.technicalName: 'IRTLPROMN'
@EndUserText: {label: 'Retail Promotion'}

@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #NOT_REQUIRED
}

@VDM: {viewType: #BASIC}
@ObjectModel: {
    compositionRoot: true,
    semanticKey: ['RetailPromotion'],
    representativeKey: 'RetailPromotion',
    usageType: {
        serviceQuality: #A,
        sizeCategory: #M,
        dataClass: #TRANSACTIONAL
   }
}

define view entity I_RetailPromotion
  as select from wakh

  association [0..*] to I_RetailPromotionT            as _Text                        on  $projection.RetailPromotion = _Text.RetailPromotion
  association [1..1] to I_SalesOrganization           as _SalesOrganization           on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [1..1] to I_DistributionChannel         as _DistributionChannel         on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_PurchasingOrganization      as _PurchasingOrganization      on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup             as _PurchasingGroup             on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [1..1] to I_RtlPromotionAnnouncementSts as _RtlPromotionAnnouncementSts on  $projection.PromotionAnnouncementStatus = _RtlPromotionAnnouncementSts.PromotionAnnouncementStatus
  association [1..1] to I_RtlPromnSalesPriceActvtnSts as _RtlPromnSalesPriceActvtnSts on  $projection.SalesPriceActivationStatus = _RtlPromnSalesPriceActvtnSts.SalesPriceActivationStatus
  association [1..1] to I_RetailPromotionType         as _RetailPromotionType         on  $projection.RetailPromotionType = _RetailPromotionType.RetailPromotionType
  association [1..1] to I_RtlPromnCrtedByAppl         as _RtlPromnCrtedByAppl         on  $projection.RetailPromotionCrtedByAppl = _RtlPromnCrtedByAppl.RetailPromotionCrtedByAppl
  association [1..1] to I_RtlPromnBlockingReason      as _RtlPromnBlockingReason      on  $projection.RetailPromnBlockingReason = _RtlPromnBlockingReason.RetailPromnBlockingReason
  association [1..1] to I_RtlPromnProcessingStatus    as _RtlPromnProcessingStatus    on  $projection.PromotionProcessingStatus = _RtlPromnProcessingStatus.PromotionProcessingStatus
  association [1..1] to I_RtlPromnLstgStatus          as _RtlPromnLstgStatus          on  $projection.RtlPromnListingStatus = _RtlPromnLstgStatus.RtlPromnListingStatus
  association [1..1] to I_RtlPromnAllocTblStatus      as _RtlPromnAllocTblStatus      on  $projection.RtlPromnAllocTableStatus = _RtlPromnAllocTblStatus.RtlPromnAllocTableStatus
  association [0..1] to I_RetailPromotionDiscount     as _RtlPromnHeaderDiscount      on  $projection.RetailPromotion                      = _RtlPromnHeaderDiscount.RetailPromotion
                                                                                      and _RtlPromnHeaderDiscount.RetailPromnDiscountLevel = '05' // maximum one entry with Level = 05


  association [0..*] to I_RetailPromotionItem         as _RetailPromotionItem         on  $projection.RetailPromotion = _RetailPromotionItem.RetailPromotion
  association [0..*] to I_RetailPromotionDiscount     as _RetailPromotionDiscount     on  $projection.RetailPromotion = _RetailPromotionDiscount.RetailPromotion

  association [0..1] to I_RetailPromotionCategory     as _RetailPromotionCategory     on  $projection.RetailPromotionCategory = _RetailPromotionCategory.RetailPromotionCategory
  association [0..1] to I_RetailPromotionCustomerType as _RetailPromotionCustomerType on  $projection.RetailPromotionCustomerType = _RetailPromotionCustomerType.RetailPromotionCustomerType
  association [0..1] to I_Currency                    as _PromnPlnHdrCurrency         on  $projection.PromnPlnHdrCurrency = _PromnPlnHdrCurrency.Currency

  // Administrative data

  association [0..1] to I_User                        as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser           on  $projection.LastChangedByUser = _LastChangedByUser.UserID
{
      @ObjectModel: {text: {association: '_Text'}}
  key aktnr                                                                                                        as RetailPromotion,

      vkdab                                                                                                        as RetailPromotionSalesFromDate,
      vkdbi                                                                                                        as RetailPromotionSalesToDate,
      ekdab                                                                                                        as PurPriceCndnStartDate,
      ekdbi                                                                                                        as PurPriceCndnEndDate,
      @ObjectModel.foreignKey.association: '_RetailPromotionType'
      akart                                                                                                        as RetailPromotionType,
      _RetailPromotionType,
      is_ref_promo                                                                                                 as RetailPromotionIsRefPromotion,
      @ObjectModel.foreignKey.association: '_RtlPromnCrtedByAppl'
      erappl                                                                                                       as RetailPromotionCrtedByAppl,
      _RtlPromnCrtedByAppl,
      spdab                                                                                                        as RetailPromnHeaderBlockDate,
      @ObjectModel.foreignKey.association: '_RtlPromnBlockingReason'
      spgru                                                                                                        as RetailPromnBlockingReason,
      _RtlPromnBlockingReason,

      ref_promo                                                                                                    as RetailPromotionRefPromotion,


      @ObjectModel.foreignKey.association: '_SalesOrganization'
      vkorg                                                                                                        as SalesOrganization,
      _SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      vtweg                                                                                                        as DistributionChannel,
      _DistributionChannel,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      ekorg                                                                                                        as PurchasingOrganization,
      _PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      ekgrp                                                                                                        as PurchasingGroup,
      _PurchasingGroup,

      @ObjectModel.foreignKey.association: '_RetailPromotionCategory'
      aktyp                                                                                                        as RetailPromotionCategory,
      _RetailPromotionCategory,
      @ObjectModel.foreignKey.association: '_RetailPromotionCustomerType'
      customer_type                                                                                                as RetailPromotionCustomerType,
      _RetailPromotionCustomerType,

      @ObjectModel.foreignKey.association:  '_RtlPromnSalesPriceActvtnSts'
      cast(vkgst as salespriceactivationstatus preserving type )                                                   as SalesPriceActivationStatus,
      _RtlPromnSalesPriceActvtnSts,
      @ObjectModel.foreignKey.association: '_RtlPromotionAnnouncementSts'
      cast(bekst as promotionannouncementstatus preserving type )                                                  as PromotionAnnouncementStatus,
      _RtlPromotionAnnouncementSts,
      @ObjectModel: {foreignKey: {association: '_RtlPromnLstgStatus'}}
      akbst                                                                                                        as RtlPromnListingStatus,
      _RtlPromnLstgStatus,
      @ObjectModel: {foreignKey: {association: '_RtlPromnAllocTblStatus'}}
      akast                                                                                                        as RtlPromnAllocTableStatus,
      _RtlPromnAllocTblStatus,

      @ObjectModel: {foreignKey: {association: '_RtlPromnProcessingStatus'}}
      akvst                                                                                                        as PromotionProcessingStatus,
      _RtlPromnProcessingStatus,


      waela                                                                                                        as PromnPlnHdrCurrency,
      _PromnPlnHdrCurrency,
      @Semantics.amount.currencyCode: 'PromnPlnHdrCurrency'
      pduep                                                                                                        as PromnPlnTotalItemsPurchasePrc,
      @Semantics.amount.currencyCode: 'PromnPlnHdrCurrency'
      pduvp                                                                                                        as PromnPlnTotalItemsSalesPrice,
      pdanz
                                                                                                                   as PromnPlnNumberOfArticles,
      // Administrative Data

      @Semantics.systemDate.createdAt: true
      erdat                                                                                                        as CreationDate,
      ernam                                                                                                        as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                                                                                        as LastChangeDate,
      aenam                                                                                                        as LastChangedByUser,


      // Associations

      _RtlPromnHeaderDiscount,
      _CreatedByUser,
      _LastChangedByUser,


      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text,
      _RetailPromotionItem,
      _RetailPromotionDiscount
}