P_TimeShtHrsAnlysForProjects

@AbapCatalog: {
  sqlViewName: 'PTSANLYS4PROJ',
  preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Staffing - Timesheet Analysis of Hours spent in Projects'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  serviceQuality: #B,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
@VDM: {
  private: true,
  lifecycle.contract.type: #NONE,
  viewType: #COMPOSITE
}
define view P_TimeShtHrsAnlysForProjects as select from I_TimeSheetRecord as A
//      left outer join I_PurchaseOrderItemAPI01 as C

//      on A.PurchaseOrder = C.PurchaseOrder

//      and A.PurchaseOrderItem = C.PurchaseOrderItem

      inner join I_WBSElementBasicData as B
      on A.WBSElementInternalID = B.WBSElementInternalID {
A.TimeSheetRecord,
A.PersonWorkAgreement,
//case when A.ActivityType = '' then C.Material,

//else A.ActivityType end as ActivityType,

A.ActivityType,
A.WorkItem,
A.WBSElementInternalID,
concat(left(A.TimeSheetDate, 4), concat('0', substring(A.TimeSheetDate, 5, 2))) as FiscalYearPeriod,
left(A.TimeSheetDate, 4) as FiscalYear,
concat('0', substring(A.TimeSheetDate, 5, 2)) as FiscalPeriod,
A.TimeSheetDate,
A.PurchaseOrder,
A.PurchaseOrderItem,
A.ServiceDocumentType,
A.ServiceDocument,
A.ServiceDocumentItem,
A.TimeSheetStatus,
A.TimeSheetPredecessorRecord,
A.AccountingIndicatorCode,
A.HoursUnitOfMeasure,
case when A.TimeSheetStatus = '10' or A.TimeSheetStatus = '20' or A.TimeSheetStatus = '30' then A.RecordedHours
else cast(0 as abap.quan( 8, 2 )) end as RecordedHours,

case when A.TimeSheetStatus = '20' then A.RecordedHours
else cast(0 as abap.quan( 8, 2 )) end as UnapprovedHours,

case when A.TimeSheetStatus = '30' then A.RecordedHours
else cast(0 as abap.quan( 8, 2 )) end as ApprovedHours,

B.WBSElement,
B._Project.Project,
B._Project.ProjectProfileCode
}   where ( A.TimeSheetStatus = '10' or A.TimeSheetStatus = '20' or A.TimeSheetStatus = '30' )
    and A.ServiceDocumentType = ''
    and A.ServiceDocument = '' and A.ServiceDocumentItem = '000000'
//    and ( B._Project.ProjectProfileCode = 'P001' or B._Project.ProjectProfileCode = 'P002' )