A_FreightBookingStop

@EndUserText.label: 'Freight Booking Stop'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }}
@VDM.viewType: #CONSUMPTION
@OData.entityType.name: 'FreightBookingStop_Type'
@Metadata.ignorePropagatedAnnotations: true

define view entity A_FreightBookingStop
  as projection on R_TransportationOrderStopTP as FreightBookingStop
{
      // Identification

  key TransportationOrderStopUUID,
      TransportationOrderUUID,
      TransportationOrderStop,
      //TranspOrdStopStopParentUUID,  // Stop Hierarchies are currently not supported in S/4HANA Cloud


      // Key Characteristics

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderStopCategory'
      TranspOrdStopCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'TransportationOrderStopRole'
      TranspOrdStopRole,

      // Location

      LocationAdditionalUUID, // This is the RAW16 UUID of the Location; LocationUUID is the CHAR22 GUID

      LocationId,
      LocationUNCode,
      LocationIATACode,

      // Dates and Times

      TranspOrdStopPlanTranspDteTme,
      TranspOrdStopDteTme, // Calculated field via actual_date of event or plan_trans_time of stop as fallback


      TranspOrdStopApptStrtDteTme,
      TranspOrdStopApptEndDteTme,
      TranspStopCarrConfStrtDteTme,
      TranspStopCarrConfEndDteTme,

      TranspOrdStopDocCutOffDateTime,
      TranspOrdStopCrgoCutOffDteTme,
      TranspOrdStopVGMCutOffDateTime,

      // Further Attributes

      TranspOrdStopSequencePosition,

      // Status

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdStopHndlgExecStatus'
      TranspOrdStopHndlgExecStatus,
      @Semantics.booleanIndicator
      TranspOrdStopExecIsBlocked,

      FreightBookingStop._TransportationOrder        as _FreightBooking              : redirected to parent A_FreightBooking,
      @Semantics.valueRange.maximum: '1'
      FreightBookingStop._TranspOrderStage           as _FreightBookingStage         : redirected to composition child A_FreightBookingStage,
      FreightBookingStop._TrOrdStopLocAddrDfltRprstn as _FrtBkgStopLocAddrDfltRprstn : redirected to composition child A_FrtBkgStopLocAddrDfltRprstn
}
where
  FreightBookingStop.TransportationOrderCategory = 'BO'