I_AllocationTable

@AbapCatalog.sqlViewName: 'IALLOCATIONTABLE'
@EndUserText.label: 'Allocation Table'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@ObjectModel: {
    compositionRoot: true,
    semanticKey: ['AllocationTable'],
    representativeKey: 'AllocationTable',
    usageType.serviceQuality: #A,
    usageType.sizeCategory: #L,
    usageType.dataClass: #TRANSACTIONAL
}

define view I_AllocationTable
  as select from auko

  association [1..1] to I_AllocationTableType          as _AllocationTableType         on  $projection.AllocationTableType = _AllocationTableType.AllocationTableType
  association [1..1] to I_PurchasingOrganization       as _PurchasingOrganization      on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [1..1] to I_PurchasingGroup              as _PurchasingGroup             on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [1..1] to I_AllocTableActivityStatus     as _AllocTableActivityStatus    on  $projection.AllocTableActivityStatus = _AllocTableActivityStatus.AllocTableActivityStatus
  association [1..1] to I_AllocTableMaintenanceStatus  as _AllocTableMaintenanceStatus on  $projection.MaintenanceStatus = _AllocTableMaintenanceStatus.MaintenanceStatus
  association [1..1] to I_AllocTableCreatingAppl       as _CreatingApplication         on  $projection.AllocTableCreatingApplication = _CreatingApplication.AllocTableCreatingApplication

  association [0..*] to I_AllocationTableItem          as _AllocationTableItem         on  $projection.AllocationTable = _AllocationTableItem.AllocationTable
  association [0..1] to I_AllocationTableDeliveryPhase as _DefaultDeliveryPhase        on  $projection.AllocationTable                        = _DefaultDeliveryPhase.AllocationTable
                                                                                       and _DefaultDeliveryPhase.AllocationTableItem          = '00000'
                                                                                       and _DefaultDeliveryPhase.AllocationTableItemRcpntGrp  = '00000'
                                                                                       and _DefaultDeliveryPhase.AllocationTableItemRecipient = '00000'
                                                                                       and _DefaultDeliveryPhase.AllocationTableDeliveryPhase = '001'
  association [0..1] to I_AllocTableDistrCtrDelivPhase as _DefaultDistrCtrDelivPhase   on  $projection.AllocationTable                             = _DefaultDistrCtrDelivPhase.AllocationTable
                                                                                       and _DefaultDistrCtrDelivPhase.AllocationTableItem          = '00000'
                                                                                       and _DefaultDistrCtrDelivPhase.AllocationTableDeliveryPhase = '001'
                                                                                       and _DefaultDistrCtrDelivPhase.DistributionCenter           = ''
  // Administrative data

  association [0..1] to I_User                         as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser           on  $projection.LastChangedByUser = _LastChangedByUser.UserID
{
      @ObjectModel.text.element: 'AllocationTableDescription'
  key abeln                                                          as AllocationTable,
      @Semantics.text:true
      cast( bezch as allocationtabledescription preserving type )    as AllocationTableDescription,

      @ObjectModel.foreignKey.association: '_AllocationTableType'
      cast( aufar as allocationtabletype preserving type )           as AllocationTableType,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      ekorg                                                          as PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      ekgrp                                                          as PurchasingGroup,

      @ObjectModel.foreignKey.association: '_AllocTableActivityStatus'
      cast( astak as alloctableactivitystatus preserving type )      as AllocTableActivityStatus,
      @ObjectModel.foreignKey.association: '_AllocTableMaintenanceStatus'
      pstak                                                          as MaintenanceStatus,
      @ObjectModel.foreignKey.association: '_CreatingApplication'
      cast( ervon as alloctablecreatingapplication preserving type ) as AllocTableCreatingApplication,

      // Administrative Data

      @Semantics.systemDate.createdAt: true
      erdat                                                          as CreationDate,
      ernam                                                          as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                                          as LastChangeDate,
      aenam                                                          as LastChangedByUser,
      _CreatedByUser,
      _LastChangedByUser,

      _AllocationTableType,
      _CreatingApplication,
      _PurchasingOrganization,
      _PurchasingGroup,
      _AllocTableActivityStatus,
      _AllocTableMaintenanceStatus,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AllocationTableItem,
      _DefaultDeliveryPhase,
      _DefaultDistrCtrDelivPhase
}