@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Fakturierungsbelege anzeigen'
@Consumption.semanticObject: 'CAInvoicingDocument'
@Search.searchable: true
@AccessControl: {
authorizationCheck: #MANDATORY,
personalData.blocking: #REQUIRED,
privilegedAssociations: [ '_CAInvcgUserContact' ]
}
@ObjectModel: {
usageType: {
serviceQuality: #C,
sizeCategory: #XL,
dataClass: #MIXED
},
representativeKey: 'CAInvoicingDocument',
semanticKey: ['CAInvoicingDocument']
}
@Analytics.technicalName: 'CCAINVDOC_DISP'
@UI.headerInfo: {
typeName: 'Fakturierungsbeleg anzeigen',
typeNamePlural: 'Fakturierungsbelege',
title: {
type: #STANDARD,
value: 'CAInvoicingDocument'
}
}
@UI.selectionVariant: [
{ text: 'Nichtstornierte Belege', qualifier: 'selvar_notrev', filter: 'CAInvcgReversalDocument eq null and CAInvcgReversedDocument eq null'},
{ text: 'Stornierte Belege', qualifier: 'selvar_reversed', filter: 'CAInvcgReversalDocument ne null and CAInvcgReversedDocument eq null'},
{ text: 'Stornobelege', qualifier: 'selvar_reversal', filter: 'CAInvcgReversalDocument eq null and CAInvcgReversedDocument ne null'},
{ text: 'Vorläufige Rechnungen', qualifier: 'selvar_prelim', filter: 'CAInvcgIsDocumentPreliminary eq "X"'},
{ text: 'Alle Belege', qualifier: 'selvar_all'}
]
@UI.presentationVariant: [{
sortOrder: [ { by: 'DocumentDate', direction: #DESC } ],
requestAtLeast: [
'CAInvcgDocPrntOutpCtrlIsEnbld', 'CAInvcgDocumentPrintIsEnabled', 'CAInvcgDocPrintPreviewIsEnbld',
'CAContractSemanticObject', 'CAInvcgDocReversalIsEnabled'
]
}]
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'C_CAInvcgDocHeader'
define view entity C_CAInvcgDocDisp
as select from R_CAInvcgDocumentTP as _CAInvcgDocHeader
// UI FACETS
association [1..*] to C_CAInvcgDocItem as _CAInvcgDocItem on $projection.CAInvoicingDocument = _CAInvcgDocItem.CAInvoicingDocument
association [1..*] to C_CAInvcgDocSource as _CAInvcgDocSource on $projection.CAInvoicingDocument = _CAInvcgDocSource.CAInvoicingDocument
association [1..*] to C_CAInvcgDocPosting as _CAInvcgDocPosting on $projection.CAInvoicingDocument = _CAInvcgDocPosting.CAInvoicingDocument
association [1..*] to C_CAInvcgDocRelation as _CAInvcgDocRelation on $projection.CAInvoicingDocument = _CAInvcgDocRelation.CAInvoicingDocument
association [1..*] to C_CAInvcgDocContractAccount as _CAInvcgDocContractAccount on $projection.ContractAccount = _CAInvcgDocContractAccount.ContractAccount
association [0..*] to C_CAInvcgDocPrintReceiver as _CAInvcgDocPrintReceiver on $projection.CAInvoicingDocument = _CAInvcgDocPrintReceiver.CAInvoicingDocument
and $projection.CAInvcgProcess = _CAInvcgDocPrintReceiver.CAInvcgProcess
and $projection.CAInvcgDocumentPrintDate is not initial
and $projection.CAInvcgDocIsLockedForPrinting is initial
and $projection.CAInvcgIsDocumentSimulated is initial
// required for in-app-navigation
association [0..1] to C_CAInvcgDocDisp as _CAInvcgReversedDocument on $projection.CAInvcgReversedDocument = _CAInvcgReversedDocument.CAInvoicingDocument
association [0..1] to C_CAInvcgDocDisp as _CAInvcgReversalDocument on $projection.CAInvcgReversalDocument = _CAInvcgReversalDocument.CAInvoicingDocument
association [0..1] to C_CAInvcgDocDisp as _CAInvcgAdjustedDocument on $projection.CAInvcgAdjustedDocument = _CAInvcgAdjustedDocument.CAInvoicingDocument
association [0..1] to C_CAInvcgDocDisp as _CAInvcgAdjustmentDocument on $projection.CAInvcgAdjustmentDocument = _CAInvcgAdjustmentDocument.CAInvoicingDocument
// extension
association [0..1] to E_CAInvcgDocHeader as _Extension on $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
{
@UI.facet: [
{ purpose: #HEADER, type: #FIELDGROUP_REFERENCE, id: 'Block1', targetQualifier: 'Block1', position: 10 },
{ purpose: #HEADER, type: #FIELDGROUP_REFERENCE, id: 'Block2', targetQualifier: 'Block2', position: 20 },
{ purpose: #HEADER, type: #FIELDGROUP_REFERENCE, id: 'Block3', targetQualifier: 'Block3', position: 30 },
{ purpose: #HEADER, type: #FIELDGROUP_REFERENCE, id: 'Block4', targetQualifier: 'Block4', position: 40 },
{ purpose: #FILTER, type: #FIELDGROUP_REFERENCE, id: 'FurtherFilter', targetQualifier: 'FurtherFilter', label: 'Weitere Einstellungen' }
]
//INVDOCNO
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85 }
@UI.selectionField: [ { position: 10 } ]
@UI.fieldGroup: [ { qualifier: 'Expanded' } ]
@UI.lineItem: [
{position: 10, importance: #HIGH },
{ type: #FOR_ACTION, position: 20, dataAction: 'MPC_EXT:ACTION_REVERSE', label: 'Stornieren', invocationGrouping: #CHANGE_SET },
{ type: #FOR_ACTION, position: 10, dataAction: 'MPC_EXT:ACTION_PRINT', label: 'Drucken', invocationGrouping: #CHANGE_SET }
]
@UI.identification: [
{ type: #FOR_ACTION, position: 20, dataAction: 'MPC_EXT:ACTION_REVERSE', label: 'Stornieren' },
{ type: #FOR_ACTION, position: 30, dataAction: 'MPC_EXT:ACTION_RELEASE', label: 'Freigeben' },
{ type: #FOR_ACTION, position: 10, dataAction: 'MPC_EXT:ACTION_PRINT', label: 'Drucken' }
// { type: #FOR_ACTION, position: 15, dataAction: 'MPC_EXT:ACTION_DUPLICATE', label: 'Drucken Duplikat' }
]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
key _CAInvcgDocHeader.CAInvoicingDocument,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( '' as abap.char(50) ) as UICT_CAInvoicingDocument,
//EXBEL
@UI.fieldGroup: [{ qualifier: 'OFFICIAL_DOCNO', position: 20 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAOfficialDocumentNumber,
//GPART
// @UI.hidden: true
// @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
// _CAInvcgDocHeader.FirstName,
// @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
// @UI.hidden: true
// _CAInvcgDocHeader.LastName,
@UI.hidden: true
@UI.fieldGroup: [ { qualifier: 'Block1', groupLabel: 'Block 1', position: 20 } ]
_CAInvcgDocHeader._BusinessPartner.BusinessPartnerFullName,
@UI.fieldGroup: [ { qualifier: 'Block1', position: 30 } ]
@ObjectModel.sort.enabled: false
@ObjectModel.filter.enabled: false
cast( concat_with_space(_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName,
_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber, 1)
as adress_gfn_kk preserving type ) as StreetName,
@UI.fieldGroup: [ { qualifier: 'Block1', position: 40 } ]
@ObjectModel.sort.enabled: false
@ObjectModel.filter.enabled: false
cast( concat_with_space(_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.CityName, 1)
as city_gfn_kk preserving type ) as AddressCityName,
@UI.fieldGroup: [ { qualifier: 'Block1', position: 50 } ]
@ObjectModel.sort.enabled: false
@ObjectModel.filter.enabled: false
cast( _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation._Country._Text[1: Language=$session.system_language].CountryName
as country_gfn_kk preserving type ) as CountryName,
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.9 }
@UI.selectionField: [ { position: 30 } ]
@UI.fieldGroup: [ { qualifier: 'Block1', position: 10 }, { qualifier: 'Expanded' } ]
@UI.lineItem: [ { position: 30 } ]
_CAInvcgDocHeader.BusinessPartner,
//VKONT
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.9 }
@UI.selectionField: [ { position: 40 } ]
@UI.fieldGroup: [ { qualifier: 'Expanded' }, { qualifier: 'Block2', groupLabel: 'Block 2', position: 10 } ]
@UI.lineItem: [ { position: 40 } ]
_CAInvcgDocHeader.ContractAccount,
@UI.hidden: true
_CAInvcgDocHeader._ContractAccountHeader.ContractAccountName,
//INV_TYPE
@UI.selectionField: [ { position: 50 } ]
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 30 } ]
@UI.lineItem: [ { position: 50 } ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgTypeVH', element: 'CAInvcgType' } } ]
@ObjectModel.text.element: ['CAInvcgTypeText']
_CAInvcgDocHeader.CAInvcgType,
@UI.hidden: true
_CAInvcgType._CAInvcgTypeText[1: Language=$session.system_language].CAInvcgTypeText,
//INVPERIOD
@UI.fieldGroup: [ { qualifier: 'INVPERIOD', position: 40 }, { qualifier: 'FurtherFilter' } ]
@UI.lineItem: [ { position: 60 } ]
_CAInvcgDocHeader.CAInvcgDocPeriodDate,
//BLDAT
@UI.selectionField: [ { position: 60 } ]
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 30 }, { qualifier: 'Expanded' }, { qualifier: 'Block3', position: 30 } ]
@UI.lineItem: [ { position: 70 } ]
_CAInvcgDocHeader.DocumentDate,
//Amount and Currency
@UI.fieldGroup: [ { qualifier: 'FurtherFilter'} ]
_CAInvcgDocHeader.TransactionCurrency,
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 35 },
{ qualifier: 'FurtherFilter' },
{ qualifier: 'Block3', position: 10 } ]
@UI.lineItem: [ { position: 80 } ]
_CAInvcgDocHeader.CAAmountInTransactionCurrency,
//INV_PROCESS
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 10 }, { qualifier: 'FurtherFilter' } ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgProcessVH', element: 'CAInvcgProcess' } } ]
@ObjectModel.text.element: ['CAInvcgProcessText']
_CAInvcgDocHeader.CAInvcgProcess,
@UI.hidden: true
_CAInvcgProcess._CAInvcgProcessText[1: Language=$session.system_language].CAInvcgProcessText,
//DOCTYPE
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 5 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocumentTypeText']
_CAInvcgDocHeader.CAInvcgDocumentType,
@UI.hidden: true
_CAInvcgDocumentType._CAInvcgDocumentTypeText[1: Language=$session.system_language].CAInvcgDocumentTypeText,
//MAZAE
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 70 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CADunningCounter,
//CFCSIMULATED
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 90 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocHasControlDoc,
//FORMKEY
@UI.fieldGroup: [ { qualifier: 'PRINT', position: 10 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.ApplicationForm,
//PRINTDATE
@UI.fieldGroup: [ { qualifier: 'PRINT', position: 20 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocumentPrintDate,
//PRINTLOCK
@UI.fieldGroup: [ { qualifier: 'PRINT', position: 30 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocLockedForPrintText']
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgDocLockedForPrintVH', element: 'CAInvcgDocIsLockedForPrinting' } } ]
_CAInvcgDocHeader.CAInvcgDocIsLockedForPrinting,
@UI.hidden: true
_CAInvcgDocLockedforPrint._CAInvcgDocLockedForPrintText[1: Language=$session.system_language].CAInvcgDocLockedForPrintText,
//FAEDN - Due date for net payment
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 40 }, { qualifier: 'FurtherFilter' }, { qualifier: 'Block3', position: 20} ]
@UI.lineItem: [ { position: 90 } ]
_CAInvcgDocHeader.CANetDueDate,
//REVREASON - Reversal Reason
@UI.fieldGroup: [ { qualifier: 'REVERSAL_CORRECTION', position: 10 }, { qualifier: 'FG_ObjectPageHeader5'}, { qualifier: 'FurtherFilter' }, { qualifier: 'Block4', position: 40} ]
@ObjectModel.text.element: ['CAInvcgDocReversalReasonText']
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgDocReversalReasonVH', element: 'CAInvcgDocumentReversalReason' } } ]
_CAInvcgDocHeader.CAInvcgDocumentReversalReason,
@UI.hidden: true
_CAInvcgDocReversalReason._CAInvcgDocReversalReasonText[1: Language=$session.system_language].CAInvcgDocReversalReasonText,
//INVOICED
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 80 },
{ qualifier: 'FurtherFilter' },
{ qualifier: 'Block4', position: 10}]
_CAInvcgDocHeader.CAInvcgIsDocumentPosted,
//PRELIMINARY
@UI.fieldGroup: [ { qualifier: 'PRELIMINARY_INV', position: 10 },
{ qualifier: 'FurtherFilter' },
{ qualifier: 'Block4', position: 20} ]
_CAInvcgDocHeader.CAInvcgIsDocumentPreliminary,
//TED
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 220 },
{ qualifier: 'FurtherFilter' },
{ qualifier: 'Block4', position: 30 }]
_CAInvcgDocHeader.CAInvcgIsDocumentSimulated,
//BUDAT
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 20 },
{ qualifier: 'Block5', position: 40 },
{ qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAPostingDate,
//APPLK
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 210 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAApplicationArea,
//TECHDOCTYPE
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 50 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocTechDocTypeText']
_CAInvcgDocHeader.CAInvcgTechnicalDocumentType,
@UI.hidden: true
_CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText[1: Language=$session.system_language].CAInvcgDocTechDocTypeText,
//TARGPROCESS
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 40 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgTargetProcText']
_CAInvcgDocHeader.CAInvcgTargetProcess,
@UI.hidden: true
_CAInvcgTargetProc._CAInvcgTargetProcText[1: Language=$session.system_language].CAInvcgTargetProcText,
//MDCAT
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 10 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgMasterDataTypeText']
_CAInvcgDocHeader.CAInvcgMasterDataType,
@UI.hidden: true
_CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,
//ABWVK
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 20 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.AltvContractAcctForCollvBills,
//ABWBL
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 30 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CASubstituteDocumentNumber,
//CRNAME
@UI.hidden: true
@ObjectModel.filter.enabled: false
_CAInvcgDocHeader.CreatedByUser,
//CRDATE - only ui.hidden, as it is needed for change documents
@UI.hidden: true
_CAInvcgDocHeader.CAInvcgCreationDate,
//CRTIME
@Consumption.hidden: true
//@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 30 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgCreationTime,
//combined field of crdate and crtime
@UI.selectionField: [ { position: 70 } ]
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 20 } ]
@Consumption.filter.selectionType: #INTERVAL
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
cast(dats_tims_to_tstmp(_CAInvcgDocHeader.CAInvcgCreationDate, _CAInvcgDocHeader.CAInvcgCreationTime,
abap_system_timezone($session.client, 'NULL'),
$session.client, 'NULL') as invdoc_crtsmp_kk) as CAInvcgCreationDateTime,
//CRMODE
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 40 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocCreationModeText']
_CAInvcgDocHeader.CAInvcgDocCreationMode,
@UI.hidden: true
_CAInvcgDocCreationMode._CAInvcgDocCreationModeText[1: Language=$session.system_language].CAInvcgDocCreationModeText,
//RECNUM
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 50 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgNmbrOfInvoicingDocItems,
//BIT_NUMBER
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 55 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CABllbleItmNumber,
//FIKEY
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 10 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAReconciliationKey,
//INVRUNNO
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 60 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocInternalNumber,
//FAEDS
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 50 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CACashDiscountDueDate,
//SKTPZ
@UI.fieldGroup: [ { qualifier: 'POSTING', position: 60 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CACashDiscountRate,
//PRLINV_CAT
@UI.fieldGroup: [ { qualifier: 'PRELIMINARY_INV', position: 20 }, { qualifier: 'FurtherFilter' } ]
@Consumption.valueHelpDefinition: [{ association: '_CAInvcgPreliminaryCategory' }]
@ObjectModel.text.element: ['CAInvcgPreliminaryCategoryTxt']
_CAInvcgDocHeader.CAInvcgPreliminaryCategory,
@UI.hidden: true
_CAInvcgPreliminaryCategory._Text[1: Language=$session.system_language].CAInvcgPreliminaryCategoryTxt,
//PRLINV_CNT
@UI.fieldGroup: [ { qualifier: 'PRELIMINARY_INV', position: 30 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAPrelimInvcgDocValue,
//PRLINV_STATUS
@UI.fieldGroup: [ { qualifier: 'PRELIMINARY_INV', position: 40 }, { qualifier: 'FurtherFilter' } ]
@Consumption.valueHelpDefinition: [{ association: '_CAPreliminaryInvcgDocStatus' }]
@ObjectModel.text.element: ['CAPreliminaryInvcgDocStatusTxt']
_CAInvcgDocHeader.CAPreliminaryInvcgDocStatus,
@UI.hidden: true
_CAPreliminaryInvcgDocStatus._Text[1: Language=$session.system_language].CAPreliminaryInvcgDocStatusTxt,
//INV_CATEGORY
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 20 }, { qualifier: 'FurtherFilter' } ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgCategoryVH', element: 'CAInvcgCategory' } } ]
@ObjectModel.text.element: ['CAInvcgCategoryText']
_CAInvcgDocHeader.CAInvcgCategory,
@UI.hidden: true
_CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,
//REVERSALDOC
@UI.fieldGroup: [ { qualifier: 'REVERSAL_CORRECTION', position: 20, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgReversalDocument', targetElement: '_CAInvcgReversalDocument' },
{ qualifier: 'FurtherFilter' } ]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAInvcgDocVH', element: 'CAInvoicingDocument' }}]
_CAInvcgDocHeader.CAInvcgReversalDocument,
//REVERSEDDOC
@UI.fieldGroup: [ { qualifier: 'REVERSAL_CORRECTION', position: 30, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgReversedDocument', targetElement: '_CAInvcgReversedDocument' },
{ qualifier: 'FurtherFilter' } ]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAInvcgDocVH', element: 'CAInvoicingDocument' }}]
_CAInvcgDocHeader.CAInvcgReversedDocument,
//CORRCAT
@UI.fieldGroup: [ { qualifier: 'REVERSAL_CORRECTION', position: 60 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgCorrectionCatText']
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgCorrectionCatVH', element: 'CAInvcgCorrectionCategory' } } ]
_CAInvcgDocHeader.CAInvcgCorrectionCategory,
@UI.hidden: true
_CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,
//PYMET
@UI.fieldGroup: [ { qualifier: 'PAYMENT', position: 10 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAPaymentMethodName']
_CAInvcgDocHeader.CAPaymentMethod,
@UI.hidden: true
_CAPaymentMethod._Text[1: Language=$session.system_language].CAPaymentMethodName,
//NRZAS
@UI.fieldGroup: [ { qualifier: 'PAYMENT', position: 20 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAPaymentFormNumber,
//ZLSCH
@UI.fieldGroup: [ { qualifier: 'PAYMENT', position: 30 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.FormIDForAttachedPaymentMedium,
//EXKID
@UI.fieldGroup: [ { qualifier: 'OFFICIAL_DOCNO', position: 10 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAKeyIdentification,
//PTSRL
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 60 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAPartnerSettlementRule,
//BUKRS
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 40 }, { qualifier: 'FurtherFilter' } ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CACompanyCodeVH', element: 'CompanyCode' } } ]
@ObjectModel.text.element: ['CompanyCodeName']
_CAInvcgDocHeader.CompanyCode,
@UI.hidden: true
_CompanyCode.CompanyCodeName,
//BUPLA
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 50 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.BusinessPlace,
//INVOICE_BASEDATE
@UI.fieldGroup: [ { qualifier: 'INVPERIOD', position: 10 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgBaseDate,
//INVPERCAT
@UI.fieldGroup: [ { qualifier: 'INVPERIOD', position: 20 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgPeriodCatText']
_CAInvcgDocHeader.CAInvcgDocPeriodCategory,
@UI.hidden: true
_CAInvcgPeriodCat._CAInvcgPeriodCatText[1: Language=$session.system_language].CAInvcgPeriodCatText,
//INVPERIOD
@UI.fieldGroup: [ { qualifier: 'INVPERIOD', position: 30 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocPeriodStartDate,
//CHGDOC_EX
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 80 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocChrgDiscItemsText']
_CAInvcgDocHeader.CAInvcgDocHasChargeOrDiscItems,
@UI.hidden: true
_CAInvcgDocChrgDiscItems._CAInvcgDocChrgDiscItemsText[1: Language=$session.system_language].CAInvcgDocChrgDiscItemsText,
//BOLLOTAX
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 100 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgBolloTaxPostStatText']
_CAInvcgDocHeader.CAInvcgBolloTaxPostStatus,
@UI.hidden: true
_CAInvcgBolloTaxPostStatus._CAInvcgBolloTaxPostStatText[1: Language=$session.system_language].CAInvcgBolloTaxPostStatText,
//XSUBINV
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 70 }, { qualifier: 'FurtherFilter' } ]
@ObjectModel.text.element: ['CAInvcgDocPartOfListText']
_CAInvcgDocHeader.CAInvcgDocIsPartOfList,
@UI.hidden: true
_CAInvcgDocPartOfList._CAInvcgDocPartOfListText[1: Language=$session.system_language].CAInvcgDocPartOfListText,
//XINVDOC_X
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 80 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocHasObjectRelation,
//SEPA_PRENOT
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 110 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocHasSEPAPreNotif,
//EXT_INVDOCNO
@UI.fieldGroup: [ { qualifier: 'OTHERS', position: 120 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocExternal,
//FORM_ID
@UI.fieldGroup: [ { qualifier: 'PRINT', position: 09 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CAInvcgDocFormID,
//ADJUSTMENTDOC
@UI.fieldGroup: [
{ qualifier: 'REVERSAL_CORRECTION', position: 40, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgAdjustmentDocument', targetElement: '_CAInvcgAdjustmentDocument' },
{ qualifier: 'FurtherFilter' }
]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
_CAInvcgDocHeader.CAInvcgAdjustmentDocument,
//ADJUSTEDDOC
@UI.fieldGroup: [
{ qualifier: 'REVERSAL_CORRECTION', position: 50, type: #WITH_NAVIGATION_PATH, value: 'CAInvcgAdjustedDocument', targetElement: '_CAInvcgAdjustedDocument' },
{ qualifier: 'FurtherFilter' }
]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
_CAInvcgDocHeader.CAInvcgAdjustedDocument,
//VTREF
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 60 }, { qualifier: 'FurtherFilter' } ]
@UI.selectionField: [ { position: 45 } ]
@ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
_CAInvcgDocHeader.CAContract,
//VTREF_SEMOBJ
@ObjectModel: {
virtualElement: true,
virtualElementCalculatedBy: 'ABAP:CL_CINV_VTREF_SEMOBJ'
}
cast ( '' as vtref_semobj_kk ) as CAContractSemanticObject,
//SUBAP
@UI.fieldGroup: [ { qualifier: 'GENERAL', position: 70 }, { qualifier: 'FurtherFilter' } ]
_CAInvcgDocHeader.CASubApplication,
@Consumption.hidden: true
_CAInvcgDocHeader.CAPaymentCompanyCodeCountry,
// Action control: Print
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( 'X' as xfeld ) as CAInvcgDocumentPrintIsEnabled,
// Action control: Print (Output Control to be used)
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast ( 'X' as xfeld ) as CAInvcgDocPrntOutpCtrlIsEnbld,
// Action control: Print Preview
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( 'X' as xfeld ) as CAInvcgDocPrintPreviewIsEnbld,
// Action control: Reversal
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( 'X' as xfeld ) as CAInvcgDocReversalIsEnabled,
// Action control: Create Credit/Debit Memo
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( 'X' as xfeld ) as CAInvcgDocBillgReqIsEnabled,
// Action control: Release Preliminary Invoice
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( 'X' as xfeld ) as CAInvcgDocReleaseIsEnabled,
// Dispute Case Management
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
cast( '' as xfeld ) as CADisputeCaseIsExisting,
// Make association public
_CAInvcgDocItem,
@Consumption.filter.hidden: true
_CAInvcgDocSource,
@Consumption.filter.hidden: true
_CAInvcgDocPosting,
@Consumption.filter.hidden: true
_CAInvcgDocRelation,
@Consumption.filter.hidden: true
_CAInvcgDocContractAccount,
@Consumption.filter.hidden: true
_BusinessPartner,
@Consumption.filter.hidden: true
_ContractAccountPartner,
@Consumption.filter.hidden: true
_ContractAccountHeader,
@Consumption.filter.hidden: true
_AltvContractAcctForCollvBills,
@Consumption.filter.hidden: true
_CAInvcgDocumentType,
@Consumption.filter.hidden: true
_TransactionCurrency,
@Consumption.filter.hidden: true
_CAInvcgPreliminaryCategory,
@Consumption.filter.hidden: true
_CAPreliminaryInvcgDocStatus,
@Consumption.filter.hidden: true
_CAInvcgReversedDocument,
@Consumption.filter.hidden: true
_CAInvcgReversalDocument,
@Consumption.filter.hidden: true
_CAInvcgAdjustedDocument,
@Consumption.filter.hidden: true
_CAInvcgAdjustmentDocument,
@Consumption.filter.hidden: true
_CAInvcgProcess,
@Consumption.filter.hidden: true
_CAInvcgType,
@Consumption.filter.hidden: true
_CAInvcgCategory,
@Consumption.filter.hidden: true
_CAInvcgDocTechDocType,
@Consumption.filter.hidden: true
_CAInvcgTargetProc,
@Consumption.filter.hidden: true
_CAInvcgMasterDataType,
@Consumption.filter.hidden: true
_CAInvcgDocCreationMode,
@Consumption.filter.hidden: true
_CAInvcgDocReversalReason,
@Consumption.filter.hidden: true
_CAInvcgCorrectionCat,
@Consumption.filter.hidden: true
_CAInvcgDocLockedforPrint,
@Consumption.filter.hidden: true
_CAInvcgPeriodCat,
@Consumption.filter.hidden: true
_CAInvcgDocChrgDiscItems,
@Consumption.filter.hidden: true
_CAInvcgBolloTaxPostStatus,
@Consumption.filter.hidden: true
_CAInvcgDocPartOfList,
@Consumption.filter.hidden: true
_CAPaymentMethod,
@Consumption.filter.hidden: true
_CompanyCode,
@Consumption.filter.hidden: true
_ProviderContract,
@Consumption.filter.hidden: true
_CAReconciliationKey,
@Consumption.filter.hidden: true
_CAInvcgDocPrintReceiver,
@UI.lineItem: [ { position: 110, label: 'Angelegt von', type: #AS_CONTACT, value: '_CAInvcgUserContact', cssDefault.width: '10rem' } ]
@UI.fieldGroup: [ { qualifier: 'ADMINISTRATIVE', position: 10, label: 'Angelegt von', type: #AS_CONTACT, value: '_CAInvcgUserContact' },
{ qualifier: 'Block3', position: 40, label: 'Angelegt von', type: #AS_CONTACT, value: '_CAInvcgUserContact' } ]
@Consumption.filter.hidden: true
_CAInvcgUserContact,
// Moved from Extension View X_S4C_C_CAINVCGDOCDISP
_CAInvcgDocHeader.CAClassificationKey
}