R_TRANSPORTATIONORDERSTOPTP

CDS View

Transportation Order Stop - TP

R_TRANSPORTATIONORDERSTOPTP is a CDS View in S/4HANA. Transportation Order Stop - TP. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_FreightBookingStop view_entity projection CONSUMPTION Freight Booking Stop
A_FreightOrderStop view_entity projection CONSUMPTION Freight Order Stop
A_FreightUnitStop view_entity projection CONSUMPTION Freight Unit Stop
I_FreightBookingStopTP view_entity projection TRANSACTIONAL Freight Booking Stop - TP
I_FreightOrderStopTP view_entity projection TRANSACTIONAL Freight Order Stop - TP
I_FreightUnitStopTP view_entity projection TRANSACTIONAL Freight Unit Stop - TP 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [
    '_CapacityStop'
  ]
}
@EndUserText.label: 'Transportation Order Stop - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TransportationOrderStop'],
    representativeKey: 'TransportationOrderStopUUID'
}

define view entity R_TransportationOrderStopTP
  as select from I_TransportationOrderStop_2 as TransportationOrderStop

  association        to parent R_TransportationOrderTP as _TransportationOrder        on  $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  composition [0..*] of R_TransportationOrderStageTP   as _TranspOrderStage
  composition [0..1] of R_TrOrdStopLocAddrDfltRprstnTP as _TrOrdStopLocAddrDfltRprstn

  association [0..1] to I_TranspOrdExecTranspActy      as _TranspOrdExecTranspActyDep on  $projection.TransportationOrderStopUUID       = _TranspOrdExecTranspActyDep.TransportationOrderStopUUID
                                                                                      and _TranspOrdExecTranspActyDep.TranspOrdActivity = '03'
  association [0..1] to I_TranspOrdExecTranspActy      as _TranspOrdExecTranspActyArr on  $projection.TransportationOrderStopUUID       = _TranspOrdExecTranspActyArr.TransportationOrderStopUUID
                                                                                      and _TranspOrdExecTranspActyArr.TranspOrdActivity = '04'
{
      /* Attributes */

      // Identification

  key TransportationOrderStop.TransportationOrderStopUUID,
      TransportationOrderStop.TransportationOrderUUID,
      TransportationOrderStop.TransportationOrderStop,

      // Key Characteristics

      TransportationOrderStop.TranspOrdStopCategory,
      TransportationOrderStop.TranspOrdStopRole,

      // Location

      TransportationOrderStop.LocationAdditionalUUID, // This is the RAW16 UUID of the Location; LocationUUID is the CHAR22 GUID

      TransportationOrderStop.LocationId,
      TransportationOrderStop.LocationUNCode,
      TransportationOrderStop.LocationAirportCode as LocationIATACode,

      // Dates and Times

      TransportationOrderStop.TranspOrdStopAccptblStrtDteTme,
      TransportationOrderStop.TranspOrdStopReqStartDteTme,
      TransportationOrderStop.TranspOrdStopReqEndDteTme,
      TransportationOrderStop.TranspOrdStopAccptblEndDteTme,

      TransportationOrderStop.TranspOrdStopPlanTranspDteTme,

      TransportationOrderStop.TranspOrdStopApptStrtDteTme,
      TransportationOrderStop.TranspOrdStopApptEndDteTme,

      TransportationOrderStop.TranspStopCarrConfStrtDteTme,
      TransportationOrderStop.TranspStopCarrConfEndDteTme,

      TransportationOrderStop.TranspOrdStopDocCutOffDateTime,
      TransportationOrderStop.TranspOrdStopCrgoCutOffDteTme,
      TransportationOrderStop.TranspOrdStopVGMCutOffDateTime,

      case // In case we have an actual date/time for departure, this is used as TranspOrdStopDteTme. otherwise the  TranspOrdStopPlanTranspDteTme is used as fallback

        when TranspOrdStopCategory = 'O' and _TranspOrdExecTranspActyDep.TranspOrdEvtActualDateTime is not initial then _TranspOrdExecTranspActyDep.TranspOrdEvtActualDateTime
        when TranspOrdStopCategory = 'I' and _TranspOrdExecTranspActyArr.TranspOrdEvtActualDateTime is not initial then _TranspOrdExecTranspActyArr.TranspOrdEvtActualDateTime
        else cast(TranspOrdStopPlanTranspDteTme as log_created_on preserving type)
      end                                         as TranspOrdStopDteTme,

      // Further Attributes

      TransportationOrderStop.TranspOrdStopSequencePosition,

      // References to Capacity Documents

      TransportationOrderStop.TranspOrdCapacityStopUUID,
      TransportationOrderStop.TranspOrdStopCapacityItemUUID,

      // Status

      TransportationOrderStop.TranspOrdStopHndlgExecStatus,
      @Semantics.booleanIndicator
      TransportationOrderStop.TranspOrdStopExecIsBlocked,

      // (Technical/Hidden) Attributes

      _TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TransportationOrderStop._CapacityStop,
      TransportationOrderStop._Location,
      TransportationOrderStop._TranspHndlgExecStatus,
      TransportationOrderStop._TranspOrdStopCategory,
      TransportationOrderStop._TranspOrdStopRole,
      
      /* Composition Associations */
      _TransportationOrder,
      @Semantics.valueRange.maximum: '1'
      _TranspOrderStage,
      _TrOrdStopLocAddrDfltRprstn
}

Learn More