I_FreightUnitStopTP

@EndUserText.label: 'Freight Unit Stop - TP'
@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
   modelingPattern: #TRANSACTIONAL_INTERFACE,
   supportedCapabilities: [#TRANSACTIONAL_PROVIDER],
   usageType: {
     sizeCategory:   #L,
     serviceQuality: #C,
     dataClass:      #TRANSACTIONAL
   },
    semanticKey: ['TransportationOrderStop'],
    representativeKey: 'TransportationOrderStopUUID',
   sapObjectNodeType.name: 'FreightUnitStop'
}
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #MANDATORY

define view entity I_FreightUnitStopTP
  as projection on R_TransportationOrderStopTP as FreightUnitStop
{
      // Identification

  key TransportationOrderStopUUID,
      TransportationOrderUUID,
      TransportationOrderStop,

      // Key Characteristics

      TranspOrdStopCategory,
      TranspOrdStopRole,

      // Location

      LocationAdditionalUUID, // This is the RAW16 UUID of the Location; LocationUUID is the CHAR22 GUID

      LocationId,
      LocationUNCode,
      LocationIATACode,

      // Dates and Times

      TranspOrdStopAccptblStrtDteTme,
      TranspOrdStopReqStartDteTme,
      TranspOrdStopReqEndDteTme,
      TranspOrdStopAccptblEndDteTme,

      TranspOrdStopDteTme,

      // Further Attributes

      TranspOrdStopSequencePosition,

      // References to Freight Order

      TranspOrdCapacityStopUUID,
      TranspOrdStopCapacityItemUUID,

      // Status

      @Semantics.booleanIndicator
      TranspOrdStopExecIsBlocked,

      FreightUnitStop._TransportationOrder        as _FreightUnit                  : redirected to parent I_FreightUnitTP,
      @Semantics.valueRange.maximum: '1'
      FreightUnitStop._TranspOrderStage           as _FreightUnitStage             : redirected to composition child I_FreightUnitStageTP,
      FreightUnitStop._TrOrdStopLocAddrDfltRprstn as _FrtUnitStopLocAddrDfltRprstn : redirected to composition child I_FrtUnitStopLocAdDfRpnTP
}
where
  FreightUnitStop.TransportationOrderCategory = 'FU'