C_RunOverheadWBSElement

DDL: C_RUNOVERHEADWBSELEMENT Type: view_entity CONSUMPTION Package: ODATA_OVERHEAD_CALC_SINGLE

Overhead Calculation WBS Element

C_RunOverheadWBSElement is a Consumption CDS View that provides data about "Overhead Calculation WBS Element" in SAP S/4HANA. It reads from 1 data source (I_WBSElementBasicData) and exposes 12 fields with key field WBSElementInternalID. It is exposed through 1 OData service (FCO_OVERHEAD_CALCULATION). Part of development package ODATA_OVERHEAD_CALC_SINGLE.

1 data source(s) Exposed by 1 service(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_WBSElementBasicData _WBSElementBasicData from

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Overhead Calculation WBS Element view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Search.searchable true view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName WBS Element view
UI.headerInfo.typeNamePlural WBS Elements view
UI.headerInfo.title.value WBSElementExternalID view
UI.headerInfo.description.value WBSDescription view

OData Services (1)

ServiceBindingVersionContractRelease
FCO_OVERHEAD_CALCULATION UI_FCO_OVERHEAD_CALC_O2 V2 C1 NOT_RELEASED

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY WBSElementInternalID I_WBSElementBasicData WBSElementInternalID
WBSElementExternalID WBSElementExternalID
WBSDescription WBSDescription
ProjectInternalID
ProjectExternalID
ProjectDescription
CompanyCode CompanyCode
CostCenter CostCenter
ProfitCenter ProfitCenter
ControllingArea ControllingArea
WBSElementObject WBSElementObject
_CompanyCode _CompanyCode 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Overhead Calculation WBS Element'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Search.searchable: true
@VDM.viewType: #CONSUMPTION

@UI.headerInfo: {
  typeName: 'WBS Element'
  ,
  typeNamePlural: 'WBS Elements'
  ,
  title: { value: 'WBSElementExternalID' }
  ,
  description: {  value: 'WBSDescription' }
  }

@UI.presentationVariant: [{
  text: 'WBS Element',
  qualifier: 'VAR_WBS'
}]
define view entity C_RunOverheadWBSElement
  as select from I_WBSElementBasicData as _WBSElementBasicData
{
      @UI.hidden: true
  key _WBSElementBasicData.WBSElementInternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'WBSElement'
      @UI.lineItem: [{ position: 10 , importance: #MEDIUM }]
      @UI.textArrangement: #TEXT_SEPARATE
      WBSElementExternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.7
      }
      @UI.lineItem: [ { position: 20 }]
      WBSDescription,

      @UI.hidden: true      
      cast( _WBSElementBasicData.ProjectInternalID as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'Project'
      @UI.lineItem: [ { position: 30 }]
      @ObjectModel.text.element: [ 'ProjectDescription']
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @UI.textArrangement: #TEXT_LAST
      cast (_WBSElementBasicData._Project.ProjectExternalID as cats_cpr_extid ) as ProjectExternalID,
      _WBSElementBasicData._Project.ProjectDescription,

      @ObjectModel.text.association: '_CompanyCode'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @Search: {
        defaultSearchElement: true,
        ranking: #MEDIUM,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'CompanyCode'
      @Consumption.filter.mandatory: true
      @UI.lineItem: [ { position: 40 }]
      @UI.textArrangement: #TEXT_LAST
      CompanyCode,

      @UI.hidden: true
      CostCenter,

      @UI.hidden: true
      ProfitCenter,

      @UI.hidden: true
      ControllingArea,

      @UI.hidden: true
      WBSElementObject,

      /* association */
      _CompanyCode
}

Learn More