A_FreightUnitStop

@EndUserText.label: 'Freight Unit Stop'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }}
@VDM.viewType: #CONSUMPTION
@OData.entityType.name: 'FreightUnitStop_Type'
@Metadata.ignorePropagatedAnnotations: true

define view entity A_FreightUnitStop
  as projection on R_TransportationOrderStopTP as FreightUnitStop
{
      // Identification

  key TransportationOrderStopUUID,
      TransportationOrderUUID,
      TransportationOrderStop,
      //TranspOrdStopStopParentUUID,  // Stop Hierarchies are currently not supported in S/4HANA Cloud


      // Key Characteristics

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderStopCategory'
      TranspOrdStopCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'TransportationOrderStopRole'
      TranspOrdStopRole,

      // Location

      LocationAdditionalUUID, // This is the RAW16 UUID of the Location; LocationUUID is the CHAR22 GUID

      LocationId,
      LocationUNCode,
      LocationIATACode,

      // Dates and Times

      TranspOrdStopAccptblStrtDteTme,
      TranspOrdStopReqStartDteTme,
      TranspOrdStopReqEndDteTme,
      TranspOrdStopAccptblEndDteTme,

      TranspOrdStopDteTme, // Calculated field via actual_date of event or plan_trans_time of stop as fallback


      // Further Attributes

      TranspOrdStopSequencePosition,

      // References to Freight Order

      TranspOrdCapacityStopUUID,
      TranspOrdStopCapacityItemUUID,

      // Status

      @Semantics.booleanIndicator
      TranspOrdStopExecIsBlocked,

      FreightUnitStop._TransportationOrder        as _FreightUnit                  : redirected to parent A_FreightUnit,
      @Semantics.valueRange.maximum: '1'
      FreightUnitStop._TranspOrderStage           as _FreightUnitStage             : redirected to composition child A_FreightUnitStage,
      FreightUnitStop._TrOrdStopLocAddrDfltRprstn as _FrtUnitStopLocAddrDfltRprstn : redirected to composition child A_FrtUnitStopLocAddrDfltRprstn
}
where
  FreightUnitStop.TransportationOrderCategory = 'FU'