C_CAInvcgDocHeader

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED,
  privilegedAssociations: [ '_CAInvcgUserContact' ]
}
@EndUserText.label: 'Fakturierungsbeleg Kopf'
@Metadata.allowExtensions: true
@ObjectModel:{
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED
  },
  semanticKey: [ 'CAInvoicingDocument' ],
  representativeKey: 'CAInvoicingDocument'
}
@OData.entitySet.name: 'C_CAInvcgDocDisp'
@OData.entityType.name: 'C_CAInvcgDocDispType'

@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}

define root view entity C_CAInvcgDocHeader
  provider contract transactional_query
  as projection on R_CAInvcgDocumentTP as _CAInvcgDocHeader

  // UI FACETS

  association [1..*] to C_CAInvcgDocItem            as _CAInvcgDocItem            on  $projection.CAInvoicingDocument = _CAInvcgDocItem.CAInvoicingDocument
  association [1..*] to C_CAInvcgDocSource          as _CAInvcgDocSource          on  $projection.CAInvoicingDocument = _CAInvcgDocSource.CAInvoicingDocument
  association [1..*] to C_CAInvcgDocPosting         as _CAInvcgDocPosting         on  $projection.CAInvoicingDocument = _CAInvcgDocPosting.CAInvoicingDocument
  association [1..*] to C_CAInvcgDocRelation        as _CAInvcgDocRelation        on  $projection.CAInvoicingDocument = _CAInvcgDocRelation.CAInvoicingDocument
  association [1..*] to C_CAInvcgDocContractAccount as _CAInvcgDocContractAccount on  $projection.ContractAccount = _CAInvcgDocContractAccount.ContractAccount
  association [0..*] to C_CAInvcgDocPrintReceiver   as _CAInvcgDocPrintReceiver   on  $projection.CAInvoicingDocument           = _CAInvcgDocPrintReceiver.CAInvoicingDocument
                                                                                  and $projection.CAInvcgProcess                = _CAInvcgDocPrintReceiver.CAInvcgProcess
                                                                                  and $projection.CAInvcgDocumentPrintDate      is not initial
                                                                                  and $projection.CAInvcgDocIsLockedForPrinting is initial
                                                                                  and $projection.CAInvcgIsDocumentSimulated    is initial

  // required for in-app-navigation

  association [0..1] to C_CAInvcgDocHeader          as _CAInvcgReversedDocument   on  $projection.CAInvcgReversedDocument = _CAInvcgReversedDocument.CAInvoicingDocument
  association [0..1] to C_CAInvcgDocHeader          as _CAInvcgReversalDocument   on  $projection.CAInvcgReversalDocument = _CAInvcgReversalDocument.CAInvoicingDocument
  association [0..1] to C_CAInvcgDocHeader          as _CAInvcgAdjustedDocument   on  $projection.CAInvcgAdjustedDocument = _CAInvcgAdjustedDocument.CAInvoicingDocument
  association [0..1] to C_CAInvcgDocHeader          as _CAInvcgAdjustmentDocument on  $projection.CAInvcgAdjustmentDocument = _CAInvcgAdjustmentDocument.CAInvoicingDocument

