P_ProjRevnRecgnRealTmeIss

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Consumption.dbHints: ['NO_SUBPLAN_SHARING','OPTIMIZATION_LEVEL(COST_BASED)', 'NO_PREDICATE_SIMPLIFICATION']

@EndUserText.label: 'Event based rev. rec. Real-time issue'

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@VDM.private: true

@VDM.viewType: #CONSUMPTION

define view entity P_ProjRevnRecgnRealTmeIss
  //----------------------------------------------------------------------------------------------------------------------------------------------------------------

  //1st Long AppLog

  //----------------------------------------------------------------------------------------------------------------------------------------------------------------

  as select from           P_EBRRRealTmeApplog         as Applog

    inner join             I_CompanyCode               as CompanyCode               on Applog.CompanyCode = CompanyCode.CompanyCode

    left outer to one join I_WBSElementBasicData       as WBSElement                on WBSElement.WBSElementInternalID = Applog.WBSElementInternalID

    left outer to one join I_ReferenceDocumentTypeText as ReferenceDocumentTypeText on  Applog.ReferenceDocumentType       = ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                    and ReferenceDocumentTypeText.Language = $session.system_language

{
  key Applog.ApplicationLog,
      Applog.ReferenceDocumentType,
      Applog.ReferenceOrganizationalUnits,
      Applog.ReferenceDocumentContext,
      Applog.ReferenceDocument,
      Applog.FiscalPeriod,
      Applog.FiscalYear,
      Applog.CompanyCode                                           as CompanyCode,
      WBSElement._Project.Project                                  as Project,
      WBSElement._Project.ProjectExternalID,
      Applog.AccountAssignmentType,
      Applog.NumberOfOpenErrorMessages,
      Applog.ApplicationLogHandle,
      Applog.ApplicationLogSubobject,
      CompanyCode.CompanyCodeName                                  as CompanyCodeName,

      concat(Applog.FiscalPeriod, concat('.', Applog.FiscalYear) ) as ToFiscalYearPeriod,
      //Period in the format yearmont 2019006

      concat(Applog.FiscalYear, Applog.FiscalPeriod)               as FiscalYearPeriod,

      ReferenceDocumentTypeText.ReferenceDocumentTypeName          as ReferenceDocumentTypeName,
      Applog.RealTimeIssueLogVersion                               as RealTimeIssueLogVersion
}
where
     Applog.AccountAssignmentType = 'PR'
  or Applog.AccountAssignmentType = '' //Project corrupted logs


//----------------------------------------------------------------------------------------------------------------------------------------------------------------

//2nd for NPI

//----------------------------------------------------------------------------------------------------------------------------------------------------------------


union select from        P_ProjRevnRecgnRealTmeApplLog  as AppLog //NPI part


  inner join             I_CompanyCode                  as CompanyCode               on AppLog.CompanyCode = CompanyCode.CompanyCode

  inner join             I_RevnRecgnConstcyLdgrEvalArea as ConstcyLdgrEvalArea       on ConstcyLdgrEvalArea.CompanyCode = AppLog.CompanyCode

  inner join             I_WBSElementBasicData          as WBSElement                on WBSElement.WBSElementInternalID = AppLog.WBSElementInternalID

  left outer to one join I_ReferenceDocumentTypeText    as ReferenceDocumentTypeText on  AppLog.ReferenceDocumentType       = ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                     and ReferenceDocumentTypeText.Language = $session.system_language

{
  key AppLog.ApplicationLog,
      AppLog.ReferenceDocumentType,
      AppLog.ReferenceOrganizationalUnits,
      AppLog.ReferenceDocumentContext,
      AppLog.ReferenceDocument,
      AppLog.FiscalPeriod,
      AppLog.FiscalYear,
      AppLog.CompanyCode,
      WBSElement._Project.Project,
      WBSElement._Project.ProjectExternalID,
      //dummy as it not needed for NPI

      cast( 'PR' as char2 )                                        as AccountAssignmentType,
      AppLog.NumberOfOpenErrorMessages,
      AppLog.ApplicationLogHandle,
      AppLog.ApplicationLogSubobject,
      CompanyCode.CompanyCodeName,

      //Period in the format month.year 006.2019

      concat(AppLog.FiscalPeriod, concat('.', AppLog.FiscalYear) ) as ToFiscalYearPeriod,
      //Period in the format yearmont 2019006

      concat(AppLog.FiscalYear, AppLog.FiscalPeriod)               as FiscalYearPeriod,

      ReferenceDocumentTypeText.ReferenceDocumentTypeName          as ReferenceDocumentTypeName,
      cast ( ' ' as fins_trr_log_version preserving type )         as RealTimeIssueLogVersion

}
group by

  AppLog.ApplicationLog,
  AppLog.ReferenceDocument,
  AppLog.ReferenceOrganizationalUnits,
  AppLog.ReferenceDocumentContext,
  AppLog.ReferenceDocumentType,
  AppLog.CompanyCode,
  CompanyCode.CompanyCodeName,
  AppLog.NumberOfOpenErrorMessages,
  AppLog.FiscalPeriod,
  AppLog.FiscalYear,
  ReferenceDocumentTypeText.ReferenceDocumentTypeName,
  WBSElement._Project.Project,
  WBSElement._Project.ProjectExternalID,
  AppLog.ApplicationLogHandle,
  AppLog.ApplicationLogSubobject