I_WBSELEMENTBASICDATA

@AbapCatalog: {
  sqlViewName: 'IWBSELMNTBSCDATA',
  compiler.compareFilter: true
}

@Analytics: { dataCategory: #DIMENSION }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'WBS Element Basic Data'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@Metadata.ignorePropagatedAnnotations:true

@Metadata.allowExtensions: true

@ObjectModel: {
    //Keys

    semanticKey: [ 'WBSElement' ],
    representativeKey: 'WBSElementInternalID',

    usageType: {
        serviceQuality: #B,
        sizeCategory : #XL,
        dataClass: #TRANSACTIONAL
    },

    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION ]
}

define view I_WBSElementBasicData
  as select from prps
  association [0..1] to prte                          as _prte                  on  prps.pspnr = _prte.posnr
                                                                                and prps.psphi = _prte.psphi

  association [1..1] to I_ProjectBasicData            as _Project               on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [0..1] to I_CompanyCode                 as _CompanyCode           on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea             as _ControllingArea       on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_FunctionalArea              as _FunctionalArea        on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..*] to I_ProfitCenter                as _ProfitCenter          on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..*] to I_CostCenter                  as _ResponsibleCostCenter on  $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
                                                                                and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
  association [0..1] to I_Plant                       as _Plant                 on  $projection.Plant = _Plant.Plant
  association [0..1] to I_FactoryCalendar             as _FactoryCalendar       on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  //  association [0..*] to I_CostingSheetProcedure as _CostingSheetProcedure on $projection.CostingSheet = _CostingSheetProcedure.CostingSheetProcedure

  association [0..*] to I_CostCenter                  as _CostCenter            on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                                and $projection.CostCenter      = _CostCenter.CostCenter
  association [0..1] to I_Projecttype                 as _ProjectType           on  $projection.ProjectType = _ProjectType.ProjectType
  association [0..*] to I_Projecttypetext             as _ProjectTypeText       on  $projection.ProjectType = _ProjectTypeText.ProjectType

  //CE2111-RA key description

  association [0..1] to I_ResultsAnalysisKeyValueHelp as _RaKeyVH               on  $projection.ResultAnalysisInternalID = _RaKeyVH.ResultAnalysisInternalID
 // Multilanguage Short text 

  association [0..1] to I_ProjectObjectShortText     as _WBSElementShortText        on  _WBSElementShortText.Language   = $session.system_language
                                                                                    and _WBSElementShortText.ProjectApplicationIdentifier = 'PS'
                                                                                    and _WBSElementShortText.ProjectObjectType = 'PR'
                                                                                    and $projection.WBSElementObject = _WBSElementShortText.ProjectObjectNode
  
{

  key cast ( prps.pspnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      @ObjectModel.text.element: 'WBSDescription'
      prps.posid_edit                                    as WBSElementExternalID,
      @ObjectModel.text.element: 'WBSDescription'
      prps.posid                                         as WBSElement,
      prps.poski                                         as WBSElementShortID,
      @Semantics.text: true
      cast ( prps.post1 as ps_s4_post1 preserving type ) as WBSDescription,

      //Organizational fields

      //--[ GENERATED:012:GFBfhyK17jY4hilWz{vTHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast ( prps.pbukr as bukrs preserving type )       as CompanyCode,

      //--[ GENERATED:012:GFBfhyK17jY4hilWz{vTHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingArea',
                     element: 'ControllingArea' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast ( prps.pkokr as ps_s4_kokrs preserving type ) as ControllingArea,

      @ObjectModel.foreignKey.association: '_FunctionalArea'
      cast ( prps.func_area as fkber preserving type )   as FunctionalArea,

      //--[ GENERATED:012:GFBfhyK17jY4hilWz{vTHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProfitCenterStdVH',
                     element: 'ProfitCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ProfitCenter'
      prps.prctr                                         as ProfitCenter,

      //--[ GENERATED:012:GFBfhyK17jY4hilWz{vTHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      cast ( prps.fkstl as ps_s4_fkstl preserving type ) as ResponsibleCostCenter,

      @ObjectModel.foreignKey.association: '_Plant'
      prps.werks                                         as Plant,

      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      cast ( prps.fabkl as stkal preserving type )       as FactoryCalendar,

      //      @ObjectModel.foreignKey.association: '_CostingSheetProcedure'

      prps.kalsm                                         as CostingSheet,

      //--[ GENERATED:012:GFBfhyK17jY4hilWz{vTHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CostCenter'
      cast ( prps.kostl as ps_kostl preserving type )    as CostCenter,

      //  _Project.ProjectObject,

      //Dimensions

      // @ObjectModel.foreignKey.association: '_Project'

      cast ( prps.psphi as ps_psphi preserving type )    as ProjectInternalID,
      cast ( prps.fakkz as ps_fakkz preserving type )    as WBSElementIsBillingElement,
      prps.objnr                                         as WBSElementObject,
      prps.imprf                                         as InvestmentProfile,
      prps.xstat                                         as WBSIsStatisticalWBSElement,
      cast ( prps.belkz as ps_s4_belkz preserving type ) as WBSIsAccountAssignmentElement,
      @ObjectModel.foreignKey.association: '_ProjectType'
      @ObjectModel.text.association: '_ProjectTypeText'
      prps.prart                                         as ProjectType,
      //Joint venture fields

      prps.vname                                         as JointVenture,
      prps.recid                                         as JointVentureCostRecoveryCode,
      prps.etype                                         as JointVentureEquityType,
      prps.otype                                         as JntVntrProjectType,
      prps.jibcl                                         as JntIntrstBillgClass,
      prps.jibsa                                         as JntIntrstBillgSubClass,
      prps.stort                                         as Location,
      prps.abgsl                                         as ResultAnalysisInternalID,
      //Public Sector fields

      prps.rfund                                         as Fund,
      prps.rgrant_nbr                                    as GrantID,
      prps.fund_fix_assign                               as FundIsFixAssigned,
      prps.func_area_fix_assigned                        as FunctionalAreaIsFixAssigned,
      prps.grant_fix_assigned                            as GrantIsFixAssigned,
      //2008 new  public sector field

      prps.sponsoredprog                                 as SponsoredProgram,
      //Tax Jurisdiction, Functional Location fields

      prps.txjcd                                         as TaxJurisdiction,
      prps.tplnr                                         as FunctionalLocation,
      @Semantics.user.createdBy: true
      prps.ernam                                         as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      prps.erdat                                         as CreationDate,
      @Semantics.user.lastChangedBy: true
      prps.aenam                                         as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      prps.aedat                                         as LastChangeDate,

      prps.fkokr                                         as RespCostCenterControllingArea,
      prps.posnr_prps                                    as LeadingSalesOrderItem,
      prps.vbeln_prps                                    as LeadingSalesOrder,
      //CE2208-Hierarchy Settlement 

      prps.settlementelement                             as EntProjectSettlementElement, 
      prps.settlmtruleinherited                          as EntProjIsSettlmtRuleInherited,
          
      //CE2111-RA key description

      _RaKeyVH.ResultAnalysisDescription                 as ResultAnalysisDescription,

      //Associations

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _Project,
      _CompanyCode,
      _ControllingArea,
      _FunctionalArea,
      _ProfitCenter,
      _ResponsibleCostCenter,
      _Plant,
      _FactoryCalendar,
      //      _CostingSheetProcedure,

      _CostCenter,
      _ProjectType,
      _ProjectTypeText,
      _RaKeyVH,
      _WBSElementShortText 
}