R_CAInvcgDocumentTP

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'IDH',
  dataSources: [ '_CAInvcgDocHeader', '_Extension' ],
  quota: {
    maximumFields: 340,
    maximumBytes: 6800
  }
}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Invoicing Document - TP'
@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  },
  representativeKey: 'CAInvoicingDocument',
  sapObjectNodeType.name: 'ContrAcctgInvoicingDocument'
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define root view entity R_CAInvcgDocumentTP
  as select from I_CAInvcgDocHeader as _CAInvcgDocHeader

  composition [0..*] of R_CAInvcgDocItemTP    as _CAInvcgDocItem

  // currently not part of a composition due to draft-enablement

  association [0..*] to R_CAInvcgDocPostingTP as _CAInvcgDocPosting  on  $projection.CAInvoicingDocument = _CAInvcgDocPosting.CAInvoicingDocument
  association [0..*] to R_CAInvcgDocSourceTP  as _CAInvcgDocSource   on  $projection.CAInvoicingDocument = _CAInvcgDocSource.CAInvoicingDocument

  // ADDITIONAL DATA

  association [0..1] to C_CABillgReqBPAddress as _CAInvcgBPAddress   on  $projection.BusinessPartner = _CAInvcgBPAddress.BusinessPartner
  association [0..1] to C_CAInvcgUserContact  as _CAInvcgUserContact on  $projection.CreatedByUser = _CAInvcgUserContact.ContactCardID
  association [0..1] to I_CAPaymentMethod     as _CAPaymentMethod    on  $projection.CAPaymentCompanyCodeCountry = _CAPaymentMethod.Country
                                                                     and $projection.CAPaymentMethod             = _CAPaymentMethod.CAPaymentMethod

  // extensibility

  association [0..1] to E_CAInvcgDocHeader    as _Extension          on  $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
{
  key CAInvoicingDocument,
      CAApplicationArea,
      CAInvcgProcess,
      CAInvcgType,
      CAInvcgCategory,
      CAInvcgTechnicalDocumentType,
      CAInvcgTargetProcess,
      BusinessPartner,
      ContractAccount,
      CAInvcgMasterDataType,
      AltvContractAcctForCollvBills,
      CASubstituteDocumentNumber,
      CreatedByUser,
      CAInvcgCreationDate,
      CAInvcgCreationTime,
      CAInvcgDocCreationMode,
      CAInvcgNmbrOfInvoicingDocItems,
      CABllbleItmNumber,
      CAInvcgDocInternalNumber,
      CAReconciliationKey,
      CAPostingDate,
      DocumentDate,
      CANetDueDate,
      CACashDiscountDueDate,
      CACashDiscountRate,
      TransactionCurrency,
      CAAmountInTransactionCurrency,
      CAInvcgIsDocumentPosted,
      CAInvcgIsDocumentSimulated,
      CAInvcgIsDocumentPreliminary,
      CAInvcgPreliminaryCategory,
      CAPrelimInvcgDocValue,
      CAPreliminaryInvcgDocStatus,
      CAInvcgDocumentReversalReason,
      CAInvcgReversalDocument,
      CAInvcgReversedDocument,
      CAInvcgCorrectionCategory,
      CAInvcgDocumentPrintDate,
      CAInvcgDocIsLockedForPrinting,
      @ObjectModel.foreignKey.association: '_CAPaymentMethod'
      CAPaymentMethod,
      CAPaymentFormNumber,
      CAInvcgDocFormID,
      ApplicationForm,
      FormIDForAttachedPaymentMedium,
      CAInvcgDocumentType,
      CAKeyIdentification,
      CAOfficialDocumentNumber,
      CAPartnerSettlementRule,
      CompanyCode,
      BusinessPlace,
      CAContract,
      CASubApplication,
      CAInvcgBaseDate,
      CAInvcgDocPeriodCategory,
      CAInvcgDocPeriodDate,
      CAInvcgDocPeriodStartDate,
      CADunningCounter,
      CAInvcgDocHasChargeOrDiscItems,
      CAInvcgDocHasControlDoc,
      CAInvcgBolloTaxPostStatus,
      CAInvcgDocIsPartOfList,
      CAInvcgDocHasObjectRelation,
      CAInvcgDocHasSEPAPreNotif,
      CAInvcgDocExternal,
      CAInvcgAdjustmentDocument,
      CAInvcgAdjustedDocument,

      // for UI fkey association

      _ContractAccountPartner._CompCodeGroup._CompanyCode.Country as CAPaymentCompanyCodeCountry,

      // from Extension

      CAClassificationKey,

      /* Associations */
      _BusinessPartner,
      _ContractAccountHeader,
      _ContractAccountPartner,
      _AltvContractAcctForCollvBills,
      _CAReconciliationKey,
      _TransactionCurrency,
      _CAInvcgPreliminaryCategory,
      _CAPreliminaryInvcgDocStatus,
      _CAInvcgProcess,
      _CAInvcgType,
      _CAInvcgCategory,
      _CAInvcgDocTechDocType,
      _CAInvcgTargetProc,
      _CAInvcgMasterDataType,
      _CAInvcgDocCreationMode,
      _CAInvcgDocReversalReason,
      _CAInvcgReversalDocument,
      _CAInvcgReversedDocument,
      _CAInvcgCorrectionCat,
      _CAInvcgDocumentType,
      _CAInvcgDocLockedforPrint,
      _CAInvcgPeriodCat,
      _CAInvcgDocChrgDiscItems,
      _CAInvcgBolloTaxPostStatus,
      _CAInvcgDocPartOfList,
      _CompanyCode,
      _CASubApplication,
      _ProviderContract,
      _CAInvcgDocHeader,
      _CAApplicationArea,

      // for UI

      _CAInvcgBPAddress,
      _CAInvcgUserContact,
      _CAPaymentMethod,

      _CAInvcgDocItem,
      _CAInvcgDocPosting,
      _CAInvcgDocSource
}