{
          //INVDOCNO

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  key     _CAInvcgDocHeader.CAInvoicingDocument,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual UICT_CAInvoicingDocument      : abap.char(50),

          //EXBEL

          _CAInvcgDocHeader.CAOfficialDocumentNumber,

          //GPART

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.BusinessPartnerFullName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.StreetName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.AddressCityName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.CountryName,

          @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.9 }
          @ObjectModel.text.element: ['BusinessPartnerFullName']
          _CAInvcgDocHeader.BusinessPartner,

          //VKONT

          @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.9 }
          @ObjectModel.text.element: ['ContractAccountName']
          _CAInvcgDocHeader.ContractAccount,

          _CAInvcgDocHeader._ContractAccountHeader.ContractAccountName,

          //INV_TYPE

          @ObjectModel.text.element: ['CAInvcgTypeText']
          _CAInvcgDocHeader.CAInvcgType,
          _CAInvcgType._CAInvcgTypeText.CAInvcgTypeText                                        : localized,

          //INVPERIOD

          _CAInvcgDocHeader.CAInvcgDocPeriodDate,

          //BLDAT

          _CAInvcgDocHeader.DocumentDate,

          //Amount and Currency

          _CAInvcgDocHeader.TransactionCurrency,

          _CAInvcgDocHeader.CAAmountInTransactionCurrency,

          //INV_PROCESS

          @ObjectModel.text.element: ['CAInvcgProcessText']
          _CAInvcgDocHeader.CAInvcgProcess,
          _CAInvcgProcess._CAInvcgProcessText.CAInvcgProcessText                               : localized,

          //DOCTYPE

          @ObjectModel.text.element: ['CAInvcgDocumentTypeText']
          _CAInvcgDocHeader.CAInvcgDocumentType,
          _CAInvcgDocumentType._CAInvcgDocumentTypeText.CAInvcgDocumentTypeText                : localized,

          //MAZAE

          _CAInvcgDocHeader.CADunningCounter,

          //CFCSIMULATED

          _CAInvcgDocHeader.CAInvcgDocHasControlDoc,

          //FORM_ID

          _CAInvcgDocHeader.CAInvcgDocFormID,

          //FORMKEY

          _CAInvcgDocHeader.ApplicationForm,

          //PRINTDATE

          _CAInvcgDocHeader.CAInvcgDocumentPrintDate,

          //PRINTLOCK

          @ObjectModel.text.element: ['CAInvcgDocLockedForPrintText']
          _CAInvcgDocHeader.CAInvcgDocIsLockedForPrinting,
          _CAInvcgDocLockedforPrint._CAInvcgDocLockedForPrintText.CAInvcgDocLockedForPrintText : localized,

          //FAEDN - Due date for net payment

          _CAInvcgDocHeader.CANetDueDate,

          //REVREASON - Reversal Reason

          @ObjectModel.text.element: ['CAInvcgDocReversalReasonText']
          _CAInvcgDocHeader.CAInvcgDocumentReversalReason,
          _CAInvcgDocReversalReason._CAInvcgDocReversalReasonText.CAInvcgDocReversalReasonText : localized,

          //INVOICED

          _CAInvcgDocHeader.CAInvcgIsDocumentPosted,

          //PRELIMINARY

          _CAInvcgDocHeader.CAInvcgIsDocumentPreliminary,

          //SIMULATED

          _CAInvcgDocHeader.CAInvcgIsDocumentSimulated,

          //BUDAT

          _CAInvcgDocHeader.CAPostingDate,

          //APPLK

          _CAInvcgDocHeader.CAApplicationArea,

          //TECHDOCTYPE

          @ObjectModel.text.element: ['CAInvcgDocTechDocTypeText']
          _CAInvcgDocHeader.CAInvcgTechnicalDocumentType,
          _CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText.CAInvcgDocTechDocTypeText          : localized,

          //TARGPROCESS

          @ObjectModel.text.element: ['CAInvcgTargetProcText']
          _CAInvcgDocHeader.CAInvcgTargetProcess,
          _CAInvcgTargetProc._CAInvcgTargetProcText.CAInvcgTargetProcText                      : localized,

          //MDCAT

          @ObjectModel.text.element: ['CAInvcgMasterDataTypeText']
          _CAInvcgDocHeader.CAInvcgMasterDataType,
          _CAInvcgMasterDataType._CAInvcgMasterDataTypeText.CAInvcgMasterDataTypeText          : localized,

          //ABWVK

          _CAInvcgDocHeader.AltvContractAcctForCollvBills,

          //ABWBL

          _CAInvcgDocHeader.CASubstituteDocumentNumber,

          //CRNAME

          _CAInvcgDocHeader.CreatedByUser,

          //CRDATE

          _CAInvcgDocHeader.CAInvcgCreationDate,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
          @ObjectModel.sort.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
  virtual CAInvcgCreationDateTime       : invdoc_crtsmp_kk,

          //CRTIME

          _CAInvcgDocHeader.CAInvcgCreationTime,

          //CRMODE

          @ObjectModel.text.element: ['CAInvcgDocCreationModeText']
          _CAInvcgDocHeader.CAInvcgDocCreationMode,
          _CAInvcgDocCreationMode._CAInvcgDocCreationModeText.CAInvcgDocCreationModeText       : localized,

          //RECNUM

          _CAInvcgDocHeader.CAInvcgNmbrOfInvoicingDocItems,

          //BIT_NUMBER

          _CAInvcgDocHeader.CABllbleItmNumber,

          //INVRUNNO

          _CAInvcgDocHeader.CAInvcgDocInternalNumber,

          //FIKEY

          _CAInvcgDocHeader.CAReconciliationKey,

          //FAEDS

          _CAInvcgDocHeader.CACashDiscountDueDate,

          //SKTPZ

          _CAInvcgDocHeader.CACashDiscountRate,

          //PRLINV_CAT

          @ObjectModel.text.element: ['CAInvcgPreliminaryCategoryTxt']
          _CAInvcgDocHeader.CAInvcgPreliminaryCategory,
          _CAInvcgPreliminaryCategory._Text.CAInvcgPreliminaryCategoryTxt                      : localized,

          //PRLINV_CNT

          _CAInvcgDocHeader.CAPrelimInvcgDocValue,

          //PRLINV_STATUS

          @ObjectModel.text.element: ['CAPreliminaryInvcgDocStatusTxt']
          _CAInvcgDocHeader.CAPreliminaryInvcgDocStatus,
          _CAPreliminaryInvcgDocStatus._Text.CAPreliminaryInvcgDocStatusTxt                    : localized,

          //INV_CATEGORY

          @ObjectModel.text.element: ['CAInvcgCategoryText']
          _CAInvcgDocHeader.CAInvcgCategory,
          _CAInvcgCategory._CAInvcgCategoryText.CAInvcgCategoryText                            : localized,

          //REVERSALDOC

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
          _CAInvcgDocHeader.CAInvcgReversalDocument,

          //REVERSEDDOC

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
          _CAInvcgDocHeader.CAInvcgReversedDocument,

          //CORRCAT

          @ObjectModel.text.element: ['CAInvcgCorrectionCatText']
          _CAInvcgDocHeader.CAInvcgCorrectionCategory,
          _CAInvcgCorrectionCat._CAInvcgCorrectionCatText.CAInvcgCorrectionCatText             : localized,

          //PYMET

          @ObjectModel.text.element: ['CAPaymentMethodName']
          _CAInvcgDocHeader.CAPaymentMethod,
          _CAPaymentMethod._Text.CAPaymentMethodName                                           : localized,
          @Consumption.hidden: true
          _CAInvcgDocHeader.CAPaymentCompanyCodeCountry,

          //NRZAS

          _CAInvcgDocHeader.CAPaymentFormNumber,

          //ZLSCH

          _CAInvcgDocHeader.FormIDForAttachedPaymentMedium,

          //EXKID

          _CAInvcgDocHeader.CAKeyIdentification,

          //PTSRL

          _CAInvcgDocHeader.CAPartnerSettlementRule,

          //BUKRS

          @ObjectModel.text.element: ['CompanyCodeName']
          _CAInvcgDocHeader.CompanyCode,
          _CAInvcgDocHeader._CompanyCode.CompanyCodeName,

          //BUPLA

          _CAInvcgDocHeader.BusinessPlace,

          //VTREF

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
          _CAInvcgDocHeader.CAContract,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_VTREF_SEMOBJ'
  virtual CAContractSemanticObject      : vtref_semobj_kk,

          //SUBAP

          @ObjectModel.text.element: ['CASubApplicationText']
          _CAInvcgDocHeader.CASubApplication,
          _CASubApplication._CASubApplicationText.CASubApplicationText : localized,

          //INVOICE_BASEDATE

          _CAInvcgDocHeader.CAInvcgBaseDate,

          //INVPERCAT

          @ObjectModel.text.element: ['CAInvcgPeriodCatText']
          _CAInvcgDocHeader.CAInvcgDocPeriodCategory,
          _CAInvcgPeriodCat._CAInvcgPeriodCatText.CAInvcgPeriodCatText                         : localized,

          //INVPERIOD

          _CAInvcgDocHeader.CAInvcgDocPeriodStartDate,

          //CHGDOC_EX

          @ObjectModel.text.element: ['CAInvcgDocChrgDiscItemsText']
          _CAInvcgDocHeader.CAInvcgDocHasChargeOrDiscItems,
          _CAInvcgDocChrgDiscItems._CAInvcgDocChrgDiscItemsText.CAInvcgDocChrgDiscItemsText    : localized,

          //BOLLOTAX

          @ObjectModel.text.element: ['CAInvcgBolloTaxPostStatText']
          _CAInvcgDocHeader.CAInvcgBolloTaxPostStatus,
          _CAInvcgBolloTaxPostStatus._CAInvcgBolloTaxPostStatText.CAInvcgBolloTaxPostStatText  : localized,

          //XSUBINV

          @ObjectModel.text.element: ['CAInvcgDocPartOfListText']
          _CAInvcgDocHeader.CAInvcgDocIsPartOfList,
          _CAInvcgDocPartOfList._CAInvcgDocPartOfListText.CAInvcgDocPartOfListText             : localized,

          //XINVDOC_X

          _CAInvcgDocHeader.CAInvcgDocHasObjectRelation,

          //SEPA_PRENOT

          _CAInvcgDocHeader.CAInvcgDocHasSEPAPreNotif,

          //EXT_INVDOCNO

          _CAInvcgDocHeader.CAInvcgDocExternal,

          //ADJUSTMENTDOC

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
          _CAInvcgDocHeader.CAInvcgAdjustmentDocument,

          //ADJUSTEDDOC

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
          _CAInvcgDocHeader.CAInvcgAdjustedDocument,


          // Action control: Print

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocumentPrintIsEnabled : xfeld,

          // Action control: Print (Output Control to be used)

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocPrntOutpCtrlIsEnbld : xfeld,

          // Action control: Print Preview

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocPrintPreviewIsEnbld : xfeld,

          // Action control: Reversal

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocReversalIsEnabled   : xfeld,

          // Action control: Create Credit/Debit Memo

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocBillgReqIsEnabled   : xfeld,

          // Action control: Release Preliminary Invoice

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CAInvcgDocReleaseIsEnabled    : xfeld,

          // Dispute Case Management

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
  virtual CADisputeCaseIsExisting       : xfeld,


          // Make association public

          _CAInvcgDocItem,
          _CAInvcgDocSource,
          _CAInvcgDocPosting,
          _CAInvcgDocRelation,
          _CAInvcgDocContractAccount,
          _BusinessPartner,
          _ContractAccountPartner,
          _ContractAccountHeader,
          _AltvContractAcctForCollvBills,
          _CAInvcgDocumentType,
          _TransactionCurrency,
          _CAInvcgPreliminaryCategory,
          _CAPreliminaryInvcgDocStatus,
          _CAInvcgReversedDocument,
          _CAInvcgReversalDocument,
          _CAInvcgAdjustedDocument,
          _CAInvcgAdjustmentDocument,
          _CAInvcgProcess,
          _CAInvcgType,
          _CAInvcgCategory,
          _CAInvcgDocTechDocType,
          _CAInvcgTargetProc,
          _CAInvcgMasterDataType,
          _CAInvcgDocCreationMode,
          _CAInvcgDocReversalReason,
          _CAInvcgCorrectionCat,
          _CAInvcgDocLockedforPrint,
          _CAInvcgPeriodCat,
          _CAInvcgDocChrgDiscItems,
          _CAInvcgBolloTaxPostStatus,
          _CAInvcgDocPartOfList,
          _CAPaymentMethod,
          _CompanyCode,
          _ProviderContract,
          _CAReconciliationKey,
          _CAInvcgDocPrintReceiver,

          _CAInvcgUserContact,

          // Moved from Extension View X_S4C_C_CAINVCGDOCHEADER

          _CAInvcgDocHeader.CAClassificationKey

}